[gentoo-commits] repo/gentoo:master commit in: dev-libs/gobject-introspection/

["Matt Turner" <mattst88@gentoo.org>]

commit:     dac7109acde03aff2a15a128a257736a4f480636
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Tue Mar 24 05:14:40 2020 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Wed Mar 25 02:20:15 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dac7109a

dev-libs/gobject-introspection: Version bump to 1.64.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/gobject-introspection/Manifest            |  1 +
 .../gobject-introspection-1.64.0.ebuild            | 71 ++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/dev-libs/gobject-introspection/Manifest b/dev-libs/gobject-introspection/Manifest
index 83ad50553dd..4606cfc104a 100644
--- a/dev-libs/gobject-introspection/Manifest
+++ b/dev-libs/gobject-introspection/Manifest
@@ -1,2 +1,3 @@
 DIST gobject-introspection-1.60.2.tar.xz 1285000 BLAKE2B 43d96bbac8dd6600726876277f945e7eb01dba2063907c21960cbf5f49d766ac156ed116641b69dfe28f3025c4b482ffd39e8e107aba9ee48010a500111a58e4 SHA512 8e8c1c3a025cb6c18933302ada8cce7c4826f22eef791c80a97abb28379239f8d99312e1237bcea1060f4d5cf65441909b9da434561982209bb4976b1f22529e
 DIST gobject-introspection-1.62.0.tar.xz 980732 BLAKE2B 96ecc98bea97b7cb24e2c0a0adb8158cfc8915ee8e3b980adf08ec3256d4d0f87bc92d33cce30f5b23c85c4b144d8da755e5313735091b27ff53fea45a80014e SHA512 b460a95fd7a323e9b0c9a45e680ebe98bbae7632abfa53b3e0b0ec050775cab17dde693314d6d4f8e93614c32b5587f8ce0b4a4c9ee9ba46c029ce029014e638
+DIST gobject-introspection-1.64.0.tar.xz 1000240 BLAKE2B 09e6dec65a53a107bee387cef9cb271345ae564f3520bd9a6485cf1796deaa47243c05f45a72f3243e811a2c1962a2ae123a6b344819187cbf36eae0ed58fbaa SHA512 d1960424d82dea1f1d36a7c3f9922029e751e77da8dc6904c24750babe7c3f4c11a6795eb218aab342ccbb6326d0ac3eac2c2c903e90b146f4e28c0f413da1ae

diff --git a/dev-libs/gobject-introspection/gobject-introspection-1.64.0.ebuild b/dev-libs/gobject-introspection/gobject-introspection-1.64.0.ebuild
new file mode 100644
index 00000000000..a2bd4c827a0
--- /dev/null
+++ b/dev-libs/gobject-introspection/gobject-introspection-1.64.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="xml"
+inherit gnome.org meson python-single-r1 toolchain-funcs xdg
+
+DESCRIPTION="Introspection system for GObject-based libraries"
+HOMEPAGE="https://wiki.gnome.org/Projects/GObjectIntrospection"
+
+LICENSE="LGPL-2+ GPL-2+"
+SLOT="0"
+IUSE="doctool gtk-doc test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+# virtual/pkgconfig needed at runtime, bug #505408
+RDEPEND="
+	>=dev-libs/gobject-introspection-common-${PV}
+	>=dev-libs/glib-2.58.0:2
+	dev-libs/libffi:=
+	doctool? (
+		$(python_gen_cond_dep '
+			dev-python/mako[${PYTHON_MULTI_USEDEP}]
+			dev-python/markdown[${PYTHON_MULTI_USEDEP}]
+		')
+	)
+	virtual/pkgconfig
+	${PYTHON_DEPS}
+"
+# Wants real bison, not virtual/yacc
+DEPEND="${RDEPEND}
+	gtk-doc? ( >=dev-util/gtk-doc-1.19
+		app-text/docbook-xml-dtd:4.3
+		app-text/docbook-xml-dtd:4.5
+	)
+	sys-devel/bison
+	sys-devel/flex
+	test? ( x11-libs/cairo[glib] )
+"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature test cairo)
+		$(meson_feature doctool)
+		#-Dglib_src_dir
+		$(meson_use gtk-doc gtk_doc)
+		#-Dcairo_libname
+		-Dpython="${EPYTHON}"
+		#-Dgir_dir_prefix
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${ED}"/usr/bin/
+	python_optimize "${ED}"/usr/$(get_libdir)/gobject-introspection/giscanner
+
+	# Prevent collision with gobject-introspection-common
+	rm -v "${ED}"/usr/share/aclocal/introspection.m4 \
+		"${ED}"/usr/share/gobject-introspection-1.0/Makefile.introspection || die
+	rmdir "${ED}"/usr/share/aclocal || die
+}