[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-calculator/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     33e4460154e63319b6248ecbe9d7bb93b4147a23
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 14 22:31:40 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sat Mar 14 22:32:34 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=33e44601

gnome-extra/gnome-calculator: bump to 3.34.1

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-extra/gnome-calculator/Manifest              |  1 +
 .../gnome-calculator-3.34.1.ebuild                 | 62 ++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/gnome-extra/gnome-calculator/Manifest b/gnome-extra/gnome-calculator/Manifest
index 1166798db88..6925defa3ab 100644
--- a/gnome-extra/gnome-calculator/Manifest
+++ b/gnome-extra/gnome-calculator/Manifest
@@ -1 +1,2 @@
 DIST gnome-calculator-3.32.2.tar.xz 947096 BLAKE2B 7c511e4d22971b008587aaa9ee7a44bfa663b663ebaddd6b5d4426f673e0f8975506c3b6aaba2781e3ccbe9ab7b9eb9b9d876c1b8acae9e14b195bfbeb207c42 SHA512 ef30ddad8b68367f71c2b894f041affe2b88c8aa90ad40d6128d03e0dc4871fd57d632809a365b14bac0b53dad37a73df564d237b8f45d4c42c38e118cb26de1
+DIST gnome-calculator-3.34.1.tar.xz 965520 BLAKE2B 7dd7af4d2065aee9a8962983ebf723aa06e4b2e3ef98213a89044d70e47057a747a88fdd58185abb272589433f84a6fcd3a3c5fd7dc0281d13f34ccaba690b50 SHA512 43900cebc6b479292a45619f1e4f6afc5264e2dceda5d0049b59f27ebe2a32b5f4b2465a22f33b33b882ab0e737f7048fbe9395b18f9b5d2023da2941b6783f6

diff --git a/gnome-extra/gnome-calculator/gnome-calculator-3.34.1.ebuild b/gnome-extra/gnome-calculator/gnome-calculator-3.34.1.ebuild
new file mode 100644
index 00000000000..bffb0d5c654
--- /dev/null
+++ b/gnome-extra/gnome-calculator/gnome-calculator-3.34.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_MAX_API_VERSION="0.44"
+inherit gnome.org gnome2-utils meson vala xdg
+
+DESCRIPTION="A calculator application for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Calculator"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+introspection"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+# gtksourceview vapi definitions in dev-lang/vala itself are too old, and newer vala removes them
+# altogether, thus we need them installed by gtksourceview[vala]
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2
+	dev-libs/libxml2:2
+	>=net-libs/libsoup-2.42:2.4
+	>=dev-libs/libgee-0.20.0:0.8
+	dev-libs/mpc:=
+	dev-libs/mpfr:0=
+	>=x11-libs/gtk+-3.19.3:3
+	>=x11-libs/gtksourceview-4.0.2:4
+	introspection? ( >=dev-libs/gobject-introspection-1.58:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	$(vala_depend)
+	net-libs/libsoup:2.4[vala]
+	x11-libs/gtksourceview:4[vala]
+"
+
+src_prepare() {
+	xdg_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddisable-ui=false
+		#-Dvala-version # doesn't do anything in 3.34
+		$(meson_use !introspection disable-introspection)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}