[gentoo-commits] repo/gentoo:master commit in: net-libs/gssdp/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     e3c0820abeb140209f2eb78770e19b5b1b0b9af0
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Thu Feb 20 09:25:34 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Fri Feb 21 20:56:29 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e3c0820a

net-libs/gssdp: bump to 1.2.2

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 net-libs/gssdp/Manifest           |  1 +
 net-libs/gssdp/gssdp-1.2.2.ebuild | 62 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/net-libs/gssdp/Manifest b/net-libs/gssdp/Manifest
index 66dafa5a2f1..d7903e9e8cd 100644
--- a/net-libs/gssdp/Manifest
+++ b/net-libs/gssdp/Manifest
@@ -1 +1,2 @@
 DIST gssdp-1.0.3.tar.xz 316740 BLAKE2B 50293e653ec5596a986770f3ea81a244b8f9772e9d0c13df0e48f00ee34445c2fc7250702d7928e7dba081715e6d4e379d7a899905c35da84915e6b4058a3307 SHA512 ef72335c3f796aff0d3dce1781d5a0b015508f614d4a73699ebce411b0593419b40c09839ffb62e50cf9d77e16ec0e31d0e23f92d35abb4d105dea47c00a0506
+DIST gssdp-1.2.2.tar.xz 61444 BLAKE2B 917936ba61ef6074939a11792ddb4f3baf0bd88475df7e49fd6e598dc2530610f04661a4b5efcb2a024e0d37011bfab32bcffd644d2a3be2eb1325c9020b73bf SHA512 3d962ac5a633492979d49c722bbbbeec88385fdbd063d3b68f6b82edbc62c9e78c556d48a904460dd04328bf7a79668dcf3ee33bf61a271ac926e01e2e645f68

diff --git a/net-libs/gssdp/gssdp-1.2.2.ebuild b/net-libs/gssdp/gssdp-1.2.2.ebuild
new file mode 100644
index 00000000000..bcdb978cc30
--- /dev/null
+++ b/net-libs/gssdp/gssdp-1.2.2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome.org meson multilib-minimal vala xdg
+
+DESCRIPTION="GObject-based API for handling resource discovery and announcement over SSDP"
+HOMEPAGE="https://wiki.gnome.org/Projects/GUPnP"
+
+LICENSE="LGPL-2+"
+SLOT="0/1.2-0" # <API version>-<soname>
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="gtk-doc +introspection gtk vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	>=dev-libs/glib-2.54:2[${MULTILIB_USEDEP}]
+	>=net-libs/libsoup-2.26.1:2.4[${MULTILIB_USEDEP},introspection?]
+	gtk? ( >=x11-libs/gtk+-3.12:3 )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	gtk-doc? ( >=dev-util/gtk-doc-1.14
+		app-text/docbook-xml-dtd:4.1.2 )
+	>=sys-devel/gettext-0.19.8
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+	vala? (
+		$(vala_depend)
+		net-libs/libsoup:2.4[vala]
+	)
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	xdg_src_prepare
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Dgtk_doc=$(multilib_native_usex gtk-doc true false)
+		-Dsniffer=$(multilib_native_usex gtk true false)
+		-Dintrospection=$(multilib_native_usex introspection true false)
+		-Dvapi=$(multilib_native_usex vala true false)
+		-Dexamples=false
+	)
+	meson_src_configure
+}
+
+multilib_src_compile() {
+	meson_src_compile
+}
+
+multilib_src_test() {
+	meson_src_test
+}
+
+multilib_src_install() {
+	meson_src_install
+}