[gentoo-commits] repo/gentoo:master commit in: media-gfx/imv/

["Jeroen Roovers" <jer@gentoo.org>]

commit:     ac5a8bb9276498749f136e52c0fa561ed4afcacb
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Mon Dec 16 09:59:18 2019 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Mon Dec 16 10:02:49 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ac5a8bb9

media-gfx/imv: Version 4.0.1

Package-Manager: Portage-2.3.82, Repoman-2.3.20
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 media-gfx/imv/Manifest         |  1 +
 media-gfx/imv/imv-4.0.1.ebuild | 88 ++++++++++++++++++++++++++++++++++++++++++
 media-gfx/imv/metadata.xml     |  3 ++
 3 files changed, 92 insertions(+)

diff --git a/media-gfx/imv/Manifest b/media-gfx/imv/Manifest
index 58c1691a2fe..d83dce4bc3a 100644
--- a/media-gfx/imv/Manifest
+++ b/media-gfx/imv/Manifest
@@ -1 +1,2 @@
 DIST imv-2.1.3.tar.gz 27664 BLAKE2B f873863d897161675b4cfbcc3c4136eebd0176317f30d656dd4c7a92615c926d1a0410d6c80283bb3a25055f3a9b710fa0763ffb86ff63ed1dd919ad3f0dfe8c SHA512 0ecdaad9b4518c2107a14969cf9348542c2ef88707be7b2b5eed435915292687d63e4ebd29cb42297cbc3dfee408ec29fd019ad6ae4f0cd789753aad84aa8128
+DIST imv-4.0.1.tar.gz 74982 BLAKE2B 5ff7f093307fdf6114e56f0e5d5a47a4320607eea12daa9a9c89c679f558b4d31f206f7eb03a8b0435a3f05974949029ebfc6e1b1fe4d7d2859bbd722ecb6366 SHA512 f946346638d4314956e86f0e7dfa38baf0ebbb80970f1738749e6c7b80642c2315256738b94ab04d45784c0930edadfc7cc339d2bcfd6eb80fd2e1e98b2d9b28

diff --git a/media-gfx/imv/imv-4.0.1.ebuild b/media-gfx/imv/imv-4.0.1.ebuild
new file mode 100644
index 00000000000..6dfc034c43a
--- /dev/null
+++ b/media-gfx/imv/imv-4.0.1.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit toolchain-funcs xdg-utils
+
+DESCRIPTION="Minimal image viewer designed for tiling window manager users"
+HOMEPAGE="https://github.com/eXeC64/imv"
+SRC_URI="https://github.com/eXeC64/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="X +freeimage jpeg png svg test tiff wayland"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	|| ( X wayland )
+"
+
+RDEPEND="
+	!sys-apps/renameutils
+	media-libs/fontconfig
+	media-libs/libsdl2
+	media-libs/sdl2-ttf
+	X? (
+		x11-libs/pango
+		x11-libs/libX11
+	)
+	freeimage? ( media-libs/freeimage )
+	jpeg? ( media-libs/libjpeg-turbo )
+	png? ( media-libs/libpng )
+	svg? ( gnome-base/librsvg )
+	tiff? ( media-libs/tiff )
+	wayland? ( dev-libs/wayland )
+"
+BDEPEND="
+	app-text/asciidoc
+	test? ( dev-util/cmocka )
+"
+DEPEND="
+	${RDEPEND}
+"
+
+src_prepare() {
+	default
+	sed -i -e 's|pkg-config|$(PKG_CONFIG)|g' Makefile || die
+}
+
+src_configure() {
+	tc-export PKG_CONFIG
+	local WINDOWS
+	if use X; then
+		if ! use wayland; then
+			WINDOWS=x11
+		else
+			WINDOWS=all
+		fi
+	else
+		if use wayland; then
+			WINDOWS=wayland
+		fi
+	fi
+
+	BACKENDS=(
+		BACKEND_FREEIMAGE=$(usex freeimage)
+		BACKEND_JPEG=$(usex jpeg)
+		BACKEND_LIBPNG=$(usex png)
+		BACKEND_LIBRSVG=$(usex svg)
+		BACKEND_LIBTIFF=$(usex tiff)
+		WINDOWS=${WINDOWS}
+	)
+}
+
+src_compile() {
+	emake ${BACKENDS[@]}
+}
+
+src_install() {
+	emake ${BACKENDS[@]} DESTDIR="${D}" install
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}

diff --git a/media-gfx/imv/metadata.xml b/media-gfx/imv/metadata.xml
index 457f62f9ff7..b0ac771f048 100644
--- a/media-gfx/imv/metadata.xml
+++ b/media-gfx/imv/metadata.xml
@@ -2,6 +2,9 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 	<!-- maintainer-needed -->
+<use>
+<flag name='freeimage'>Use <pkg>media-libs/freeimage</pkg> as image library</flag>
+</use>
 	<upstream>
 		<remote-id type="github">eXeC64/imv</remote-id>
 	</upstream>