[gentoo-commits] repo/gentoo:master commit in: x11-misc/xsnap/

["Jeroen Roovers" <jer@gentoo.org>]

commit:     84b6cb6a3fb3828c5099fa76cc86ed20fc2775c8
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Sun Feb  2 20:15:54 2020 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Sun Feb  2 20:16:19 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=84b6cb6a

x11-misc/xsnap: Uncompress man pages

Package-Manager: Portage-2.3.87, Repoman-2.3.20
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 x11-misc/xsnap/xsnap-1.5.15-r2.ebuild | 69 +++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)

diff --git a/x11-misc/xsnap/xsnap-1.5.15-r2.ebuild b/x11-misc/xsnap/xsnap-1.5.15-r2.ebuild
new file mode 100644
index 00000000000..920e4a2ffcc
--- /dev/null
+++ b/x11-misc/xsnap/xsnap-1.5.15-r2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit toolchain-funcs
+
+DESCRIPTION="Program to interactively take a 'snapshot' of a region of the screen"
+HOMEPAGE="ftp://ftp.ac-grenoble.fr/ge/Xutils/"
+SRC_URI="ftp://ftp.ac-grenoble.fr/ge/Xutils/${P}.tar.bz2"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux"
+IUSE=""
+
+COMMON_DEPEND="
+	media-libs/libpng:0
+	virtual/jpeg:0
+	x11-libs/libX11
+	x11-libs/libXft
+	x11-libs/libXpm
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	media-fonts/font-misc-misc
+"
+DEPEND="
+	${COMMON_DEPEND}
+	app-text/rman
+	dev-lang/perl
+	x11-base/xorg-proto
+	x11-misc/imake
+"
+DOCS=( AUTHORS Changelog README )
+PATCHES=( "${FILESDIR}"/${P}-root_name.patch )
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e 's|/usr/share/locale|$(LOCALEDIR)|g' \
+		-e 's|/usr/share/man/man1|$(MANDIR)|g' \
+		-e '/cd po.*install/s|cd.*|$(MAKE) -C po LOCALEDIR=$(LOCALEDIR) install|' \
+		-e '21s|.*|LOCALEDIR = /usr/share/locale|' \
+		Imakefile || die
+	sed -i \
+		-e '/^LOCALEDIR=/d' \
+		po/Makefile || die
+
+	xmkmf || die
+
+	sed -i \
+		-e '/ CC = /d' \
+		-e '/ LD = /d' \
+		-e '/ CDEBUGFLAGS = /d' \
+		-e '/ CCOPTIONS = /d' \
+		-e 's|CPP = cpp|CPP = $(CC)|g' \
+		Makefile || die
+}
+
+src_compile() {
+	tc-export CC
+	emake CCOPTIONS="${CFLAGS}" EXTRA_LDOPTIONS="${LDFLAGS}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.1.gz' -exec gunzip {} \; || die
+}