[gentoo-commits] repo/gentoo:master commit in: dev-python/pyro/

["Michał Górny" <mgorny@gentoo.org>]

commit:     73f57f0ffb4e4338cd9bc04d9d460fb5b9cf63e8
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 16 05:33:04 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Feb 16 06:29:46 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=73f57f0f

dev-python/pyro: Bump to 4.79

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pyro/Manifest         |  1 +
 dev-python/pyro/pyro-4.79.ebuild | 65 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/dev-python/pyro/Manifest b/dev-python/pyro/Manifest
index 2f2d13df116..4fb2efd665e 100644
--- a/dev-python/pyro/Manifest
+++ b/dev-python/pyro/Manifest
@@ -1,2 +1,3 @@
 DIST Pyro4-4.77.tar.gz 479025 BLAKE2B 20c7b53cea55b77efea11cd7b74a1cfcc45ad721ba45e039947f1d869291bfcb054f16bc48fb5ad21386fe7d47785514ff94953b1bcf893266c2c41015bba589 SHA512 52a9f90cec8c5e23ec30ddb69484a15bb86d61024d1bc718d075e01678a3d9655a1ed21f18da1891c121bf0e95282fb1151762b2fdb826a6408056079d2b1a66
 DIST Pyro4-4.78.tar.gz 490988 BLAKE2B 0fbd7129557d2b1603176a34106f9e287faa6e1725eeede7a7427c0b975f2c4e136dc4ce1573e826c43211a903fee0d7baca85fb8ae58360da7869a3309a1a2d SHA512 7a95828f6c8d9d94b8a5263c63263335c3bfaa54c5e527bd8e61d2bc00d4cdb3c4c6a92155af189401b892a6729ad91dad207e389ff43ee342a011b95ddc90e5
+DIST Pyro4-4.79.tar.gz 490917 BLAKE2B 421fa2d0b32c27c44d11adb7c89e24cfd7a79c10ae40827407d3d8965e98b7d5126168e5b00b042c4bd94800d3e73fc8febdbbbf2b82d3046584ea88106c4734 SHA512 03e75537c7943e1044b7e6623ead934e3004b023ffc6d364472868e0895e3819c4b3c92d1610018ab1466262f32681e69a91d360c33b17e687861c8c742bdf72

diff --git a/dev-python/pyro/pyro-4.79.ebuild b/dev-python/pyro/pyro-4.79.ebuild
new file mode 100644
index 00000000000..493fa5c46b9
--- /dev/null
+++ b/dev-python/pyro/pyro-4.79.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+MY_PN="Pyro4"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Distributed object middleware for Python (RPC)"
+HOMEPAGE="https://pypi.org/project/Pyro4/
+	https://github.com/irmen/Pyro4"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="4"
+KEYWORDS="~amd64 ~arm64 ~ppc ~x86"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!dev-python/pyro:0
+	$(python_gen_cond_dep \
+		'dev-python/selectors34[${PYTHON_USEDEP}]' -2)
+	>=dev-python/serpent-1.27[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		>=dev-python/cloudpickle-1.2.1[${PYTHON_USEDEP}]
+		dev-python/dill[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.4.6[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# Disable tests requiring network connection.
+	rm tests/PyroTests/test_naming.py || die
+	sed \
+		-e "s/testStartNSfunc/_&/" \
+		-i tests/PyroTests/test_naming2.py || die
+
+	sed \
+		-e "s/testBroadcast/_&/" \
+		-e "s/testGetIP/_&/" \
+		-i tests/PyroTests/test_socket.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/. )
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}