[gentoo-commits] repo/gentoo:master commit in: dev-libs/opensc/

["Mikle Kolyada" <zlogene@gentoo.org>]

commit:     338f86fa965dc8c8f559799ab993088e71925a94
Author:     Mikk Margus Möll <mimoll <AT> ttu <DOT> ee>
AuthorDate: Sun Jan 12 23:27:13 2020 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Mon Jan 13 12:02:53 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=338f86fa

dev-libs/opensc: bump to 0.20.0

Bug: https://bugs.gentoo.org/704216
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mikk Margus Möll <mimoll <AT> ttu.ee>
Signed-off-by: Mikle Kolyada <zlogene <AT> gentoo.org>

 dev-libs/opensc/Manifest             |  1 +
 dev-libs/opensc/opensc-0.20.0.ebuild | 61 ++++++++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/dev-libs/opensc/Manifest b/dev-libs/opensc/Manifest
index 0ac21a4400f..016cba20da9 100644
--- a/dev-libs/opensc/Manifest
+++ b/dev-libs/opensc/Manifest
@@ -1 +1,2 @@
 DIST opensc-0.19.0.tar.gz 2080320 BLAKE2B c07df317f26562107680ed586e9a1ea83252c10a7dd227cffe51de709d9c888874963f6835a68f83f212d83f264b0231ea7428ed8d3ecce74cb9265d8191040a SHA512 90659133fb593cbf82ed6502e3858f34119bff051e3090489b7622659dcb1c26d389a4715892aa60a5606bc0ce115bd6c504521abfb965de9ad46441e4ed2b8e
+DIST opensc-0.20.0.tar.gz 2140645 BLAKE2B 298a6d9c8a9682899cae201ba7edd464a2e3d947f6d97672727bedc47f6b529cb1495a8bc335f83cdb42b0c0077de0fd7ff9f3f8f506b543b1970cb6557b762e SHA512 71f71fa6062410e63c6c60f5b2d10d1d855cc6cc815ef0e42e42a1ddd25bbd52fc396c1e495ef54610f3243996dec84dacc8007b186deb670ed645b04ee6eda5

diff --git a/dev-libs/opensc/opensc-0.20.0.ebuild b/dev-libs/opensc/opensc-0.20.0.ebuild
new file mode 100644
index 00000000000..7dd7147094b
--- /dev/null
+++ b/dev-libs/opensc/opensc-0.20.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit bash-completion-r1
+
+DESCRIPTION="Libraries and applications to access smartcards"
+HOMEPAGE="https://github.com/OpenSC/OpenSC/wiki"
+SRC_URI="https://github.com/OpenSC/OpenSC/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="ctapi doc libressl openct notify +pcsc-lite readline secure-messaging ssl test zlib"
+RESTRICT="!test? ( test )"
+
+RDEPEND="zlib? ( sys-libs/zlib )
+	readline? ( sys-libs/readline:0= )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( >=dev-libs/libressl-2.7.0:0= )
+	)
+	openct? ( >=dev-libs/openct-0.5.0 )
+	pcsc-lite? ( >=sys-apps/pcsc-lite-1.3.0 )
+	notify? ( dev-libs/glib:2 )"
+DEPEND="${RDEPEND}
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	test? ( dev-util/cmocka )"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	pcsc-lite? ( !openct !ctapi )
+	openct? ( !pcsc-lite !ctapi )
+	ctapi? ( !pcsc-lite !openct )
+	|| ( pcsc-lite openct ctapi )"
+
+src_configure() {
+	econf \
+		--with-completiondir="$(get_bashcompdir)" \
+		--disable-openpace \
+		--disable-static \
+		--disable-strict \
+		--enable-man \
+		$(use_enable ctapi) \
+		$(use_enable doc) \
+		$(use_enable notify ) \
+		$(use_enable openct) \
+		$(use_enable pcsc-lite pcsc) \
+		$(use_enable readline) \
+		$(use_enable secure-messaging sm) \
+		$(use_enable ssl openssl) \
+		$(use_enable test cmocka) \
+		$(use_enable zlib)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}