[gentoo-commits] repo/gentoo:master commit in: app-admin/qtpass/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     5a31e596d93cefb19f61cd7598cff35bf5471556
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Jan 15 20:40:15 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Jan 19 23:51:32 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5a31e596

app-admin/qtpass: Prepare for dev-qt/qtgui[xcb -> X]

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-admin/qtpass/qtpass-1.3.2-r1.ebuild | 65 +++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)

diff --git a/app-admin/qtpass/qtpass-1.3.2-r1.ebuild b/app-admin/qtpass/qtpass-1.3.2-r1.ebuild
new file mode 100644
index 00000000000..7ece9838e01
--- /dev/null
+++ b/app-admin/qtpass/qtpass-1.3.2-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop qmake-utils virtualx
+
+DESCRIPTION="multi-platform GUI for pass, the standard unix password manager"
+HOMEPAGE="https://qtpass.org/"
+SRC_URI="https://github.com/IJHack/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="test"
+
+RDEPEND="app-admin/pass
+	dev-qt/qtcore:5
+	|| (
+		dev-qt/qtgui:5[X(-)]
+		dev-qt/qtgui:5[xcb(-)]
+	)
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	net-misc/x11-ssh-askpass"
+DEPEND="${RDEPEND}
+	dev-qt/qtsvg:5
+	test? ( dev-qt/qttest:5 )"
+BDEPEND="dev-qt/linguist-tools:5"
+
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}/QtPass-${PV}"
+
+DOCS=( {CHANGELOG,CONTRIBUTING,FAQ,README}.md )
+
+src_prepare() {
+	default
+
+	if ! use test ; then
+		sed -i '/SUBDIRS += src /s/tests //' \
+			qtpass.pro || die "sed for qtpass.pro failed"
+	fi
+}
+
+src_configure() {
+	eqmake5 PREFIX="${D}"/usr
+}
+
+src_test() {
+	virtx default
+}
+
+src_install() {
+	default
+
+	insinto /usr/share/qtpass/translations
+	doins localization/*.qm
+
+	doman qtpass.1
+	domenu qtpass.desktop
+	newicon artwork/icon.png qtpass-icon.png
+	insinto /usr/share/appdata
+	doins qtpass.appdata.xml
+}