[gentoo-commits] repo/gentoo:master commit in: media-video/pymp/

[gentoo-commits] repo/gentoo:master commit in: media-video/pymp/

[Michał Górny]

commit:     373cf0c1a4d9f2217450aec6de39b00e40f68805
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Feb 20 22:32:28 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Feb 21 08:51:44 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=373cf0c1

media-video/pymp: python-single-r1, EAPI=6

 media-video/pymp/pymp-1.1-r1.ebuild | 44 ++++++++++++++++++++++++++++++++++
 media-video/pymp/pymp-1.1.ebuild    | 48 -------------------------------------
 2 files changed, 44 insertions(+), 48 deletions(-)

diff --git a/media-video/pymp/pymp-1.1-r1.ebuild b/media-video/pymp/pymp-1.1-r1.ebuild
new file mode 100644
index 0000000000..950711322d
--- /dev/null
+++ b/media-video/pymp/pymp-1.1-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+inherit eutils python-single-r1
+
+DESCRIPTION="a lean, flexible frontend to mplayer written in python"
+HOMEPAGE="http://jdolan.dyndns.org/trac/wiki/Pymp"
+SRC_URI="http://jdolan.dyndns.org/jaydolan/files/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86 ~amd64-fbsd"
+IUSE=""
+
+RDEPEND="media-video/mplayer
+	dev-python/pygtk[${PYTHON_USEDEP}]
+	${PYTHON_DEPS}"
+DEPEND="sys-apps/sed"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+src_compile() {
+	python_fix_shebang pymp.py
+}
+
+src_install() {
+	python_moduleinto /usr/lib/pymp
+	python_domodule *.py
+
+	# note: pymp script is a horrible unnecessary wrapper
+	# a) with a dependency on sys-apps/which;
+	# b) that invokes compiled .pyc directly
+	# do not use it
+	dodir /usr/bin
+	dosym ../lib/pymp/pymp.py /usr/bin/pymp
+	fperms +x /usr/lib/pymp/pymp.py
+
+	dodoc CHANGELOG README
+	doicon pymp.png
+	make_desktop_entry pymp Pymp pymp
+}

diff --git a/media-video/pymp/pymp-1.1.ebuild b/media-video/pymp/pymp-1.1.ebuild
deleted file mode 100644
index 45f0b0c24b..0000000000
--- a/media-video/pymp/pymp-1.1.ebuild
+++ /dev/null
@@ -1,48 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=3
-PYTHON_DEPEND="2:2.5"
-inherit eutils multilib python
-
-DESCRIPTION="a lean, flexible frontend to mplayer written in python"
-HOMEPAGE="http://jdolan.dyndns.org/trac/wiki/Pymp"
-SRC_URI="http://jdolan.dyndns.org/jaydolan/files/${P}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 x86 ~amd64-fbsd"
-IUSE=""
-
-RDEPEND="media-video/mplayer
-	dev-python/pygtk"
-DEPEND="sys-apps/sed"
-
-pkg_setup() {
-	python_set_active_version 2
-	python_pkg_setup
-}
-
-src_prepare() {
-	sed -i -e "s/python/python2/" -e "s:PREFIX/lib:/usr/$(get_libdir):" pymp || die "sed failed"
-}
-
-src_compile() { :; }
-
-src_install() {
-	dobin pymp || die "dobin failed"
-	insinto /usr/$(get_libdir)/pymp
-	doins *.py || die "doins failed"
-	dodoc CHANGELOG README
-	doicon pymp.png
-	make_desktop_entry pymp Pymp pymp
-}
-
-pkg_postinst() {
-	python_mod_optimize /usr/$(get_libdir)/pymp
-}
-
-pkg_postrm() {
-	python_mod_cleanup /usr/$(get_libdir)/pymp
-}

[gentoo-commits] repo/gentoo:master commit in: media-video/pymp/

[Michał Górny]

commit:     739d7c0319b26fbfaa2fe2e5cd56a9b3059b5bce
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Feb  7 16:58:22 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Feb  9 16:31:31 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=739d7c03

media-video/pymp: Switch to PYTHON_MULTI_USEDEP API

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 media-video/pymp/{pymp-1.1-r1.ebuild => pymp-1.1-r2.ebuild} | 6 ++++--
 1 file changed, 4 insertions(+), 2 deletions(-)

diff --git a/media-video/pymp/pymp-1.1-r1.ebuild b/media-video/pymp/pymp-1.1-r2.ebuild
similarity index 89%
rename from media-video/pymp/pymp-1.1-r1.ebuild
rename to media-video/pymp/pymp-1.1-r2.ebuild
index b9fb82683b7..2ce35400dcf 100644
--- a/media-video/pymp/pymp-1.1-r1.ebuild
+++ b/media-video/pymp/pymp-1.1-r2.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -15,7 +15,9 @@ KEYWORDS="amd64 x86"
 IUSE=""
 
 RDEPEND="media-video/mplayer
-	dev-python/pygtk[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/pygtk[${PYTHON_MULTI_USEDEP}]
+	')
 	${PYTHON_DEPS}"
 DEPEND="sys-apps/sed"