[gentoo-commits] repo/gentoo:master commit in: media-libs/grilo/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     37c9a5260163490537145a5068ee82a1bcf5aacd
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 11 09:06:49 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sat Jan 11 09:34:33 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=37c9a526

media-libs/grilo: bump to 0.3.11

Package-Manager: Portage-2.3.79, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 media-libs/grilo/Manifest            |  1 +
 media-libs/grilo/grilo-0.3.11.ebuild | 75 ++++++++++++++++++++++++++++++++++++
 2 files changed, 76 insertions(+)

diff --git a/media-libs/grilo/Manifest b/media-libs/grilo/Manifest
index 4cf1c23996d..b7594e94c48 100644
--- a/media-libs/grilo/Manifest
+++ b/media-libs/grilo/Manifest
@@ -1 +1,2 @@
+DIST grilo-0.3.11.tar.xz 233516 BLAKE2B 4f239ae99bbd0fefe501e60bbb1249641a2996a26cc8342d5b8daf0665baaad268de9e295bf52b0b504da5c9a0a1f9174664c1afe1303e5dc8a5b547b2e1d160 SHA512 fd46d035982b14ed19681acce3f4878cc678919babc031ce5eb577a21d14f97b905eb5094b344b7fc732bf317fb504dae940cffb7875de2d577bae431b7f9c36
 DIST grilo-0.3.9.tar.xz 233616 BLAKE2B c22b868d5bcb6731024b212d6bc1502b493950e363127202ded0ed80f3e937bf78062ba6f2803e29f686ff8cfc521147e69b8f4a7b33060d81e30f34a231e37b SHA512 250596f277ea76d8f6a071fb0e48dd7ea735a534f48a4f2e3f69f7c62a2b5b4c995714a8435ffa9107345e86bba5b21fc136cc47b956f461723a00d0e6ede9bf

diff --git a/media-libs/grilo/grilo-0.3.11.ebuild b/media-libs/grilo/grilo-0.3.11.ebuild
new file mode 100644
index 00000000000..1c79be334ff
--- /dev/null
+++ b/media-libs/grilo/grilo-0.3.11.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_6,3_7} )
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome.org meson python-any-r1 vala xdg
+
+DESCRIPTION="A framework for easy media discovery and browsing"
+HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.3/0" # subslot is libgrilo-0.3 soname suffix
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="gtk gtk-doc +introspection +network +playlist test vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+# oauth could be optional if meson is patched - used for flickr oauth in grilo-test-ui tool
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	dev-libs/libxml2:2
+	network? ( >=net-libs/libsoup-2.41.3:2.4[introspection?] )
+	playlist? ( >=dev-libs/totem-pl-parser-3.4.1 )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+
+	gtk? (
+		net-libs/liboauth
+		>=x11-libs/gtk+-3.14:3 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.10
+		app-text/docbook-xml-dtd:4.3 )
+	${PYTHON_DEPS}
+	test? ( sys-apps/dbus )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	sed -i -e "s:'GETTEXT_PACKAGE', meson.project_name():'GETTEXT_PACKAGE', 'grilo-${SLOT%/*}':" meson.build || die
+	sed -i -e "s:meson.project_name():'grilo-${SLOT%/*}':" po/meson.build || die
+	sed -i -e "s:'grilo':'grilo-${SLOT%/*}':" doc/grilo/meson.build || die
+
+	# Drop explicit unversioned vapigen check
+	sed -i -e "/find_program.*vapigen/d" meson.build || die
+
+	# Don't build examples; they get embedded in gtk-doc, thus we don't install the sources with USE=examples either
+	sed -i -e "/subdir('examples')/d" meson.build || die
+
+	xdg_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use network enable-grl-net)
+		$(meson_use playlist enable-grl-pls)
+		$(meson_use gtk-doc enable-gtk-doc)
+		$(meson_use introspection enable-introspection)
+		$(meson_use gtk enable-test-ui)
+		$(meson_use vala enable-vala)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" || die
+}