[gentoo-commits] repo/gentoo:master commit in: media-sound/clementine/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     2ae54c04e1e24c281e7836cc86256d5b91652063
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Wed Jan  1 17:59:01 2020 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Wed Jan  1 18:02:32 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2ae54c04

media-sound/clementine: Bump to version 1.3.92

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 media-sound/clementine/Manifest                 |   1 +
 media-sound/clementine/clementine-1.3.92.ebuild | 176 ++++++++++++++++++++++++
 2 files changed, 177 insertions(+)

diff --git a/media-sound/clementine/Manifest b/media-sound/clementine/Manifest
index 2b976959cb2..9c86f3475fc 100644
--- a/media-sound/clementine/Manifest
+++ b/media-sound/clementine/Manifest
@@ -1,3 +1,4 @@
 DIST clementine-1.3.1_p20190127.tar.gz 8516435 BLAKE2B ce884c25d76e26349cf11109f885361dd79c4d567b08927962a611a2bb17dbe6674ac176f6b09b3a8ebe14e82f30125a56ffd08ff6d2072a96ee7b9ba1f066db SHA512 b82d2dc49dbe41e68440fb421cda6989f670a2a43829bf42e21f3c07d6f6badcb217333559d6dd9c66accd88e2473e5c717969e987410bf4801669dccba7cd15
 DIST clementine-1.3.1_p20190609.tar.gz 8516585 BLAKE2B a02e473703da5cfa3a7fb702f3ff90f3aa0fd97faf8b10b2c080b4a9a052f514f67fe40dcd0fd435c1681bd8749b0f4d731b21e4b842979e9dbe516cf7a19e76 SHA512 d72d29a01920bfe74d1a51b419cdbb5bd096cfd816edec4e7325bf43cc5b75a893c273b131539ae362f2a804cbb4ca57002737e4833ef6e5c1adc1b7f142dd57
 DIST clementine-1.3.1_p20191004.tar.gz 8528437 BLAKE2B 11c7bd7ac4ad4cdc75e2c5e54651832c1aa31448341230917df973227fcb1cd659309bb361f0b62a12dc38ce48e1f25697742df478650f4c10996938a7093acf SHA512 eb755d47f2e518c4e1bb28596e6554184d9fb6bab594e2f16b73c0bdecaa7c19692d368e9ec6a91e5012b786368eb7d3b2d051db11f3b5934233ba3e5b488679
+DIST clementine-1.3.92.tar.gz 8570513 BLAKE2B 9cb4de03579e0555be255cae295cc973966587be59dc83d07cbe139c74a9ffe046adf4cec8de12888306fb168ab00a388ac8fa490928c4f76ad187b4c482a829 SHA512 ce6a30eb8fdcc2e105aedc976566d11f88ec537915210d3b7fe1471457371ab472e3707bd62fd8606756e6caf5b5844d4dbceb08fec8ab69750e9fa03dde0193

