[gentoo-commits] repo/gentoo:master commit in: app-misc/hivex/

["Rick Farina" <zerochaos@gentoo.org>]

commit:     31c4a89a231c5035a4238c8c8a66e1690f6473bc
Author:     Rick Farina <zerochaos <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 18 20:36:01 2020 +0000
Commit:     Rick Farina <zerochaos <AT> gentoo <DOT> org>
CommitDate: Wed Mar 18 20:36:15 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=31c4a89a

app-misc/hivex: bump

Package-Manager: Portage-2.3.94, Repoman-2.3.21
Signed-off-by: Rick Farina <zerochaos <AT> gentoo.org>

 app-misc/hivex/Manifest            |   1 +
 app-misc/hivex/hivex-1.3.18.ebuild | 110 +++++++++++++++++++++++++++++++++++++
 2 files changed, 111 insertions(+)

diff --git a/app-misc/hivex/Manifest b/app-misc/hivex/Manifest
index a3290cd9d4d..933c62f73e3 100644
--- a/app-misc/hivex/Manifest
+++ b/app-misc/hivex/Manifest
@@ -1 +1,2 @@
 DIST hivex-1.3.14.tar.gz 1332257 BLAKE2B fe7c19e05d29c7e98a334842cc1144aa76b148a3b7aae91449a4923a124eb54227a9a004346ef3558732c688c4f92cacd0c9328056930c33dba0404465634da0 SHA512 dd7dd52dceda580179a815fc48a2a2c7e8f7234614beceb937fba7e317df17984e65453338160c4c467b70d7d4f9bd61b48aad3ca51e19bd5e4cfbca8ee3adb6
+DIST hivex-1.3.18.tar.gz 1542133 BLAKE2B 961d0797770a2bd3176ce288a509fab8685de91317d55f05e5295f9f56fd54c31acb64847e0cbb6a6074627ccbdfdf35bd0d35150beb7746a8b3de9128ac24e3 SHA512 1851351118921e81df9e505f90d00048a178572c2edd3de40194a69915176bdb615e2eb5afea408d57063e98257c8d1e3d0cd6730407153892cc9e3befc4aa3a

diff --git a/app-misc/hivex/hivex-1.3.18.ebuild b/app-misc/hivex/hivex-1.3.18.ebuild
new file mode 100644
index 00000000000..ac1bd5848ab
--- /dev/null
+++ b/app-misc/hivex/hivex-1.3.18.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+USE_RUBY="ruby23 ruby24 ruby25"
+RUBY_OPTIONAL=yes
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit eutils perl-module ruby-ng python-single-r1
+
+DESCRIPTION="Library for reading and writing Windows Registry 'hive' binary files"
+HOMEPAGE="http://libguestfs.org"
+SRC_URI="http://libguestfs.org/download/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ocaml readline +perl python test static-libs ruby"
+
+RDEPEND="
+	virtual/libiconv
+	virtual/libintl
+	dev-libs/libxml2:2
+	ocaml? ( dev-lang/ocaml[ocamlopt]
+			 dev-ml/findlib[ocamlopt]
+			 )
+	readline? ( sys-libs/readline:0 )
+	perl? (
+		dev-lang/perl:=
+		dev-perl/IO-stringy
+	)
+	ruby? ( $(ruby_implementations_depend) )
+	python? ( ${PYTHON_DEPS} )
+	"
+
+DEPEND="${RDEPEND}
+	perl? (
+		test? ( dev-perl/Pod-Coverage
+			dev-perl/Test-Pod-Coverage )
+		  )
+	"
+
+ruby_add_bdepend "ruby? ( dev-ruby/rake
+			virtual/rubygems
+			dev-ruby/rdoc )"
+ruby_add_rdepend "ruby? ( virtual/rubygems )"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
+			ruby? ( || ( $(ruby_get_use_targets) ) )"
+
+DOCS=( README )
+
+S="${WORKDIR}/${P}"
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_unpack() {
+	default
+	cp -prlP "${WORKDIR}/${P}" "${WORKDIR}"/all
+}
+
+src_configure() {
+	ruby-ng_src_configure
+
+	if use perl; then
+		pushd perl
+		perl-module_src_configure
+		popd
+	fi
+
+	local myeconfargs=(
+		$(use_with readline)
+		$(use_enable ocaml)
+		$(use_enable perl)
+		--enable-nls
+		--disable-ruby
+		$(use_enable python)
+		--disable-rpath
+		)
+
+	econf ${myeconfargs[@]}
+}
+
+src_compile() {
+	default
+	ruby-ng_src_compile
+}
+
+src_install() {
+	strip-linguas -i po
+
+	emake install DESTDIR="${ED}" "LINGUAS=""${LINGUAS}"""
+	python_optimize
+
+	ruby-ng_src_install
+
+	if use perl; then
+		perl_delete_localpod
+	fi
+
+	#can't figure out a better way to do this
+	mv "${ED}"/usr/man/man3/* "${ED}/usr/share/man/man3/" || die
+	rm -r "${ED}/usr/man" || die
+}