[gentoo-commits] repo/gentoo:master commit in: gnome-base/gnome-control-center/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     2725f640f0bf61f9e10462605fd6e3243a85c884
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 15 19:33:10 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Mar 15 19:37:12 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2725f640

gnome-base/gnome-control-center: bump to 3.34.4

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-base/gnome-control-center/Manifest           |   2 +
 .../gnome-control-center-3.34.4.ebuild             | 178 +++++++++++++++++++++
 2 files changed, 180 insertions(+)

diff --git a/gnome-base/gnome-control-center/Manifest b/gnome-base/gnome-control-center/Manifest
index fff06d340c3..becad0521a7 100644
--- a/gnome-base/gnome-control-center/Manifest
+++ b/gnome-base/gnome-control-center/Manifest
@@ -2,3 +2,5 @@ DIST gnome-control-center-3.30.3-patchset.tar.xz 65244 BLAKE2B d210f94e0058e6284
 DIST gnome-control-center-3.30.3.tar.xz 5889900 BLAKE2B a03153cb689edc3c8c96a0f184f8831a8df218691fefd035842170871eebb6f17e34405e7c4c18da6a191b92c7b58fcd40b252cdb67154becdf7e7ac6a63aa8f SHA512 85c7b51d6bc32f73d7f4ad6df8d4cc14c59e19da88d7a17b7337f995483f41008213ca829247a3c9db43c4b31eae0be321ed6804570660fbe0356da3dd0948dc
 DIST gnome-control-center-3.32.2-patchset.tar.xz 62920 BLAKE2B 0268c048317c0ef267b1606b5eb85a40bff4f59a0baa8876cf1c893b96513c51708edeeb965933d54fe345bbce3e255e889c45eef98147b32d3d1208bf049fc9 SHA512 458ea50c1e95e2e005a1dbeb3c1d1a82d3399909a1367ad827ee3c5cef14cd3ecdfe27bc17bf24d6b037e1eae00df3235a75d0154178203b177b05b8d0688e6c
 DIST gnome-control-center-3.32.2.tar.xz 5953072 BLAKE2B 98206c6c7fd8fdca8bb6ba7c1178eacaa6e3364380c6faf7b1e98c0819c440e16d35f4299d323c27db8271a161be84e4e7520a4b8b03c4d654d195b25c93cdc6 SHA512 6f69f72e15d901935bd2fba90e0a598e6c6463d4b0f914d2a9c330c77378a461c8da86f198408045c07de370d3c1558046323a4c23a97ceed96602597e167c78
+DIST gnome-control-center-3.34.4-patchset.tar.xz 76008 BLAKE2B e66888fc0813508a8bd93677610d5c0d6abc474276dc4b37d7743fc5983e7c5ecacbd47078a81bef8d67b9ad0a32e452ee0f74a2e83c1b2998f5bf910ba21c43 SHA512 75b963c8fa3ce353efbfeb9ffa0d08c09febde01d548973e5d3c4fdc56dd156c091b645c07e9d56020cfbba9f9ab3752081f01bef4fb2527bb0f933bd9d659fb
+DIST gnome-control-center-3.34.4.tar.xz 6202616 BLAKE2B 41ab7ca34f930233f8b7bff06215df551765381accf16239d6515cabec8f106477e8895592278773d5b741f608c6cb3a2a70daf15bc4598dadd5ab967796ee8a SHA512 51c78766e6cfb02258f5e92dfe3b97c8a712e82290e7403c43b7abeb18af8d22addbabb7f2035782e4a90e45b464c8f3e7e65a4a610f27b79c2bedca8c822158

