[gentoo-commits] repo/gentoo:master commit in: dev-util/redo/

["Jeroen Roovers" <jer@gentoo.org>]

commit:     b49eee7e14b1626df7f88ac239f04ee2151d419e
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 22 10:07:55 2020 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Sun Mar 22 10:09:31 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b49eee7e

dev-util/redo: Version 0.42a

Package-Manager: Portage-2.3.94, Repoman-2.3.21
Closes: https://bugs.gentoo.org/693034
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 dev-util/redo/Manifest          |  1 +
 dev-util/redo/redo-0.42a.ebuild | 57 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/dev-util/redo/Manifest b/dev-util/redo/Manifest
index 684194243ee..792f0935e82 100644
--- a/dev-util/redo/Manifest
+++ b/dev-util/redo/Manifest
@@ -1 +1,2 @@
 DIST redo-0.42.tar.gz 194344 BLAKE2B ce17ba2bc8b6a074bfc5cae58cc99c1c41b2e8bab93a10f29d1178cb2071bd68ef5528529c320ee55063a4e3bce83705b486bc92992a9c0c18b65e7fec76fde5 SHA512 41b8417136f98d12edf3c62f027f2459ae3fb92f6c5464553d79c3a52344de57220a5c64b565118da0a99c1544eaa153a468ffcdcfbf7193c76c896bcd40e900
+DIST redo-0.42a.tar.gz 195053 BLAKE2B 3e84e961eeb66396d5d5aa8a3f05f10d4000089d12c36bd8e061c163e050b9bc125cd8dcc5987c9f3b25e2b8803ff7c34d48a173ab91fc4a3e9fd63c114adc8a SHA512 8473bd8168c8e70b59a573560f8f725c8538061ee15eabeb63e467a363fa6869aa8088e8ce324726da4e2f7115e2ddf72cbb657703e9090f4f93c05f42bb67cb

diff --git a/dev-util/redo/redo-0.42a.ebuild b/dev-util/redo/redo-0.42a.ebuild
new file mode 100644
index 00000000000..47a81ecf202
--- /dev/null
+++ b/dev-util/redo/redo-0.42a.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2018-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="sqlite"
+inherit multilib multiprocessing python-utils-r1 python-single-r1
+
+DESCRIPTION="Smaller, easier, more powerful, and more reliable than make"
+HOMEPAGE="https://github.com/apenwarr/redo"
+SRC_URI="https://github.com/apenwarr/redo/archive/${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/beautifulsoup[${PYTHON_MULTI_USEDEP}]
+		dev-python/markdown[${PYTHON_MULTI_USEDEP}]
+	')
+	${PYTHON_DEPS}
+"
+RDEPEND="
+	${BDEPEND}
+"
+S=${WORKDIR}/${PN}-${P}
+
+src_configure() {
+	echo ${PYTHON} > redo/whichpython || die
+}
+
+src_compile() {
+	./do -j$(makeopts_jobs) build || die
+}
+
+src_test() {
+	local ARCH= CFLAGS= CXXFLAGS= LDFLAGS=
+	./do -j$(makeopts_jobs) test || die
+}
+
+src_install() {
+	DESTDIR="${D}" \
+	DOCDIR="${D}/usr/share/doc/${PF}" \
+	LIBDIR="${D}/$(python_get_sitedir)/${PN}" \
+	./do -j$(makeopts_jobs) \
+		install || die
+
+	python_fix_shebang "${D}"
+
+	sed -i \
+		-e 's|/lib/|/'"$(get_libdir)"'/|g' \
+		"${D}"/usr/bin/* || die
+
+	python_optimize
+}