diff --git a/media-sound/clementine/clementine-1.3.92.ebuild b/media-sound/clementine/clementine-1.3.92.ebuild
new file mode 100644
index 00000000000..cdb73b18766
--- /dev/null
+++ b/media-sound/clementine/clementine-1.3.92.ebuild
@@ -0,0 +1,176 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PLOCALES="af ar be bg bn br bs ca cs cy da de el en en_CA en_GB eo es et eu fa fi fr ga gl he he_IL hi hr hu hy ia id is it ja ka kk ko lt lv mk_MK mr ms my nb nl oc pa pl pt pt_BR ro ru si_LK sk sl sr sr@latin sv te tr tr_TR uk uz vi zh_CN zh_TW"
+
+inherit cmake flag-o-matic l10n virtualx xdg
+
+MY_P="${P/_}"
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/clementine-player/Clementine.git"
+	inherit git-r3
+else
+	S="${WORKDIR}/${PN^}-${PV}"
+	SRC_URI_BASE="https://github.com/clementine-player/${PN^}"
+	COMMIT=""
+	if [[ -n "${COMMIT}" ]] ; then
+		SRC_URI="${SRC_URI_BASE}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+		S="${WORKDIR}/${PN^}-${COMMIT}"
+	elif [[ $(ver_cut 3) -gt 90 ]] ; then
+		SRC_URI="${SRC_URI_BASE}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	else
+		SRC_URI="${SRC_URI_BASE}/releases/download/${PV}/${P}.tar.xz"
+	fi
+	KEYWORDS="~amd64 ~x86"
+fi
+DESCRIPTION="Modern music player and library organizer based on Amarok 1.4 and Qt"
+HOMEPAGE="https://www.clementine-player.org https://github.com/clementine-player/Clementine"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="box cdda +dbus debug dropbox googledrive ipod lastfm mms moodbar mtp projectm pulseaudio seafile skydrive test +udisks wiimote"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="
+	udisks? ( dbus )
+	wiimote? ( dbus )
+"
+
+BDEPEND="
+	>=dev-cpp/gtest-1.8.0
+	dev-qt/linguist-tools:5
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? (
+		dev-qt/qttest:5
+		gnome-base/gsettings-desktop-schemas
+	)
+"
+COMMON_DEPEND="
+	app-crypt/qca:2[qt5(+)]
+	dev-db/sqlite:=
+	dev-libs/crypto++:=
+	dev-libs/glib:2
+	dev-libs/libxml2
+	dev-libs/protobuf:=
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtwidgets:5
+	media-libs/chromaprint:=
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+	>=media-libs/libmygpo-qt-1.0.9[qt5(+)]
+	>=media-libs/taglib-1.11.1_p20181028
+	sys-libs/zlib
+	virtual/glu
+	x11-libs/libX11
+	cdda? ( dev-libs/libcdio:= )
+	dbus? ( dev-qt/qtdbus:5 )
+	ipod? ( >=media-libs/libgpod-0.8.0 )
+	lastfm? ( >=media-libs/liblastfm-1.1.0_pre20150206 )
+	moodbar? ( sci-libs/fftw:3.0 )
+	mtp? ( >=media-libs/libmtp-1.0.0 )
+	projectm? (
+		media-libs/glew:=
+		>=media-libs/libprojectm-1.2.0:=
+		virtual/opengl
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	media-plugins/gst-plugins-meta:1.0
+	media-plugins/gst-plugins-soup:1.0
+	media-plugins/gst-plugins-taglib:1.0
+	mms? ( media-plugins/gst-plugins-libmms:1.0 )
+	mtp? ( gnome-base/gvfs[mtp] )
+	udisks? ( sys-fs/udisks:2 )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/boost
+	dev-qt/qtopengl:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	box? ( dev-cpp/sparsehash )
+	dropbox? ( dev-cpp/sparsehash )
+	googledrive? ( dev-cpp/sparsehash )
+	pulseaudio? ( media-sound/pulseaudio )
+	seafile? ( dev-cpp/sparsehash )
+	skydrive? ( dev-cpp/sparsehash )
+"
+
+RESTRICT="test"
+
+DOCS=( Changelog README.md )
+
+src_prepare() {
+	l10n_find_plocales_changes "src/translations" "" ".po"
+
+	cmake_src_prepare
+	# some tests fail or hang
+	sed -i \
+		-e '/add_test_file(translations_test.cpp/d' \
+		tests/CMakeLists.txt || die
+
+	if ! use test; then
+		sed -e "/find_package.*Qt5/s:\ Test::" -i CMakeLists.txt || die
+		cmake_comment_add_subdirectory tests
+	fi
+
+	rm -r 3rdparty/{libmygpo-qt,libmygpo-qt5,taglib} || die
+}
+
+src_configure() {
+	# spotify is not in portage
+	local mycmakeargs=(
+		-DBUILD_WERROR=OFF
+		# force to find crypto++ see bug #548544
+		-DCRYPTOPP_LIBRARIES="cryptopp"
+		-DCRYPTOPP_FOUND=ON
+		# avoid automagically enabling of ccache (bug #611010)
+		-DCCACHE_EXECUTABLE=OFF
+		-DENABLE_BREAKPAD=OFF  #< disable crash reporting
+		-DENABLE_DEVICEKIT=OFF
+		-DENABLE_GIO=ON
+		-DENABLE_SPOTIFY_BLOB=OFF
+		-DUSE_SYSTEM_GMOCK=ON
+		-DUSE_SYSTEM_PROJECTM=ON
+		-DBUNDLE_PROJECTM_PRESETS=OFF
+		-DLINGUAS="$(l10n_get_locales)"
+		-DENABLE_BOX="$(usex box)"
+		-DENABLE_AUDIOCD="$(usex cdda)"
+		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5DBus=$(usex !dbus)
+		-DENABLE_DROPBOX="$(usex dropbox)"
+		-DENABLE_GOOGLE_DRIVE="$(usex googledrive)"
+		-DENABLE_LIBGPOD="$(usex ipod)"
+		-DENABLE_LIBLASTFM="$(usex lastfm)"
+		-DENABLE_MOODBAR="$(usex moodbar)"
+		-DENABLE_LIBMTP="$(usex mtp)"
+		-DENABLE_VISUALISATIONS="$(usex projectm)"
+		-DENABLE_SEAFILE="$(usex seafile)"
+		-DENABLE_SKYDRIVE="$(usex skydrive)"
+		-DENABLE_LIBPULSE="$(usex pulseaudio)"
+		-DENABLE_UDISKS2="$(usex udisks)"
+		-DENABLE_WIIMOTEDEV="$(usex wiimote)"
+	)
+
+	use !debug && append-cppflags -DQT_NO_DEBUG_OUTPUT
+
+	cmake_src_configure
+}
+
+src_test() {
+	cd "${CMAKE_BUILD_DIR}" || die
+	virtx emake test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	elog "Note that list of supported formats is controlled by media-plugins/gst-plugins-meta "
+	elog "USE flags. You may be interested in setting aac, flac, mp3, ogg or wavpack USE flags "
+	elog "depending on your preferences"
+}