[gentoo-commits] repo/gentoo:master commit in: app-crypt/tpm2-abrmd/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     51c5f040cb0907561ef0e93c62c939a40d0e38fa
Author:     Salah Coronya <salah.coronya <AT> gmail <DOT> com>
AuthorDate: Sun Nov  3 00:56:21 2019 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Sun Dec  8 08:41:07 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=51c5f040

app-crypt/tpm2-abrmd: Implement GLEP 81

Package-Manager: Portage-2.3.76, Repoman-2.3.16
Signed-off-by: Salah Coronya <salah.coronya <AT> gmail.com>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 app-crypt/tpm2-abrmd/tpm2-abrmd-2.1.1-r1.ebuild | 55 +++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/app-crypt/tpm2-abrmd/tpm2-abrmd-2.1.1-r1.ebuild b/app-crypt/tpm2-abrmd/tpm2-abrmd-2.1.1-r1.ebuild
new file mode 100644
index 00000000000..535dcd41a59
--- /dev/null
+++ b/app-crypt/tpm2-abrmd/tpm2-abrmd-2.1.1-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools systemd
+
+DESCRIPTION="TPM2 Access Broker & Resource Manager"
+HOMEPAGE="https://github.com/tpm2-software/tpm2-abrmd"
+SRC_URI="https://github.com/tpm2-software/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="static-libs test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-apps/dbus:=
+	dev-libs/glib:=
+	app-crypt/tpm2-tss:="
+DEPEND="${RDEPEND}
+	acct-group/tss
+	acct-user/tss
+	test? ( dev-util/cmocka )"
+BDEPEND="virtual/pkgconfig
+	dev-util/gdbus-codegen"
+
+PATCHES=(
+	"${FILESDIR}/${P}-build.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable test unit) \
+		--disable-defaultflags \
+		--with-dbuspolicydir="${EPREFIX}/etc/dbus-1/system.d" \
+		--with-systemdpresetdir="$(systemd_get_systemunitdir)/../system-preset" \
+		--with-systemdpresetdisable \
+		--with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+}