[gentoo-commits] repo/gentoo:master commit in: x11-misc/zim/

["Sebastian Pipping" <sping@gentoo.org>]

commit:     89c67a43f4cbd4ef2534ed4557c5b55298a48625
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 18 03:11:41 2020 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Wed Mar 18 03:11:41 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=89c67a43

x11-misc/zim: Python 3.7 and 3.8

Closes: https://bugs.gentoo.org/712606
Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>
Package-Manager: Portage-2.3.92, Repoman-2.3.20

 x11-misc/zim/zim-0.72.1-r2.ebuild | 79 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 79 insertions(+)

diff --git a/x11-misc/zim/zim-0.72.1-r2.ebuild b/x11-misc/zim/zim-0.72.1-r2.ebuild
new file mode 100644
index 00000000000..51a1c261843
--- /dev/null
+++ b/x11-misc/zim/zim-0.72.1-r2.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="sqlite"
+DISTUTILS_SINGLE_IMPL=1
+inherit xdg-utils distutils-r1 virtualx
+
+DESCRIPTION="A desktop wiki"
+HOMEPAGE="
+	https://zim-wiki.org/
+	https://github.com/zim-desktop-wiki/zim-desktop-wiki
+"
+SRC_URI="https://github.com/${PN}-desktop-wiki/${PN}-desktop-wiki/archive/${PV/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+RESTRICT="test"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+		dev-python/pyxdg[${PYTHON_MULTI_USEDEP}]
+	')
+	x11-libs/gtk+:3[introspection]
+	x11-misc/xdg-utils
+"
+DEPEND="
+	${RDEPEND}
+"
+DOCS=( CHANGELOG.md CONTRIBUTING.md PLUGIN_WRITING.md README.md )
+PATCHES=( "${FILESDIR}"/${PN}-0.60-remove-ubuntu-theme.patch )
+S=${WORKDIR}/${PN}-desktop-wiki-${PV/_/-}
+
+python_prepare_all() {
+	sed -i -e "s/'USER'/'LOGNAME'/g" zim/__init__.py zim/fs.py || die
+
+	if [[ ${LINGUAS} ]]; then
+		local lingua
+		for lingua in translations/*.po; do
+			lingua=${lingua/.po}
+			lingua=${lingua/translations\/}
+			has ${lingua} ${LINGUAS} || \
+				{ rm translations/${lingua}.po || die; }
+		done
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_install() {
+	distutils-r1_python_install
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+	if ! has_version ${CATEGORY}/${PN}; then
+		elog "Please install these packages for additional functionality"
+		elog "    dev-lang/R"
+		elog "    dev-python/gtkspell-python"
+		elog "    dev-vcs/bzr"
+		elog "    media-gfx/graphviz"
+		elog "    media-gfx/imagemagick"
+		elog "    media-gfx/scrot"
+		elog "    media-sound/lilypond"
+		elog "    sci-visualization/gnuplot"
+		elog "    virtual/latex-base app-text/dvipng"
+	fi
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}