[gentoo-commits] repo/gentoo:master commit in: xfce-base/xfce4-session/

["Michał Górny" <mgorny@gentoo.org>]

commit:     3445dfcc081c257d6ed44d3ca461e22099dc465d
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 11 04:31:58 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jan 11 05:07:59 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3445dfcc

xfce-base/xfce4-session: Bump to 4.14.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 xfce-base/xfce4-session/Manifest                   |  1 +
 .../xfce4-session/xfce4-session-4.14.1.ebuild      | 78 ++++++++++++++++++++++
 2 files changed, 79 insertions(+)

diff --git a/xfce-base/xfce4-session/Manifest b/xfce-base/xfce4-session/Manifest
index 3fd800cd30a..a9600113798 100644
--- a/xfce-base/xfce4-session/Manifest
+++ b/xfce-base/xfce4-session/Manifest
@@ -1 +1,2 @@
 DIST xfce4-session-4.14.0.tar.bz2 826950 BLAKE2B 164fd9f61f03a61e705abf1f7ab82e81eccbd5269d28d66f6da7234ba073d38a1b38d1be0ddb5f3c055e829adf12673611a2b0ea0585f9fd1d2806b17cf0e761 SHA512 fba79ef9727d47514c5e4223376c49057b714f9be9bda6031a1220f4840abb257d31517252180c0af2e7cd6969bbc4e6f525b00cac594e1a3b80f09f3f2335cb
+DIST xfce4-session-4.14.1.tar.bz2 836607 BLAKE2B 916589884e47ce3224c4a6d5537dc7b03d18ec56009ae3e2b4db01d9614a18d1db0f14d3a732b0ed72b924a56831c37111f08068b39b43dab85a39d82ea38cac SHA512 af797e33145311015ca6444b929d82c4e321f76defe773aba723d0a373f894399216e043b45e0669dd1c9aa1ad3cd2dcfd422352fd2381b7425bb310be66c92b

diff --git a/xfce-base/xfce4-session/xfce4-session-4.14.1.ebuild b/xfce-base/xfce4-session/xfce4-session-4.14.1.ebuild
new file mode 100644
index 00000000000..251ab43f61c
--- /dev/null
+++ b/xfce-base/xfce4-session/xfce4-session-4.14.1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils
+
+DESCRIPTION="A session manager for the Xfce desktop environment"
+HOMEPAGE="https://docs.xfce.org/xfce/xfce4-session/start"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="elogind nls policykit systemd +xscreensaver"
+
+COMMON_DEPEND="x11-apps/iceauth
+	>=dev-libs/glib-2.42
+	>=x11-libs/gtk+-3.22:3
+	x11-libs/libSM
+	x11-libs/libwnck:3
+	x11-libs/libX11
+	>=xfce-base/libxfce4util-4.12:=
+	>=xfce-base/libxfce4ui-4.12.1:=[gtk3(+)]
+	>=xfce-base/xfconf-4.12:=
+	policykit? ( >=sys-auth/polkit-0.102 )"
+RDEPEND="${COMMON_DEPEND}
+	x11-apps/xrdb
+	nls? ( x11-misc/xdg-user-dirs )
+	xscreensaver? ( || (
+		xfce-extra/xfce4-screensaver
+		>=x11-misc/xscreensaver-5.26
+		>=x11-misc/xlockmore-5.43
+		x11-misc/slock
+		x11-misc/alock[pam]
+	) )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+REQUIRED_USE="elogind? ( policykit )
+	systemd? ( policykit )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.10.1-alock_support_to_xflock4.patch
+# TODO: this patch needs updating for the new version, and finding
+# upstream bug.
+#	"${FILESDIR}"/${PN}-4.12.1-light-locker_support_to_xflock4.patch
+)
+
+src_configure() {
+	local myconf=(
+		$(use_enable policykit polkit)
+		--with-xsession-prefix="${EPREFIX}"/usr
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+
+	local sessiondir=/etc/X11/Sessions
+	echo startxfce4 > "${T}"/Xfce4 || die
+	exeinto ${sessiondir}
+	doexe "${T}"/Xfce4
+	dosym Xfce4 ${sessiondir}/Xfce
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}