[gentoo-commits] repo/gentoo:master commit in: net-dialup/accel-ppp/

["Sergey Popov" <pinkbyte@gentoo.org>]

commit:     65289919c4600500f63773cf5e70eb7feee40984
Author:     Sergey Popov <pinkbyte <AT> gentoo <DOT> org>
AuthorDate: Thu Jan  9 12:20:11 2020 +0000
Commit:     Sergey Popov <pinkbyte <AT> gentoo <DOT> org>
CommitDate: Thu Jan  9 12:25:17 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=65289919

net-dialup/accel-ppp: drop old version

Signed-off-by: Sergey Popov <pinkbyte <AT> gentoo.org>

 .../accel-ppp/accel-ppp-1.11.1_p20180320.ebuild    | 105 ---------------------
 1 file changed, 105 deletions(-)

diff --git a/net-dialup/accel-ppp/accel-ppp-1.11.1_p20180320.ebuild b/net-dialup/accel-ppp/accel-ppp-1.11.1_p20180320.ebuild
deleted file mode 100644
index 0d27e032077..00000000000
--- a/net-dialup/accel-ppp/accel-ppp-1.11.1_p20180320.ebuild
+++ /dev/null
@@ -1,105 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit cmake-utils flag-o-matic linux-info linux-mod
-
-DESCRIPTION="High performance PPTP, PPPoE and L2TP server"
-HOMEPAGE="https://sourceforge.net/projects/accel-ppp/"
-SRC_URI="https://dev.gentoo.org/~pinkbyte/distfiles/snapshots/${P}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="debug doc ipoe lua postgres radius shaper snmp valgrind"
-
-RDEPEND="lua? ( dev-lang/lua:0 )
-	postgres? ( dev-db/postgresql:* )
-	snmp? ( net-analyzer/net-snmp )
-	dev-libs/libpcre
-	dev-libs/openssl:0"
-DEPEND="${RDEPEND}
-	valgrind? ( dev-util/valgrind )"
-PDEPEND="net-dialup/ppp-scripts"
-
-DOCS=( README )
-
-CONFIG_CHECK="~L2TP ~PPPOE ~PPTP"
-
-REQUIRED_USE="valgrind? ( debug )"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-1.11.1-socklen.patch"
-)
-
-S="${WORKDIR}"
-
-pkg_setup() {
-	if use ipoe; then
-		linux-mod_pkg_setup
-		set_arch_to_kernel
-	else
-		linux-info_pkg_setup
-	fi
-}
-
-src_prepare() {
-	sed -i  -e "/mkdir/d" \
-		-e "s: RENAME accel-ppp.conf.dist::" accel-pppd/CMakeLists.txt || die 'sed on accel-pppd/CMakeLists.txt failed'
-
-	# Do not install kernel modules like that - breaks sandbox!
-	sed -i -e '/modules_install/d' \
-		drivers/ipoe/CMakeLists.txt \
-		drivers/vlan_mon/CMakeLists.txt || die
-
-	# Bug #549918
-	append-ldflags -Wl,-z,lazy
-
-	cmake-utils_src_prepare
-}
-
-src_configure() {
-	local libdir="$(get_libdir)"
-	# There must be also dev-libs/tomcrypt (TOMCRYPT) as crypto alternative to OpenSSL
-	local mycmakeargs=(
-		-DLIB_SUFFIX="${libdir#lib}"
-		-DBUILD_IPOE_DRIVER="$(usex ipoe)"
-		-DBUILD_PPTP_DRIVER=no
-		-DBUILD_VLAN_MON_DRIVER="$(usex ipoe)"
-		-DCRYPTO=OPENSSL
-		-DLOG_PGSQL="$(usex postgres)"
-		-DLUA="$(usex lua)"
-		-DMEMDEBUG="$(usex debug)"
-		-DNETSNMP="$(usex snmp)"
-		-DRADIUS="$(usex radius)"
-		-DSHAPER="$(usex shaper)"
-		$(use debug && echo "-DVALGRIND=$(usex valgrind)")
-	)
-	cmake-utils_src_configure
-}
-
-src_compile() {
-	cmake-utils_src_compile
-}
-
-src_install() {
-	if use ipoe; then
-		local MODULE_NAMES="ipoe(accel-ppp:${BUILD_DIR}/drivers/ipoe/driver) vlan_mon(accel-ppp:${BUILD_DIR}/drivers/vlan_mon/driver)"
-		linux-mod_src_install
-	fi
-
-	cmake-utils_src_install
-
-	use doc && dodoc -r rfc
-
-	if use snmp; then
-		insinto /usr/share/snmp/mibs
-		doins accel-pppd/extra/net-snmp/ACCEL-PPP-MIB.txt
-	fi
-
-	newinitd "${FILESDIR}"/${PN}.initd ${PN}d
-	newconfd "${FILESDIR}"/${PN}.confd ${PN}d
-
-	dodir /var/log/accel-ppp
-}