[gentoo-commits] repo/gentoo:master commit in: app-emulation/docker-compose/

["Sebastian Pipping" <sping@gentoo.org>]

commit:     fe3e64db0c2ad140ead9fe8f1c4781fed1c7adbc
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Sat Feb 29 22:35:10 2020 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Sat Feb 29 22:35:10 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fe3e64db

app-emulation/docker-compose: py37

Closes: https://bugs.gentoo.org/711092
Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>
Package-Manager: Portage-2.3.84, Repoman-2.3.20

 .../docker-compose/docker-compose-1.25.4-r1.ebuild | 68 ++++++++++++++++++++++
 1 file changed, 68 insertions(+)

diff --git a/app-emulation/docker-compose/docker-compose-1.25.4-r1.ebuild b/app-emulation/docker-compose/docker-compose-1.25.4-r1.ebuild
new file mode 100644
index 00000000000..b1caca0fcb1
--- /dev/null
+++ b/app-emulation/docker-compose/docker-compose-1.25.4-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 2018-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="Multi-container orchestration for Docker"
+HOMEPAGE="https://github.com/docker/compose"
+SRC_URI="https://github.com/docker/compose/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/cached-property-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/docker-py-3.7.0[${PYTHON_USEDEP}]
+	>=dev-python/dockerpty-0.4.1[${PYTHON_USEDEP}]
+	>=dev-python/docopt-0.6.1[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-2.5.1[${PYTHON_USEDEP}]
+	dev-python/paramiko[${PYTHON_USEDEP}]
+	>=dev-python/PySocks-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.20.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/texttable-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/websocket-client-0.32.0[${PYTHON_USEDEP}]"
+
+DEPEND="${RDEPEND}
+	test? (
+		<dev-python/pytest-4[${PYTHON_USEDEP}]
+		dev-python/ddt[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/compose-${PV}"
+
+PATCHES=(
+	# Bug #679968 -- https://bugs.gentoo.org/679968
+	# Bug #681002 -- https://bugs.gentoo.org/681002
+	"${FILESDIR}"/${PN}-1.25.2-setup-py.patch
+)
+
+src_prepare() {
+	# Address QA issue "docker-compose.exe: missing alias (symlink) for completed command."
+	sed 's,^\(complete.*\) docker-compose\.exe\(.*\),\1\2,' -i contrib/completion/bash/docker-compose || die
+
+	default
+}
+
+python_test() {
+	distutils_install_for_testing
+	${PYTHON} -m pytest tests/unit/ || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp contrib/completion/bash/docker-compose ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	doins contrib/completion/zsh/*
+
+	distutils-r1_python_install_all
+}