[gentoo-commits] repo/gentoo:master commit in: dev-python/twine/files/, dev-python/twine/

["Patrick McLean" <chutzpah@gentoo.org>]

commit:     f5b5595547fd1588b716d8816ce3c0af0877086e
Author:     Patrick McLean <patrick.mclean <AT> sony <DOT> com>
AuthorDate: Fri Nov 22 02:31:53 2019 +0000
Commit:     Patrick McLean <chutzpah <AT> gentoo <DOT> org>
CommitDate: Fri Nov 22 03:15:16 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f5b55955

dev-python/twine: Version bump to 3.0.0

Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Patrick McLean <chutzpah <AT> gentoo.org>

 dev-python/twine/Manifest                      |  1 +
 dev-python/twine/files/twine-3.0.0-tests.patch | 20 +++++++++
 dev-python/twine/twine-3.0.0.ebuild            | 60 ++++++++++++++++++++++++++
 3 files changed, 81 insertions(+)

diff --git a/dev-python/twine/Manifest b/dev-python/twine/Manifest
index d86f366ef82..4a2188bc17f 100644
--- a/dev-python/twine/Manifest
+++ b/dev-python/twine/Manifest
@@ -1 +1,2 @@
 DIST twine-1.11.0.tar.gz 55301 BLAKE2B 88e88bc88a6dc8320064b3e296d85f1614d1ecf1628c8442737566ac58c3296b2292f147c0b39047a1d13a3ac98297fd7a77a0ba6fdb6ff04e59d16bc8ed463a SHA512 28e588f26b59bc9f4a8481caf2353934ad6927734762ffebb4416c147ec9e6dffb37092def20a76eb888c94b27f97e013dacc42c63e5dcda30f4290bb6c90a22
+DIST twine-3.0.0.tar.gz 138502 BLAKE2B 80cc475704979030435505103e45cfd051d2e3979e6fd9d4ad33fdbb2644bdebf789c504491f22a161f346295222287114ab68034560360f08a1beadefb20ac0 SHA512 1f5577c74c47618ae07672b53633110a5ecb486d25046cb87f36cbf5974b679714f962803b9dc6e970c57d8f2542b323e11437e76effe7172511557b56df5f12

diff --git a/dev-python/twine/files/twine-3.0.0-tests.patch b/dev-python/twine/files/twine-3.0.0-tests.patch
new file mode 100644
index 00000000000..e79fa03646d
--- /dev/null
+++ b/dev-python/twine/files/twine-3.0.0-tests.patch
@@ -0,0 +1,20 @@
+diff --git a/tests/test_upload.py b/tests/test_upload.py
+index c87e16e..1487a0d 100644
+--- a/tests/test_upload.py
++++ b/tests/test_upload.py
+@@ -13,6 +13,7 @@
+ # limitations under the License.
+ import pretend
+ import pytest
++import unittest
+ from requests.exceptions import HTTPError
+ 
+ from twine.commands import upload
+@@ -298,6 +299,7 @@ def test_values_from_env(monkeypatch):
+     "https://test.pypi.org/",
+     "https://pypi.org/"
+ ])
++@unittest.skip("needs internet access")
+ def test_check_status_code_for_wrong_repo_url(repo_url, make_settings):
+     upload_settings = make_settings()
+ 

diff --git a/dev-python/twine/twine-3.0.0.ebuild b/dev-python/twine/twine-3.0.0.ebuild
new file mode 100644
index 00000000000..8909b650265
--- /dev/null
+++ b/dev-python/twine/twine-3.0.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of utilities for publishing packages on PyPI"
+HOMEPAGE="https://twine.readthedocs.io/ https://github.com/pypa/twine https://pypi.org/project/twine/"
+SRC_URI="https://github.com/pypa/twine/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+CDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+BDEPEND="${CDEPEND}
+	test? (
+		dev-python/jaraco-envs[${PYTHON_USEDEP}]
+		dev-python/jaraco-functools[${PYTHON_USEDEP}]
+		dev-python/munch[${PYTHON_USEDEP}]
+		dev-python/portend[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+		dev-python/pypiserver[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="${CDEPEND}
+	>=dev-python/tqdm-4.14[${PYTHON_USEDEP}]
+	>=dev-python/pkginfo-1.4.2[${PYTHON_USEDEP}]
+	>=dev-python/readme_renderer-21.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.20.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-0.8.0[${PYTHON_USEDEP}]
+	dev-python/importlib_metadata[${PYTHON_USEDEP}]
+	dev-python/keyring[${PYTHON_USEDEP}]
+"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	"${FILESDIR}/twine-3.0.0-tests.patch"
+)
+
+python_prepare_all() {
+	# avoid a dep on setuptools_scm
+	sed -i "s:use_scm_version=True:version=\"${PV}\":" setup.py || die
+
+	# requires internet
+	rm -f tests/test_integration.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	distutils_install_for_testing
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}