[gentoo-commits] repo/gentoo:master commit in: app-editors/texworks/

["Mikle Kolyada" <zlogene@gentoo.org>]

commit:     ba9f86c1332817d5353dcf3b2701f5b0950a4ae7
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 22 17:46:17 2020 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Sun Mar 22 17:46:52 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ba9f86c1

app-editors/texworks: Version bump (v0.6.4)

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Mikle Kolyada <zlogene <AT> gentoo.org>

 app-editors/texworks/Manifest              |  1 +
 app-editors/texworks/texworks-0.6.4.ebuild | 68 ++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/app-editors/texworks/Manifest b/app-editors/texworks/Manifest
index ff1a9953be4..e8ccc5fee1a 100644
--- a/app-editors/texworks/Manifest
+++ b/app-editors/texworks/Manifest
@@ -1 +1,2 @@
 DIST texworks-0.6.3.tar.gz 12082640 BLAKE2B db5b98f9226e0e7e109dc06d8e0a88b0e8f0dd237676ebec3be55308c720eb6dada25be061d8d5dc27949b9673e93fd65c8ddddfbe03aee4f8170471c52b37fd SHA512 389cf54441e74164fc842f2f293cdee45c6ff9fe202f262d32f3fb076de9a29813a62cd75052969293f2f784e0722215bbbf2206e75bc836a13d495bf5aed653
+DIST texworks-0.6.4.tar.gz 12139530 BLAKE2B 48808ba7c868c9f445d902254c4fe7abb4af740b77e227ab3d9d0ced3132129faa885af68811fa6e3c27ede217deacaf062ae4d8ff0f3fe24b066ab1195de96b SHA512 8fa3e16e6ee19d46dba30707e7a83340c1d68f6cb855cc2838c5c168dc580f8973cb7438bdfce93e51962653694d369c51d7a82a07ad6bcf5eb89030fa3640ea

diff --git a/app-editors/texworks/texworks-0.6.4.ebuild b/app-editors/texworks/texworks-0.6.4.ebuild
new file mode 100644
index 00000000000..5a37d1418bb
--- /dev/null
+++ b/app-editors/texworks/texworks-0.6.4.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{3_6,3_7} )
+
+inherit python-single-r1 cmake-utils virtualx xdg-utils
+
+DESCRIPTION="A simple interface for working with TeX documents"
+HOMEPAGE="http://tug.org/texworks/"
+SRC_URI="https://github.com/TeXworks/texworks/archive/release-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="lua python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="app-text/hunspell:=
+	app-text/poppler[qt5]
+	dev-qt/designer:5
+	dev-qt/qtcore:5
+	dev-qt/qtconcurrent:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtscript:5[scripttools]
+	lua? ( dev-lang/lua:0 )
+	python? ( ${PYTHON_DEPS} ) "
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="virtual/pkgconfig"
+
+S=${WORKDIR}/${PN}-release-${PV}
+
+RESTRICT="!test? ( test )"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-Wno-dev
+		-DPREFER_BUNDLED_SYNCTEX=ON
+		-DWITH_LUA=$(usex lua ON OFF)
+		-DWITH_PYTHON=$(usex python ON OFF)
+		-DTeXworks_PLUGIN_DIR="/usr/$(get_libdir)/texworks"
+		-DTeXworks_DOCS_DIR="/share/doc/${PF}"
+		-DQTPDF_VIEWER=ON
+		-DBUILD_SHARED_LIBS=ON
+		-DBUILD_SHARED_PLUGINS=ON
+	)
+	cmake-utils_src_configure
+}
+
+src_test() {
+	virtx default_src_test
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}