[gentoo-commits] repo/gentoo:master commit in: xfce-extra/xfce4-pulseaudio-plugin/

["Michał Górny" <mgorny@gentoo.org>]

commit:     d7d19b210154751065c6fc0929deddf50e7010f0
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 30 06:30:20 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Mar 30 06:51:00 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d7d19b21

xfce-extra/xfce4-pulseaudio-plugin: Bump to 0.4.3

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 xfce-extra/xfce4-pulseaudio-plugin/Manifest        |  1 +
 .../xfce4-pulseaudio-plugin-0.4.3.ebuild           | 63 ++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/xfce-extra/xfce4-pulseaudio-plugin/Manifest b/xfce-extra/xfce4-pulseaudio-plugin/Manifest
index 441d8a3a85c..89e77d658b9 100644
--- a/xfce-extra/xfce4-pulseaudio-plugin/Manifest
+++ b/xfce-extra/xfce4-pulseaudio-plugin/Manifest
@@ -1 +1,2 @@
 DIST xfce4-pulseaudio-plugin-0.4.2.tar.bz2 428504 BLAKE2B dd8c855e75aaee060df1e7abb2f8b835f1a630ce8b45b28c407c48f52071a51729e0bf8c645d5f68f968f12a45dea272d03ee69f4554009421a1a075a8fb8d2c SHA512 94184fe7379a7f1763d606fe3c45186767a43180329b43c8cba04b76ae5e1b2249531fc1fb6304da9bb03e7475ad65f861341253ead530d9a945165b4eb9e46e
+DIST xfce4-pulseaudio-plugin-0.4.3.tar.bz2 431773 BLAKE2B 2c0de4ea0ab9304b737fe4ce570bcd8427f983845fe898dbe7e053a5fe79793223df6882a931b186664d8c95d4c767daf39ba36a98dc58595ba77e8a18c13a6c SHA512 d3214b2b7c35a0a87ea60a5d843f5027d1b09f320d4d24c6bf89a8936de92226223cb4dc5368edf4c0a1aedb3b8796510981eeadee8e836e764569d9284f0efa

diff --git a/xfce-extra/xfce4-pulseaudio-plugin/xfce4-pulseaudio-plugin-0.4.3.ebuild b/xfce-extra/xfce4-pulseaudio-plugin/xfce4-pulseaudio-plugin-0.4.3.ebuild
new file mode 100644
index 00000000000..bd780cf925b
--- /dev/null
+++ b/xfce-extra/xfce4-pulseaudio-plugin/xfce4-pulseaudio-plugin-0.4.3.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils
+
+DESCRIPTION="A panel plug-in for PulseAudio volume control"
+HOMEPAGE="https://git.xfce.org/panel-plugins/xfce4-pulseaudio-plugin/"
+SRC_URI="https://archive.xfce.org/src/panel-plugins/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="debug keybinder libnotify wnck"
+
+RDEPEND=">=dev-libs/glib-2.42.0:=
+	media-sound/pulseaudio:=
+	>=x11-libs/gtk+-3.20.0:3=
+	>=xfce-base/exo-0.11:=
+	>=xfce-base/libxfce4ui-4.11.0:=[gtk3(+)]
+	>=xfce-base/libxfce4util-4.9.0:=
+	>=xfce-base/xfce4-panel-4.11.0:=
+	>=xfce-base/xfconf-4.6.0:=
+	keybinder? ( dev-libs/keybinder:3= )
+	libnotify? ( x11-libs/libnotify:= )
+	wnck? ( x11-libs/libwnck:3= )"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig"
+
+src_configure() {
+	local myconf=(
+		$(use_enable keybinder)
+		$(use_enable libnotify)
+		$(use_enable wnck)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+
+	if ! has_version media-sound/pavucontrol; then
+		elog "For the 'audio mixer...' shortcut to work, you need to install"
+		elog "an external mixer application. Please either install:"
+		elog
+		elog "	media-sound/pavucontrol"
+		elog
+		elog "or specify another application to use in the 'Properties' dialog."
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}