From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1141772-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 94EF6138350
for <garchives@archives.gentoo.org>; Fri, 31 Jan 2020 08:50:25 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id B76ABE0875;
Fri, 31 Jan 2020 08:50:24 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 8469FE0875
for <gentoo-commits@lists.gentoo.org>; Fri, 31 Jan 2020 08:50:24 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 275ED34E5B8
for <gentoo-commits@lists.gentoo.org>; Fri, 31 Jan 2020 08:50:23 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id DEB997B
for <gentoo-commits@lists.gentoo.org>; Fri, 31 Jan 2020 08:50:13 +0000 (UTC)
From: "Tim Harder" <radhermit@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Tim Harder" <radhermit@gentoo.org>
Message-ID: <1580460569.e7ac086a44381ca195346f7ee20d9a58603057d3.radhermit@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-gfx/gmic/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-gfx/gmic/Manifest media-gfx/gmic/gmic-2.8.3.ebuild
X-VCS-Directories: media-gfx/gmic/
X-VCS-Committer: radhermit
X-VCS-Committer-Name: Tim Harder
X-VCS-Revision: e7ac086a44381ca195346f7ee20d9a58603057d3
X-VCS-Branch: master
Date: Fri, 31 Jan 2020 08:50:13 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 4cb2cd6e-4cb6-4d19-83dc-afe991d2c884
X-Archives-Hash: bbfc3d3271826d243b2c5258e2d3e973
commit: e7ac086a44381ca195346f7ee20d9a58603057d3
Author: Tim Harder <radhermit <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 31 08:48:00 2020 +0000
Commit: Tim Harder <radhermit <AT> gentoo <DOT> org>
CommitDate: Fri Jan 31 08:49:29 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e7ac086a
media-gfx/gmic: version bump to 2.8.3
Signed-off-by: Tim Harder <radhermit <AT> gentoo.org>
media-gfx/gmic/Manifest | 1 +
media-gfx/gmic/gmic-2.8.3.ebuild | 170 +++++++++++++++++++++++++++++++++++++++
2 files changed, 171 insertions(+)
diff --git a/media-gfx/gmic/Manifest b/media-gfx/gmic/Manifest
index 53b6fcfee55..e252f1e9e13 100644
--- a/media-gfx/gmic/Manifest
+++ b/media-gfx/gmic/Manifest
@@ -1,2 +1,3 @@
DIST gmic_2.8.1.tar.gz 5995556 BLAKE2B 3f3c35290d18c927745b4b527f5297a9c3beb109a34b7e8b70dcff064f2587e022616e0fe5063d79e94b8fbd0ce3f70b6b5417ebaa0f0cc0f61891d79330afa9 SHA512 0f9ae9454c6f053026cdace43b24e32183f384d79099bc654c3b154647d24ef6541b1fae62cb17e27e527fb51ed8cef03a46490af3ace1551646fc8b3cd64eb9
DIST gmic_2.8.2.tar.gz 6170087 BLAKE2B 36bea32531fef3694c4bf295603c2327dba2391f8cb868393d01a86dd9dcc52a127584e8eaeeba79425aceb07fd3ee31e0383a182eb0956daa920122463c4a08 SHA512 80fbba0dd1f02fe23986f57190e6e4bb0df31ac8b4084ddcfa088fcf352b44484ada47704b42c9cd27f52a55e42247447c73181c0a84a4f0e54f064e9fc9ca9a
+DIST gmic_2.8.3.tar.gz 6172645 BLAKE2B 51a910ca9bb146173863f7f72dafec8ed42334757223055a5e174bebbed9e23372e1fdeb5b522c2120b203f4cbac0f255a9ada58fa62c7f83c745016d11bcabb SHA512 cde0e3fc50a97dae2b6d1dac1e7292a3d0af5e963586ec3e7ab6890721bc9617ea80b3bc86ec4cdc897d8b4ddc0fde552eea8322f8f337c447c603bcbc1403fd
diff --git a/media-gfx/gmic/gmic-2.8.3.ebuild b/media-gfx/gmic/gmic-2.8.3.ebuild
new file mode 100644
index 00000000000..b9efdacb34d
--- /dev/null
+++ b/media-gfx/gmic/gmic-2.8.3.ebuild
@@ -0,0 +1,170 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_BUILD_TYPE=Release
+inherit cmake bash-completion-r1
+
+if [[ ${PV} == "9999" ]]; then
+ EGIT_REPO_URI="https://github.com/dtschump/gmic.git"
+ inherit git-r3
+else
+ SRC_URI="https://gmic.eu/files/source/${PN}_${PV}.tar.gz"
+ KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="GREYC's Magic Image Converter"
+HOMEPAGE="https://gmic.eu/ https://github.com/dtschump/gmic"
+
+LICENSE="CeCILL-2 GPL-3"
+SLOT="0"
+IUSE="+cli curl ffmpeg fftw gimp graphicsmagick jpeg krita opencv openexr openmp png qt5 static-libs tiff X zlib"
+REQUIRED_USE="
+ || ( cli gimp krita qt5 )
+ gimp? ( png zlib fftw X )
+ krita? ( png zlib fftw X )
+ qt5? ( png zlib fftw X )
+"
+
+MIN_QT_VER="5.2.0"
+QT_DEPEND="
+ >=dev-qt/qtcore-${MIN_QT_VER}:5=
+ >=dev-qt/qtgui-${MIN_QT_VER}:5=
+ >=dev-qt/qtnetwork-${MIN_QT_VER}:5=
+ >=dev-qt/qtwidgets-${MIN_QT_VER}:5=
+"
+COMMON_DEPEND="
+ curl? ( net-misc/curl )
+ fftw? ( sci-libs/fftw:3.0=[threads] )
+ gimp? (
+ >=media-gfx/gimp-2.8.0
+ ${QT_DEPEND}
+ )
+ graphicsmagick? ( media-gfx/graphicsmagick:0= )
+ jpeg? ( virtual/jpeg:0 )
+ krita? ( ${QT_DEPEND} )
+ opencv? ( >=media-libs/opencv-2.3.1a-r1:0= )
+ openexr? (
+ media-libs/ilmbase:0=
+ media-libs/openexr:0=
+ )
+ png? ( media-libs/libpng:0= )
+ qt5? ( ${QT_DEPEND} )
+ tiff? ( media-libs/tiff:0 )
+ X? (
+ x11-libs/libX11
+ x11-libs/libXext
+ )
+ zlib? ( sys-libs/zlib:0= )"
+RDEPEND="${COMMON_DEPEND}
+ ffmpeg? ( media-video/ffmpeg:0= )
+"
+DEPEND="${COMMON_DEPEND}
+ gimp? ( dev-qt/linguist-tools )
+ krita? ( dev-qt/linguist-tools )
+ qt5? ( dev-qt/linguist-tools )
+"
+BDEPEND="virtual/pkgconfig"
+
+pkg_pretend() {
+ if use openmp ; then
+ tc-has-openmp || die "Please switch to an openmp compatible compiler"
+ fi
+
+ if ! test-flag-CXX -std=c++11 ; then
+ die "You need at least GCC 4.7.x or Clang >= 3.3 for C++11-specific compiler flags"
+ fi
+}
+
+src_prepare() {
+ cmake_src_prepare
+ sed -i '/CMAKE_CXX_FLAGS/s/-g //' CMakeLists.txt || die
+
+ if use gimp || use krita || use qt5; then
+ # respect user flags
+ sed -e '/CMAKE_CXX_FLAGS_RELEASE/d' \
+ -e '/${CMAKE_EXE_LINKER_FLAGS} -s/d' \
+ -i gmic-qt/CMakeLists.txt || die
+ local S="${S}/gmic-qt"
+ cmake_src_prepare
+ fi
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DBUILD_LIB=ON
+ -DBUILD_LIB_STATIC=$(usex static-libs)
+ -DBUILD_CLI=$(usex cli)
+ -DBUILD_MAN=$(usex cli)
+ -DBUILD_BASH_COMPLETION=$(usex cli)
+ -DCUSTOM_CFLAGS=ON
+ -DENABLE_CURL=$(usex curl)
+ -DENABLE_X=$(usex X)
+ -DENABLE_FFMPEG=$(usex ffmpeg)
+ -DENABLE_FFTW=$(usex fftw)
+ -DENABLE_GRAPHICSMAGICK=$(usex graphicsmagick)
+ -DENABLE_JPEG=$(usex jpeg)
+ -DENABLE_OPENCV=$(usex opencv)
+ -DENABLE_OPENEXR=$(usex openexr)
+ -DENABLE_OPENMP=$(usex openmp)
+ -DENABLE_PNG=$(usex png)
+ -DENABLE_TIFF=$(usex tiff)
+ -DENABLE_ZLIB=$(usex zlib)
+ -DENABLE_DYNAMIC_LINKING=ON
+ )
+
+ cmake_src_configure
+
+ # configure gmic-qt frontends
+ local CMAKE_USE_DIR="${S}/gmic-qt"
+ mycmakeargs=(
+ -DENABLE_DYNAMIC_LINKING=ON
+ -DENABLE_CURL=$(usex curl)
+ -DGMIC_LIB_PATH="${BUILD_DIR}"
+ -DGMIC_PATH="${S}/src"
+ )
+
+ if use gimp; then
+ mycmakeargs+=( -DGMIC_QT_HOST=gimp )
+ BUILD_DIR="${BUILD_DIR}"/gimp cmake_src_configure
+ fi
+
+ if use krita; then
+ mycmakeargs+=( -DGMIC_QT_HOST=krita )
+ BUILD_DIR="${BUILD_DIR}"/krita cmake_src_configure
+ fi
+
+ if use qt5; then
+ mycmakeargs+=( -DGMIC_QT_HOST=none )
+ BUILD_DIR="${BUILD_DIR}"/qt5 cmake_src_configure
+ fi
+}
+
+src_compile() {
+ cmake_src_compile
+
+ # build gmic-qt frontends
+ local S="${S}/gmic-qt"
+ use gimp && { BUILD_DIR="${BUILD_DIR}"/gimp cmake_src_compile || die "failed building gimp plugin" ; }
+ use krita && { BUILD_DIR="${BUILD_DIR}"/krita cmake_src_compile || die "failed building krita plugin" ; }
+ use qt5 && { BUILD_DIR="${BUILD_DIR}"/qt5 cmake_src_compile || die "failed building qt5 GUI" ; }
+}
+
+src_install() {
+ cmake_src_install
+ dodoc README
+ use cli && newbashcomp "${BUILD_DIR}"/resources/gmic_bashcompletion.sh ${PN}
+
+ local PLUGINDIR="/usr/$(get_libdir)/gimp/2.0/plug-ins"
+ insinto "${PLUGINDIR}"
+ doins resources/gmic_cluts.gmz
+
+ # install gmic-qt frontends
+ if use gimp; then
+ exeinto "${PLUGINDIR}"
+ doexe "${BUILD_DIR}"/gimp/gmic_gimp_qt
+ fi
+ use krita && dobin "${BUILD_DIR}"/krita/gmic_krita_qt
+ use qt5 && dobin "${BUILD_DIR}"/qt5/gmic_qt
+}