[gentoo-commits] repo/gentoo:master commit in: media-video/baka-mplayer/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     8b112e56d0bc13c6972f9db4e1fe626f4531ff17
Author:     Christopher Steward <cstew764 <AT> gmail <DOT> com>
AuthorDate: Mon Dec  9 15:05:52 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Jan 21 19:10:49 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8b112e56

media-video/baka-mplayer: New live ebuild

Package has been updated with some bug fixes on git
but has not had a release in a while.

Signed-off-by: Christopher Steward <cstew764 <AT> gmail.com>
Package-Manager: Portage-2.3.79, Repoman-2.3.16
Closes: https://github.com/gentoo/gentoo/pull/13929
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-video/baka-mplayer/baka-mplayer-9999.ebuild | 48 +++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/media-video/baka-mplayer/baka-mplayer-9999.ebuild b/media-video/baka-mplayer/baka-mplayer-9999.ebuild
new file mode 100644
index 00000000000..73e27a96b7c
--- /dev/null
+++ b/media-video/baka-mplayer/baka-mplayer-9999.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qmake-utils git-r3
+
+DESCRIPTION="Cross-platform libmpv-based multimedia player with uncluttered design"
+HOMEPAGE="http://bakamplayer.u8sand.net/"
+EGIT_REPO_URI="https://github.com/u8sand/Baka-MPlayer.git"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE=""
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig"
+
+RDEPEND="dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-video/mpv[libmpv]
+	x11-libs/libX11"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/baka-mplayer-${PV}"
+
+src_prepare() {
+	default
+	# no need to install license
+	sed -e '/^INSTALLS/s:license::' -i src/Baka-MPlayer.pro || die
+	# put manual in our docdir
+	sed -e '/^manual.path/s:'${PN}':'${PF}':' -i src/Baka-MPlayer.pro || die
+}
+
+src_configure() {
+	eqmake5 \
+		INSTROOT="${D}" \
+		CONFIG+=install_translations \
+		lrelease="$(qt5_get_bindir)"/lrelease \
+		lupdate="$(qt5_get_bindir)"/lupdate \
+		src/Baka-MPlayer.pro
+}