diff --git a/gnome-base/gnome-control-center/gnome-control-center-3.34.4.ebuild b/gnome-base/gnome-control-center/gnome-control-center-3.34.4.ebuild
new file mode 100644
index 00000000000..127c385c6ef
--- /dev/null
+++ b/gnome-base/gnome-control-center/gnome-control-center-3.34.4.ebuild
@@ -0,0 +1,178 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 xdg
+
+DESCRIPTION="GNOME's main interface to configure various aspects of the desktop"
+HOMEPAGE="https://git.gnome.org/browse/gnome-control-center/"
+SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="2"
+IUSE="+bluetooth +cups debug elogind flickr +gnome-online-accounts +ibus input_devices_wacom kerberos networkmanager systemd test v4l wayland"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	flickr? ( gnome-online-accounts )
+	^^ ( elogind systemd )
+" # Theoretically "?? ( elogind systemd )" is fine too, lacking some functionality at runtime, but needs testing if handled gracefully enough
+KEYWORDS="~amd64 ~arm64 ~ia64 ~ppc ~ppc64 ~x86"
+
+# kerberos unfortunately means mit-krb5; build fails with heimdal
+# display panel requires colord and gnome-settings-daemon[colord]
+# wacom panel requires gsd-enums.h from gsd at build time, probably also runtime support
+# printer panel requires cups and smbclient (the latter is not patched yet to be separately optional)
+# >=polkit-0.114 for .policy files gettext ITS
+# First block is toplevel meson.build deps in order of occurrence (plus deeper deps if in same conditional). Second block is dependency() from subdir meson.builds, sorted by directory name occurrence order
+DEPEND="
+	>=gui-libs/libhandy-0.0.9:0.0=
+	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.25.3:= )
+	>=media-sound/pulseaudio-2.0[glib]
+	>=sys-apps/accountsservice-0.6.39
+	>=x11-misc/colord-0.1.34:0=
+	>=x11-libs/gdk-pixbuf-2.23.0:2
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gnome-desktop-3.27.90:3=
+	>=gnome-base/gnome-settings-daemon-3.27.90[colord,input_devices_wacom?]
+	>=gnome-base/gsettings-desktop-schemas-3.31.0
+	dev-libs/libxml2:2
+	>=sys-auth/polkit-0.114
+	>=sys-power/upower-0.99.8:=
+	dev-libs/libgudev
+	x11-libs/libX11
+	>=x11-libs/libXi-1.2
+	flickr? ( >=media-libs/grilo-0.3.0:0.3= )
+	>=x11-libs/gtk+-3.22.0:3[X,wayland=]
+	cups? (
+		>=net-print/cups-1.7[dbus]
+		>=net-fs/samba-4.0.0[client]
+	)
+	v4l? (
+		>=media-video/cheese-3.28.0 )
+	ibus? ( >=app-i18n/ibus-1.5.2 )
+	networkmanager? (
+		>=gnome-extra/nm-applet-1.8.0
+		>=net-misc/networkmanager-1.12.0:=[modemmanager]
+		>=net-misc/modemmanager-0.7.990 )
+	bluetooth? ( >=net-wireless/gnome-bluetooth-3.18.2:= )
+	input_devices_wacom? ( >=dev-libs/libwacom-0.27 )
+	kerberos? ( app-crypt/mit-krb5 )
+
+	x11-libs/cairo[glib]
+	>=x11-libs/colord-gtk-0.1.24
+	net-libs/libsoup:2.4
+	media-libs/fontconfig
+	gnome-base/libgtop:2=
+	>=sys-fs/udisks-2.1.8:2
+	app-crypt/libsecret
+	media-libs/gsound
+	>=dev-libs/libpwquality-1.2.2
+"
+# systemd/elogind USE flagged because package manager will potentially try to satisfy a
+# "|| ( systemd ( elogind openrc-settingsd)" via systemd if openrc-settingsd isn't already installed.
+# libgnomekbd needed only for gkbd-keyboard-display tool
+# gnome-color-manager needed for gcm-calibrate and gcm-viewer calls from color panel
+# <gnome-color-manager-3.1.2 has file collisions with g-c-c-3.1.x
+#
+# mouse panel needs a concrete set of X11 drivers at runtime, bug #580474
+# Also we need newer driver versions to allow wacom and libinput drivers to
+# not collide
+#
+# system-config-printer provides org.fedoraproject.Config.Printing service and interface
+# cups-pk-helper provides org.opensuse.cupspkhelper.mechanism.all-edit policykit helper policy
+RDEPEND="${DEPEND}
+	systemd? ( >=sys-apps/systemd-31 )
+	elogind? ( app-admin/openrc-settingsd
+		sys-auth/elogind )
+	x11-themes/adwaita-icon-theme
+	>=gnome-extra/gnome-color-manager-3.1.2
+	cups? (
+		app-admin/system-config-printer
+		net-print/cups-pk-helper )
+	>=gnome-base/libgnomekbd-3
+	wayland? ( dev-libs/libinput )
+	!wayland? (
+		>=x11-drivers/xf86-input-libinput-0.19.0
+		input_devices_wacom? ( >=x11-drivers/xf86-input-wacom-0.33.0 ) )
+	flickr? ( media-plugins/grilo-plugins:0.3[flickr,gnome-online-accounts] )
+
+	!<gnome-base/gdm-2.91.94
+	!gnome-extra/gnome-media[pulseaudio]
+	!<gnome-extra/gnome-media-2.32.0-r300
+	!<net-wireless/gnome-bluetooth-3.3.2
+"
+# PDEPEND to avoid circular dependency; gnome-session-check-accelerated called by info panel
+# gnome-session-2.91.6-r1 also needed so that 10-user-dirs-update is run at login
+PDEPEND=">=gnome-base/gnome-session-2.91.6-r1"
+
+BDEPEND="
+	dev-libs/libxslt
+	app-text/docbook-xsl-stylesheets
+	app-text/docbook-xml-dtd:4.2
+	x11-base/xorg-proto
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? ( $(python_gen_any_dep '
+		dev-python/dbusmock[${PYTHON_USEDEP}]
+	') )
+"
+
+PATCHES=(
+	# Patches from gnome-3-32 branch on top of 3.32.2
+	# Makes some panels and dependencies optional
+	# https://bugzilla.gnome.org/686840, 697478, 700145
+	# Fix some absolute paths to be appropriate for Gentoo
+	"${WORKDIR}"/patches/
+
+	"${FILESDIR}"/${PN}-3.32.2-fix-gcc10-fno-common.patch # fixed in 3.35.90
+)
+
+python_check_deps() {
+	use test && \
+		has_version "dev-python/dbusmock[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	xdg_src_prepare
+	# Mark python tests with shebang executable, so that meson will launch them directly, instead
+	# of via its own python-single-r1 version, which might not match what we get from python_check_deps
+	chmod a+x tests/network/test-network-panel.py tests/datetime/test-datetime.py || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use bluetooth)
+		$(meson_use v4l cheese)
+		-Dcups=$(usex cups enabled disabled)
+		-Ddocumentation=true # manpage
+		-Dgoa=$(usex gnome-online-accounts enabled disabled)
+		-Dgrilo=$(usex flickr enabled disabled)
+		$(meson_use ibus)
+		-Dkerberos=$(usex kerberos enabled disabled)
+		$(meson_use networkmanager network_manager)
+		$(meson_use debug tracing)
+		$(meson_use input_devices_wacom wacom)
+		#$(meson_use wayland) # doesn't do anything in 3.34 and 3.36 due to unified gudev handling code
+		# bashcompletions installed to $datadir/bash-completion/completions by v3.28.2, which is the same as $(get_bashcompdir)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}