[gentoo-commits] repo/gentoo:master commit in: dev-libs/appstream/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     7bcfa7c1060fcc3efb92d173b769c4c0934fda06
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 28 14:51:10 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Jan 28 15:11:39 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7bcfa7c1

dev-libs/appstream: 0.12.10 version bump

Package-Manager: Portage-2.3.85, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 dev-libs/appstream/Manifest                 |  1 +
 dev-libs/appstream/appstream-0.12.10.ebuild | 72 +++++++++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/dev-libs/appstream/Manifest b/dev-libs/appstream/Manifest
index 815369fce16..a9fc0a19339 100644
--- a/dev-libs/appstream/Manifest
+++ b/dev-libs/appstream/Manifest
@@ -1,2 +1,3 @@
+DIST AppStream-0.12.10.tar.xz 2045744 BLAKE2B fd8f96bd0b829e73bbbb5ae725feaf8f1275f2ed4a50ad107fddc52cdfd7d7c2e382235fc322513cdfe000789505e7b9998bb4e601e223d673ee65c0fbb55c25 SHA512 5cd7da7adbd035947bde6a6d7655dc2f7c1be25cef102e51ef88e8f684a83b196a41b440edaabdd89da69a9117a26dad30e548b86b50f324f0ba70eef95a6060
 DIST AppStream-0.12.7.tar.xz 1958948 BLAKE2B 51a70395e4801ceeb3e97ac081f4c45be242cca14728f8efc5eec0d4b3cfa4cc9fab9ef7429c18e9bbb0dedb693a847258be1b11491155658a6ffa2a28358e35 SHA512 53ca7ebde3fcd345a895527da2ac5d829a09f25d28836a867b500282fba3465bde657cd75a4030cb831022f7a0d9f50aadb36078d62924e4d0edad6bfe3c5561
 DIST AppStream-0.12.9.tar.xz 2023312 BLAKE2B aa5de7936909be54401e4df80363c9b59ad60dc29b3d02ef1ed8203dd480dfb4222816cde5ea6e469039448684142afc028275e619665f15cef99af6745d80e8 SHA512 af3d5e7885ee09fb6ef9ea0a5c2386141736166ce42912e618f1ee04f2b28866b27c7c5e326221574eb78933b32de8db9f76023bf54e528aded1607e5130992e

diff --git a/dev-libs/appstream/appstream-0.12.10.ebuild b/dev-libs/appstream/appstream-0.12.10.ebuild
new file mode 100644
index 00000000000..4d3a31bbb3b
--- /dev/null
+++ b/dev-libs/appstream/appstream-0.12.10.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson xdg-utils
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/ximion/${PN}"
+else
+	SRC_URI="https://www.freedesktop.org/software/appstream/releases/AppStream-${PV}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+	S="${WORKDIR}/AppStream-${PV}"
+fi
+
+DESCRIPTION="Cross-distro effort for providing metadata for software in the Linux ecosystem"
+HOMEPAGE="https://www.freedesktop.org/wiki/Distributions/AppStream/"
+
+LICENSE="LGPL-2.1+ GPL-2+"
+# check as_api_level
+SLOT="0/4"
+IUSE="apt doc +introspection qt5 test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-libs/libxslt
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	doc? ( app-text/docbook-xml-dtd:4.5 )
+	test? ( dev-qt/linguist-tools:5 )
+"
+RDEPEND="
+	dev-db/lmdb:=
+	>=dev-libs/glib-2.58:2
+	dev-libs/libxml2:2
+	dev-libs/libyaml
+	dev-libs/snowball-stemmer
+	>=net-libs/libsoup-2.56:2.4
+	introspection? ( >=dev-libs/gobject-introspection-1.56:= )
+	qt5? ( dev-qt/qtcore:5 )
+"
+DEPEND="${RDEPEND}
+	test? ( qt5? ( dev-qt/qttest:5 ) )
+"
+
+src_prepare() {
+	default
+	sed -e "/^as_doc_target_dir/s/appstream/${PF}/" -i docs/meson.build || die
+	if ! use test; then
+		sed -e "/^subdir.*tests/s/^/#DONT /" -i {,qt/}meson.build || die # bug 675944
+	fi
+}
+
+src_configure() {
+	xdg_environment_reset
+
+	local emesonargs=(
+		-Dapidocs=false
+		-Ddocs=false
+		-Dmaintainer=false
+		-Dstemming=true
+		-Dvapi=false
+		-Dapt-support=$(usex apt true false)
+		-Dinstall-docs=$(usex doc true false)
+		-Dgir=$(usex introspection true false)
+		-Dqt=$(usex qt5 true false)
+	)
+
+	meson_src_configure
+}