[gentoo-commits] proj/sci:master commit in: dev-python/traits/

["Horea Christian" <horea.christ@gmail.com>]

commit:     2109e5887c6cadddd4fdb629514580bc97dc8a27
Author:     Horea Christian <chr <AT> chymera <DOT> eu>
AuthorDate: Fri Mar 20 05:38:54 2020 +0000
Commit:     Horea Christian <horea.christ <AT> gmail <DOT> com>
CommitDate: Fri Mar 20 05:40:18 2020 +0000
URL:        https://gitweb.gentoo.org/proj/sci.git/commit/?id=2109e588

dev-python/traits: version bump 6.0.0

and added PYTHON_COMPAT to include 3_7

Package-Manager: Portage-2.3.94, Repoman-2.3.21
Signed-off-by: Horea Christian <chr <AT> chymera.eu>

 dev-python/traits/traits-6.0.0.ebuild | 43 +++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

diff --git a/dev-python/traits/traits-6.0.0.ebuild b/dev-python/traits/traits-6.0.0.ebuild
new file mode 100644
index 000000000..163fc881e
--- /dev/null
+++ b/dev-python/traits/traits-6.0.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{3_6,3_7} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Enthought Tool Suite: Explicitly typed attributes for Python"
+HOMEPAGE="http://docs.enthought.com/traits/
+	https://github.com/enthought/traits
+	https://pypi.org/project/traits/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+
+RDEPEND="dev-python/numpy[${PYTHON_USEDEP}]"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		${RDEPEND}
+		)"
+
+python_prepare_all() {
+	sed -i -e "s/'-O3'//g" setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	python_is_python3 || local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile
+}
+
+python_test() {
+	cd "${BUILD_DIR}"/lib || die
+	${EPYTHON} -m unittest discover || die
+}