[gentoo-commits] repo/gentoo:master commit in: dev-util/vulkan-tools/

["Matt Turner" <mattst88@gentoo.org>]

commit:     316142af196db16fe9d5dfefd041e8b0746b77a4
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 11 19:52:47 2020 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Mar 15 21:28:39 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=316142af

dev-util/vulkan-tools: Fix 1.2.133, copying over from 9999

Use actual 1.2.133 upstream tarball.

Closes: https://bugs.gentoo.org/712090
Package-Manager: Portage-2.3.93, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-util/vulkan-tools/Manifest                     |  1 +
 .../vulkan-tools/vulkan-tools-1.2.133-r1.ebuild    | 81 ++++++++++++++++++++++
 2 files changed, 82 insertions(+)

diff --git a/dev-util/vulkan-tools/Manifest b/dev-util/vulkan-tools/Manifest
index 44a327d2acf..d5c60760e72 100644
--- a/dev-util/vulkan-tools/Manifest
+++ b/dev-util/vulkan-tools/Manifest
@@ -1,2 +1,3 @@
 DIST vulkan-tools-1.1.124.tar.gz 691639 BLAKE2B 6c40d8fd9498205bac9eedfc97486a0567f503847f5efff7d2e36563f72862b9a74e7d5b8c61e7d92822a4fbb91c24ee72614f7efb85aff68d4dbda42e09c422 SHA512 9f1f5dad1a5a847dc2fcc43382ee86f19a4c4b97c300f096b3cb33852378fcb260c33e6e920e9b70839a726bd6473ccceb8ef7504a530a3553dcb30c3ac74421
 DIST vulkan-tools-1.2.133.tar.gz 691639 BLAKE2B 6c40d8fd9498205bac9eedfc97486a0567f503847f5efff7d2e36563f72862b9a74e7d5b8c61e7d92822a4fbb91c24ee72614f7efb85aff68d4dbda42e09c422 SHA512 9f1f5dad1a5a847dc2fcc43382ee86f19a4c4b97c300f096b3cb33852378fcb260c33e6e920e9b70839a726bd6473ccceb8ef7504a530a3553dcb30c3ac74421
+DIST vulkan-tools-1.2.133a.tar.gz 698176 BLAKE2B 55f1b298a5daf7c656492c75999002aa54811df448f635e6d0c95cf717ae00c8d8158c39557c3c646281f1b763a848716d1a4429540a5a3a137462e355338427 SHA512 3f7a431b6889e2d62d16105b928707b9ae9d77515398284bfde8ced7b0741523f0b37c281c789d5c786c089854010edb9c7b18ed373f342ca0db7533ec9fd698

diff --git a/dev-util/vulkan-tools/vulkan-tools-1.2.133-r1.ebuild b/dev-util/vulkan-tools/vulkan-tools-1.2.133-r1.ebuild
new file mode 100644
index 00000000000..ff7a561dba6
--- /dev/null
+++ b/dev-util/vulkan-tools/vulkan-tools-1.2.133-r1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=Vulkan-Tools
+CMAKE_ECLASS="cmake"
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/v${PV}.tar.gz -> ${P}a.tar.gz"
+	KEYWORDS="~amd64 ~ppc64"
+	S="${WORKDIR}"/${MY_PN}-${PV}
+fi
+
+DESCRIPTION="Official Vulkan Tools and Utilities for Windows, Linux, Android, and MacOS"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Tools"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="cube wayland +X"
+
+# Cube demo only supports one window system at a time
+REQUIRED_USE="!cube? ( || ( X wayland ) ) cube? ( ^^ ( X wayland ) )"
+
+BDEPEND="${PYTHON_DEPS}
+	>=dev-util/cmake-3.10.2
+	cube? ( dev-util/glslang:=[${MULTILIB_USEDEP}] )
+"
+RDEPEND="
+	>=media-libs/vulkan-loader-${PV}:=[${MULTILIB_USEDEP},wayland?,X?]
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-util/vulkan-headers-${PV}
+"
+
+pkg_setup() {
+	MULTILIB_CHOST_TOOLS=(
+		/usr/bin/vulkaninfo
+	)
+
+	use cube && MULTILIB_CHOST_TOOLS+=(
+		/usr/bin/vkcube
+		/usr/bin/vkcubepp
+	)
+
+	python-any-r1_pkg_setup
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_VULKANINFO=ON
+		-DBUILD_CUBE=$(usex cube)
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DVULKAN_HEADERS_INSTALL_DIR="${EPREFIX}/usr"
+	)
+
+	use cube && mycmakeargs+=(
+		-DGLSLANG_INSTALL_DIR="${EPREFIX}/usr"
+		-DCUBE_WSI_SELECTION=$(usex X XCB WAYLAND)
+	)
+
+	cmake_src_configure
+}
+
+multilib_src_install() {
+	cmake_src_install
+}