[gentoo-commits] repo/gentoo:master commit in: dev-python/pyqrcode/

["Michał Górny" <mgorny@gentoo.org>]

commit:     e27be08d4e93cf2816362123a74e774a4897dc5c
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Mar  9 09:58:10 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Mar  9 10:16:54 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e27be08d

dev-python/pyqrcode: Modernize, enable tests, py3.{7,8}

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pyqrcode/Manifest                 |  2 +-
 dev-python/pyqrcode/pyqrcode-1.2.1-r1.ebuild | 37 ++++++++++++++++++++++++++++
 dev-python/pyqrcode/pyqrcode-1.2.1.ebuild    | 28 ---------------------
 3 files changed, 38 insertions(+), 29 deletions(-)

diff --git a/dev-python/pyqrcode/Manifest b/dev-python/pyqrcode/Manifest
index 9f1a0d78ee7..69a4e310243 100644
--- a/dev-python/pyqrcode/Manifest
+++ b/dev-python/pyqrcode/Manifest
@@ -1 +1 @@
-DIST pyqrcode-1.2.1.tar.gz 36989 BLAKE2B 88d5274a503abd78d0b8cab462d12be0af925a5eee2a6ad2b47a276559710eac40643a8aec99f26a9579f94e9084182894163e7e71f0abd486c5c2913e510080 SHA512 784262cb15c10f3581b0caeac6bba046686b35b8c0709ee78684b805b6cba49f4250a004dc5f7d393cc25929cbf815c6c3a94e284a77d20ff7224a8dde3a036a
+DIST pyqrcode-1.2.1.gh.tar.gz 63404 BLAKE2B b192c55f3e6fb5c6d2c5f245d34fc909fbaaa582586a2a60526a98fb83079136358a0012d98e0772fb73eecb5133fecb643525fae05de8eede10b6f7a6662f08 SHA512 87a307e57d470153b37cccd3e79c8e04fc8de63cc7ffce313a7cc7d7e7f53b2979125ac3680a4b261fe0eeffd476e7934fa189a679f9370d690113811cc750b8

diff --git a/dev-python/pyqrcode/pyqrcode-1.2.1-r1.ebuild b/dev-python/pyqrcode/pyqrcode-1.2.1-r1.ebuild
new file mode 100644
index 00000000000..50803e75ddd
--- /dev/null
+++ b/dev-python/pyqrcode/pyqrcode-1.2.1-r1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit distutils-r1
+
+# upstream doesn't do tags
+EGIT_COMMIT="674a77b5eaf850d063f518bd90c243ee34ad6b5d"
+
+DESCRIPTION="A pure Python QR code generator with SVG, EPS, PNG and terminal output"
+HOMEPAGE="https://github.com/mnooner256/pyqrcode https://pypi.org/project/PyQRCode/"
+SRC_URI="https://github.com/mnooner256/pyqrcode/archive/${EGIT_COMMIT}.tar.gz -> ${P}.gh.tar.gz"
+S=${WORKDIR}/${PN}-${EGIT_COMMIT}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 arm ~arm64 x86 ~amd64-linux ~x86-linux"
+IUSE="png"
+
+RDEPEND="
+	png? ( dev-python/pypng[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	test? ( dev-python/pypng[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_tests nose
+
+src_prepare() {
+	# don't pull in tkinter for one test
+	sed -i -e 's:test_xbm_with_tkinter:_&:' \
+		tests/test_xbm.py || die
+
+	distutils-r1_src_prepare
+}

diff --git a/dev-python/pyqrcode/pyqrcode-1.2.1.ebuild b/dev-python/pyqrcode/pyqrcode-1.2.1.ebuild
deleted file mode 100644
index 1a10c8f1558..00000000000
--- a/dev-python/pyqrcode/pyqrcode-1.2.1.ebuild
+++ /dev/null
@@ -1,28 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-PYTHON_COMPAT=( python3_6)
-
-inherit distutils-r1
-
-MY_PN="PyQRCode"
-MY_P="${MY_PN}-${PV}"
-
-DESCRIPTION="A pure Python QR code generator with SVG, EPS, PNG and terminal output"
-HOMEPAGE="https://github.com/mnooner256/pyqrcode https://pypi.org/project/PyQRCode/"
-SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="amd64 arm ~arm64 x86 ~amd64-linux ~x86-linux"
-IUSE="png"
-
-RDEPEND="
-	png? ( dev-python/pypng[${PYTHON_USEDEP}] )
-"
-DEPEND="${RDEPEND}
-	dev-python/setuptools[${PYTHON_USEDEP}]
-"
-
-S=${WORKDIR}/${MY_P}