[gentoo-commits] repo/gentoo:master commit in: app-emulation/winetricks/

["Nick Sarnie" <sarnex@gentoo.org>]

commit:     18ff09608f6c2a3af22d384e996b644b04427a2c
Author:     Nick Sarnie <sarnex <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 24 23:32:25 2019 +0000
Commit:     Nick Sarnie <sarnex <AT> gentoo <DOT> org>
CommitDate: Tue Dec 24 23:32:25 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=18ff0960

app-emulation/winetricks: Sync with ::wine

Bump winetricks version

Package-Manager: Portage-2.3.83, Repoman-2.3.20
Signed-off-by: Nick Sarnie <sarnex <AT> gentoo.org>

 app-emulation/winetricks/Manifest                  |  1 +
 .../winetricks/winetricks-20191224.ebuild          | 86 ++++++++++++++++++++++
 2 files changed, 87 insertions(+)

diff --git a/app-emulation/winetricks/Manifest b/app-emulation/winetricks/Manifest
index 2c6ad93722c..3e226af6f9d 100644
--- a/app-emulation/winetricks/Manifest
+++ b/app-emulation/winetricks/Manifest
@@ -1,2 +1,3 @@
 DIST winetricks-20190912.tar.gz 679544 BLAKE2B 633c407f8560fa3aa38806befded957d0bf1276164483b08fb3ef285fe873531d6362ae6305f5a33a85891d75990e6e0271fe954358e49425c4f36f0f918f48d SHA512 a0017cc08c56a511e523116daf2024b1462460d00b3d07de87720c7912dccab3d953db3653d7d611c5ae3b457a45de8d36688ee703e805c1e1f5be5c0fa7739f
+DIST winetricks-20191224.tar.gz 683074 BLAKE2B 53e89f57883c7527e083610d4ea036887cc8e058d281ee77b0e8fd7dec8520bcd27d5d86f6cadfa5d11bc191a33571086128e6729642e7f302dc37e27b1ce402 SHA512 31c0866e78d866e569da6c1123af7823a07b6358a79fcba84296938d89a39447ec9f504ca524471abc74ec2e3b24024bbc8a579413b4fe0ee74b1d5612f5d41a
 DIST winetricks-gentoo-2012.11.24.tar.bz2 6398 BLAKE2B 54a4502f6e8ef15d21b02c43e3ce599e32d476c2559246064de14cc4ce2243ff11dde681d24c8a7f4913c3d7a10b855bda47e8fb8ecad31e00d839705416be6f SHA512 59c93b73f3a7b2d11aefcde2ff66659ff1de21ad4b5f232f4b60572f3a48b15a6c49f369b1696862bf1b33fde190bf5598945e9536fb41ddec42d8def4d2be2a

diff --git a/app-emulation/winetricks/winetricks-20191224.ebuild b/app-emulation/winetricks/winetricks-20191224.ebuild
new file mode 100644
index 00000000000..900a5b53922
--- /dev/null
+++ b/app-emulation/winetricks/winetricks-20191224.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop xdg
+
+if [[ ${PV} == "99999999" ]] ; then
+	EGIT_REPO_URI="https://github.com/Winetricks/${PN}.git"
+	inherit git-r3
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/Winetricks/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+wtg="winetricks-gentoo-2012.11.24"
+
+SRC_URI="${SRC_URI}
+	gtk? ( https://dev.gentoo.org/~chiitoo/distfiles/${wtg}.tar.bz2 )
+	kde? ( https://dev.gentoo.org/~chiitoo/distfiles/${wtg}.tar.bz2 )
+"
+
+DESCRIPTION="Easy way to install DLLs needed to work around problems in Wine"
+HOMEPAGE="https://github.com/Winetricks/winetricks https://wiki.winehq.org/Winetricks"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="gtk kde rar test"
+
+BDEPEND="
+	test? (
+		dev-python/bashate
+		dev-util/checkbashisms
+		dev-util/shellcheck
+	)
+"
+DEPEND=""
+RDEPEND="${DEPEND}
+	app-arch/cabextract
+	app-arch/p7zip
+	app-arch/unzip
+	net-misc/wget
+	virtual/wine
+	x11-misc/xdg-utils
+	gtk? ( gnome-extra/zenity )
+	kde? ( kde-apps/kdialog )
+	rar? ( app-arch/unrar )
+"
+
+# Test targets include syntax checks only, not the "heavy duty" tests
+# that would require a lot of disk space, as well as network access.
+
+# This uses a non-standard "Wine" category, which is provided by
+# '/etc/xdg/menus/applications-merged/wine.menu' from the
+# 'app-emulation/wine-desktop-common' package.
+# https://bugs.gentoo.org/451552
+QA_DESKTOP_FILE="usr/share/applications/winetricks.desktop"
+
+src_unpack() {
+	if [[ ${PV} == "99999999" ]]; then
+		git-r3_src_unpack
+
+		if use gtk || use kde; then
+			unpack ${wtg}.tar.bz2
+		fi
+
+	else
+		default
+	fi
+}
+
+src_test() {
+	./tests/shell-checks || die "Test(s) failed."
+}
+
+src_install() {
+	default
+
+	if use gtk || use kde; then
+		cd "${WORKDIR}/${wtg}" || die
+		domenu winetricks.desktop
+		insinto /usr/share/icons/hicolor/scalable/apps
+		doins wine-winetricks.svg
+	fi
+}