[gentoo-commits] repo/gentoo:master commit in: app-misc/solaar/

["Robin H. Johnson" <robbat2@gentoo.org>]

commit:     ff77d5dfd8f7ca5862f3aacc146f858ca593d23a
Author:     Robin H. Johnson <robbat2 <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 23 19:26:06 2020 +0000
Commit:     Robin H. Johnson <robbat2 <AT> gentoo <DOT> org>
CommitDate: Mon Mar 23 19:26:19 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ff77d5df

app-misc/solaar: bump

Signed-off-by: Robin H. Johnson <robbat2 <AT> gentoo.org>

 app-misc/solaar/Manifest                |  1 +
 app-misc/solaar/solaar-1.0.2_rc1.ebuild | 49 ++++++++++++++++++++++++++++++
 app-misc/solaar/solaar-9999.ebuild      | 53 +++++++++++++++++++++++++++++++++
 3 files changed, 103 insertions(+)

diff --git a/app-misc/solaar/Manifest b/app-misc/solaar/Manifest
index ed728d68155..c9144dca339 100644
--- a/app-misc/solaar/Manifest
+++ b/app-misc/solaar/Manifest
@@ -1,2 +1,3 @@
 DIST solaar-0.9.2.tar.gz 864509 BLAKE2B 57c58d203d8d1ae390eaaa1cfc963cfcc9523de8d7edcb482f30c66bcaaceebc7c514cf0fcffb1b20ca5cc3bc869c94cb61bcddff44debba9307ec3b1c0e1def SHA512 13f469df753cc8fab55f5259ccc3e62b6e44471d277d240cd56ce0580144d2b1f95d731268176648663dd15e5607bfb512f477362f4f100aa0a653b001dfe04b
 DIST solaar-1.0.1.tar.gz 1195660 BLAKE2B e6cd89b5735e125dd438255a8961b1d5d38feb515c5097efec0403d99b9db6e29c439c13e279fcffe69cb314bf2650a7a11770830fdf1e971ade27ce8331aed2 SHA512 e0b2bbfd97d9650d94f1a4b47e4e70f09c75f684e7e1d3e67d2cf6dd197109084e941b98333e173fb205d5c9464dd07e17390d9c2d5b46393fee2efdb20429ac
+DIST solaar-1.0.2-rc1.tar.gz 1219777 BLAKE2B aa6780aa4748de97c69c03263e731a47068844e7f4275f87eadd3251e8dcf14b82fdd5ba0eae13492634b7d252340a01b9492cc8948f78fb86c15b4bc4698789 SHA512 1aa5a066c8b735e6525da4da738e9632107867e3d70d67fe7e643debdc9dc7969b033d618ff2c3f538095a9995a7e90d068f9d0f41e858361327c75718dbdb12

diff --git a/app-misc/solaar/solaar-1.0.2_rc1.ebuild b/app-misc/solaar/solaar-1.0.2_rc1.ebuild
new file mode 100644
index 00000000000..d4a89545dd8
--- /dev/null
+++ b/app-misc/solaar/solaar-1.0.2_rc1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit linux-info udev xdg distutils-r1
+
+DESCRIPTION="A Linux device manager for Logitech's Unifying Receiver peripherals"
+HOMEPAGE="https://pwr-solaar.github.io/Solaar/"
+SRC_URI="https://github.com/pwr-Solaar/Solaar/archive/${PV/_rc/-rc}.tar.gz -> ${P/_rc/-rc}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="doc"
+
+RDEPEND="
+	acct-group/plugdev
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	>=dev-python/pyudev-0.13[${PYTHON_USEDEP}]
+	x11-libs/gtk+:3[introspection]"
+
+S="${WORKDIR}"/Solaar-${PV/_rc/-rc}
+
+CONFIG_CHECK="~HID_LOGITECH_DJ ~HIDRAW"
+
+python_prepare_all() {
+	# don't autostart (bug #494608)
+	sed -i '/yield autostart_path/d' setup.py || die
+
+	# grant plugdev group rw access
+	sed -i 's/#MODE=/MODE=/' rules.d/42-logitech-unify-permissions.rules || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	udev_dorules rules.d/*.rules
+
+	dodoc docs/devices.md
+	if use doc; then
+		dodoc -r docs/*
+	fi
+}

diff --git a/app-misc/solaar/solaar-9999.ebuild b/app-misc/solaar/solaar-9999.ebuild
new file mode 100644
index 00000000000..6b0376ffc08
--- /dev/null
+++ b/app-misc/solaar/solaar-9999.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit linux-info udev xdg distutils-r1
+
+DESCRIPTION="A Linux device manager for Logitech's Unifying Receiver peripherals"
+HOMEPAGE="https://pwr-solaar.github.io/Solaar/"
+if [[ ${PV} =~ 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/pwr-Solaar/Solaar"
+else
+	SRC_URI="https://github.com/pwr-Solaar/Solaar/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~x86"
+	S="${WORKDIR}"/Solaar-${PV} # hopefully upstream fixes this in future packaging
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="doc"
+
+RDEPEND="
+	acct-group/plugdev
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	>=dev-python/pyudev-0.13[${PYTHON_USEDEP}]
+	x11-libs/gtk+:3[introspection]"
+
+CONFIG_CHECK="~HID_LOGITECH_DJ ~HIDRAW"
+
+python_prepare_all() {
+	# don't autostart (bug #494608)
+	sed -i '/yield autostart_path/d' setup.py || die
+
+	# grant plugdev group rw access
+	sed -i 's/#MODE=/MODE=/' rules.d/42-logitech-unify-permissions.rules || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	udev_dorules rules.d/*.rules
+
+	dodoc docs/devices.md
+	if use doc; then
+		dodoc -r docs/*
+	fi
+}