From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1130344-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 2B76A138335
for <garchives@archives.gentoo.org>; Fri, 13 Dec 2019 15:35:53 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 2A469E0921;
Fri, 13 Dec 2019 15:35:51 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id EA0F1E0921
for <gentoo-commits@lists.gentoo.org>; Fri, 13 Dec 2019 15:35:50 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 8293334D855
for <gentoo-commits@lists.gentoo.org>; Fri, 13 Dec 2019 15:35:49 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id EC8D18A7
for <gentoo-commits@lists.gentoo.org>; Fri, 13 Dec 2019 15:35:47 +0000 (UTC)
From: "Ben Kohler" <bkohler@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Ben Kohler" <bkohler@gentoo.org>
Message-ID: <1576251336.4c98fe628b7ebb7f6f54094bdbf29e41f6b4378b.bkohler@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-misc/remmina/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-misc/remmina/Manifest net-misc/remmina/remmina-1.3.7.ebuild
X-VCS-Directories: net-misc/remmina/
X-VCS-Committer: bkohler
X-VCS-Committer-Name: Ben Kohler
X-VCS-Revision: 4c98fe628b7ebb7f6f54094bdbf29e41f6b4378b
X-VCS-Branch: master
Date: Fri, 13 Dec 2019 15:35:47 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 2e01087d-c184-4f7f-9eeb-088b4dbd06b5
X-Archives-Hash: cfa4295b4a3ba4049e8ac2b8de125059
commit: 4c98fe628b7ebb7f6f54094bdbf29e41f6b4378b
Author: Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Thu Dec 12 13:18:10 2019 +0000
Commit: Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Fri Dec 13 15:35:36 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4c98fe62
net-misc/remmina: bump to 1.3.7
Package-Manager: Portage-2.3.81, Repoman-2.3.20
Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>
net-misc/remmina/Manifest | 1 +
net-misc/remmina/remmina-1.3.7.ebuild | 95 +++++++++++++++++++++++++++++++++++
2 files changed, 96 insertions(+)
diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index 288761d8fdf..3f7c384cca8 100644
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -1,2 +1,3 @@
DIST Remmina-v1.3.4.tar.gz 1365473 BLAKE2B f71a9c0a0fa9eafa547abf192972da39f0cfe1ca3745a87783d6a9ec5bab0674d93df8815b589b25659990bb345748f8f464f401c7efb934e8e71b207b0dab67 SHA512 212ebc6e08c694861522a05feb51e4efa012ef3361debf079384c07e4354370f6cf7d2880ff442bbe03782421bac7f33343d8049207073d90925d1c894d30e7a
DIST Remmina-v1.3.6.tar.gz 1538166 BLAKE2B f3fc60df2a1a31bd5aae7d8de2d85cd579fa4cc35a0351fbce80433e21583b67cfc81665307d02fbd4863f6a55695be81f9c4d07423d6c8122d84dd625b69c3b SHA512 ce16379aa163467d05018c900d0dc7c2a7d73c1c22dd06a9a3092efa7675fda505bfa31b20131b9a3a10c74788377db17961c0bc9e59c47b1c7a15bf347f3bab
+DIST Remmina-v1.3.7.tar.gz 1611711 BLAKE2B cccf874a23faf72d8dc93c92e06036e7b19dd5fed5ee9c1d860ea7ed559d02b6120ac1347677626951c5e6c5c2ee7da9e5b022386d9d483acc3c16e5aa3b75e2 SHA512 a88e2e751c5882134ced22c3faf80fcd1fb32e48cdcab61e823b6f77ca806006d309ef492e7060f4862f5956b3443bc482b6e1495acb1a2df2beb3a64c4fb00e
diff --git a/net-misc/remmina/remmina-1.3.7.ebuild b/net-misc/remmina/remmina-1.3.7.ebuild
new file mode 100644
index 00000000000..78a79a44408
--- /dev/null
+++ b/net-misc/remmina/remmina-1.3.7.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils eutils gnome2-utils xdg-utils
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC, XDMCP and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ayatana crypt examples gnome-keyring kwallet libressl nls spice ssh rdp telepathy vnc webkit zeroconf"
+
+CDEPEND="
+ dev-libs/glib:2
+ dev-libs/json-glib
+ dev-libs/libsodium:=
+ net-libs/libsoup
+ x11-libs/gdk-pixbuf
+ x11-libs/gtk+:3
+ x11-libs/libX11
+ x11-libs/libxkbfile
+ ayatana? ( dev-libs/libappindicator:3 )
+ crypt? ( dev-libs/libgcrypt:0= )
+ rdp? ( >=net-misc/freerdp-2.0.0_rc4 )
+ gnome-keyring? ( app-crypt/libsecret )
+ kwallet? ( kde-frameworks/kwallet )
+ !libressl? ( dev-libs/openssl:0= )
+ libressl? ( dev-libs/libressl:0= )
+ spice? ( net-misc/spice-gtk[gtk3] )
+ ssh? ( net-libs/libssh:0=[sftp]
+ x11-libs/vte:2.91 )
+ telepathy? ( net-libs/telepathy-glib )
+ vnc? ( net-libs/libvncserver[jpeg] )
+ webkit? ( net-libs/webkit-gtk:4 )
+ zeroconf? ( net-dns/avahi[dbus,gtk3] )
+"
+DEPEND="${CDEPEND}
+ dev-util/intltool
+ virtual/pkgconfig
+ nls? ( sys-devel/gettext )
+"
+RDEPEND="${CDEPEND}
+ virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+ local mycmakeargs=(
+ -DWITH_APPINDICATOR=$(usex ayatana)
+ -DWITH_GCRYPT=$(usex crypt)
+ -DWITH_EXAMPLES=$(usex examples)
+ -DWITH_LIBSECRET=$(usex gnome-keyring)
+ -DWITH_KF5WALLET=$(usex kwallet)
+ -DWITH_GETTEXT=$(usex nls)
+ -DWITH_TRANSLATIONS=$(usex nls)
+ -DWITH_FREERDP=$(usex rdp)
+ -DWITH_SPICE=$(usex spice)
+ -DWITH_LIBSSH=$(usex ssh)
+ -DWITH_VTE=$(usex ssh)
+ -DWITH_TELEPATHY=$(usex telepathy)
+ -DWITH_LIBVNCSERVER=$(usex vnc)
+ -DWITH_WWW=$(usex webkit)
+ -DWITH_AVAHI=$(usex zeroconf)
+ -DWITH_ICON_CACHE=OFF
+ -DWITH_UPDATE_DESKTOP_DB=OFF
+ )
+ cmake-utils_src_configure
+}
+
+pkg_postinst() {
+ gnome2_icon_cache_update
+ xdg_mimeinfo_database_update
+ xdg_desktop_database_update
+
+ elog "To get additional features, some optional runtime dependencies"
+ elog "may be installed:"
+ elog ""
+ optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+ optfeature "XDMCP support" x11-base/xorg-server[xephyr]
+}
+
+pkg_postrm() {
+ gnome2_icon_cache_update
+ xdg_mimeinfo_database_update
+ xdg_desktop_database_update
+}