From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1139120-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 571E8138350
for <garchives@archives.gentoo.org>; Mon, 20 Jan 2020 10:23:55 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 89EBCE0950;
Mon, 20 Jan 2020 10:23:54 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 5800DE0950
for <gentoo-commits@lists.gentoo.org>; Mon, 20 Jan 2020 10:23:54 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 1721A34E2CB
for <gentoo-commits@lists.gentoo.org>; Mon, 20 Jan 2020 10:23:53 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 76FA57E
for <gentoo-commits@lists.gentoo.org>; Mon, 20 Jan 2020 10:23:51 +0000 (UTC)
From: "Michael Palimaka" <kensington@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Michael Palimaka" <kensington@gentoo.org>
Message-ID: <1579515773.3aff69cf5a9cb540cfde8a3617774b93a676d319.kensington@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: sys-libs/libapparmor/
X-VCS-Repository: repo/gentoo
X-VCS-Files: sys-libs/libapparmor/libapparmor-2.13.3-r1.ebuild
X-VCS-Directories: sys-libs/libapparmor/
X-VCS-Committer: kensington
X-VCS-Committer-Name: Michael Palimaka
X-VCS-Revision: 3aff69cf5a9cb540cfde8a3617774b93a676d319
X-VCS-Branch: master
Date: Mon, 20 Jan 2020 10:23:51 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 9dfc0e73-66da-48ba-8932-952e66c840a0
X-Archives-Hash: 26f32c1f1932e696624cd622829f7810
commit: 3aff69cf5a9cb540cfde8a3617774b93a676d319
Author: Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 20 10:18:25 2020 +0000
Commit: Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Mon Jan 20 10:22:53 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3aff69cf
sys-libs/libapparmor: bump EAPI, python compat, and LICENSE fix
Closes: https://bugs.gentoo.org/704878
Thanks-to: Jason Chan <graysonchsi <AT> gmail.com>
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Michael Palimaka <kensington <AT> gentoo.org>
sys-libs/libapparmor/libapparmor-2.13.3-r1.ebuild | 98 +++++++++++++++++++++++
1 file changed, 98 insertions(+)
diff --git a/sys-libs/libapparmor/libapparmor-2.13.3-r1.ebuild b/sys-libs/libapparmor/libapparmor-2.13.3-r1.ebuild
new file mode 100644
index 00000000000..e47d13d2ba5
--- /dev/null
+++ b/sys-libs/libapparmor/libapparmor-2.13.3-r1.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python2_7 python3_{5,6,7,8} )
+GENTOO_DEPEND_ON_PERL="no"
+
+inherit autotools distutils-r1 perl-functions
+
+MY_PV="$(ver_cut 1-2)"
+
+DESCRIPTION="Library to support AppArmor userspace utilities"
+HOMEPAGE="https://gitlab.com/apparmor/apparmor/wikis/home"
+SRC_URI="https://launchpad.net/apparmor/${MY_PV}/${PV}/+download/apparmor-${PV}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc +perl +python static-libs"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="perl? ( dev-lang/perl:= )
+ python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+ sys-devel/autoconf-archive
+ sys-devel/bison
+ sys-devel/flex
+ doc? ( dev-lang/perl )
+ perl? ( dev-lang/swig )
+ python? ( dev-lang/swig )"
+
+S=${WORKDIR}/apparmor-${PV}/libraries/${PN}
+
+PATCHES=( "${FILESDIR}/${PN}-2.10-symbol_visibility.patch" )
+
+# depends on the package already being installed
+RESTRICT="test"
+
+src_prepare() {
+ rm -r m4 || die "failed to remove bundled macros"
+ default
+ eautoreconf
+ use python && distutils-r1_src_prepare
+}
+
+src_configure() {
+ econf \
+ $(use_enable static-libs static) \
+ $(use_with perl) \
+ $(use_with python)
+}
+
+src_compile() {
+ emake -C src
+ emake -C include
+ use doc && emake -C doc
+ use perl && emake -C swig/perl
+
+ if use python ; then
+ pushd swig/python > /dev/null
+ emake libapparmor_wrap.c
+ distutils-r1_src_compile
+ popd > /dev/null
+ fi
+}
+
+src_install() {
+ emake DESTDIR="${D}" -C src install
+ emake DESTDIR="${D}" -C include install
+ use doc && emake DESTDIR="${D}" -C doc install
+
+ if use perl ; then
+ emake DESTDIR="${D}" -C swig/perl install
+ perl_set_version
+ insinto "${VENDOR_ARCH}"
+ doins swig/perl/LibAppArmor.pm
+
+ # bug 620886
+ perl_delete_localpod
+ perl_fix_packlist
+ fi
+
+ if use python ; then
+ pushd swig/python > /dev/null
+ distutils-r1_src_install
+
+ python_moduleinto LibAppArmor
+ python_foreach_impl python_domodule LibAppArmor.py
+ popd > /dev/null
+ fi
+
+ dodoc AUTHORS ChangeLog NEWS README
+
+ find "${D}" -name '*.la' -delete || die
+}