[gentoo-commits] repo/gentoo:master commit in: net-libs/accounts-qt/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     5559fe0a4337202d0f03d8e9a0e9d7e63cd8f421
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Nov 20 14:54:03 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Nov 20 15:37:56 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5559fe0a

net-libs/accounts-qt: 1.16 version bump

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 net-libs/accounts-qt/Manifest                |  1 +
 net-libs/accounts-qt/accounts-qt-1.16.ebuild | 55 ++++++++++++++++++++++++++++
 2 files changed, 56 insertions(+)

diff --git a/net-libs/accounts-qt/Manifest b/net-libs/accounts-qt/Manifest
index b8ed8e166d5..a4e4cdcaa68 100644
--- a/net-libs/accounts-qt/Manifest
+++ b/net-libs/accounts-qt/Manifest
@@ -1 +1,2 @@
 DIST accounts-qt-1.15.tar.gz 64190 BLAKE2B a00f4677d9e99304729af4768c288bce1b19f357e50db0db1264760114b6a9cea821bda112605a49dafa192e10d4d6454155fa94a3dd3cea2a6525d63c129bb4 SHA512 36c80a237bc2d427ce3acb62ac3b2e7878ac7e02b00f17022af326b52edbc7ad3d0cf428fb4e1e2bcc1d0d410054102926f549dc18bea137a9d9ea19a2d268d3
+DIST accounts-qt-1.16.tar.gz 64445 BLAKE2B 380d34857e9eef5bec1f1a3d1d789c67b709e8a80b648c61cb4fe4bfe84fc08e18b88e1729dfdb35587c148781574b1a2bd9973cbbc87fe6842b6c61e3d0035f SHA512 ea495f508cd383a8f936277b5e86ceda86b2912d262145e8c097b713d53c14760c6b5b8cfb58de1d0aeee6d13be504fa94a78db07ff027ea9d28f5a43d4a29c3

diff --git a/net-libs/accounts-qt/accounts-qt-1.16.ebuild b/net-libs/accounts-qt/accounts-qt-1.16.ebuild
new file mode 100644
index 00000000000..1770e7ed667
--- /dev/null
+++ b/net-libs/accounts-qt/accounts-qt-1.16.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qmake-utils
+
+DESCRIPTION="Qt5 bindings for libaccounts-glib"
+HOMEPAGE="https://accounts-sso.gitlab.io/"
+SRC_URI="https://gitlab.com/accounts-sso/lib${PN}/repository/VERSION_${PV}/archive.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc test"
+
+BDEPEND="
+	doc? ( app-doc/doxygen )
+"
+RDEPEND="
+	dev-libs/glib:2
+	dev-qt/qtcore:5
+	dev-qt/qtxml:5
+	>=net-libs/libaccounts-glib-1.23:=
+"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )
+"
+
+# dbus problems
+RESTRICT="test"
+
+S="${WORKDIR}/lib${PN}-VERSION_${PV}-5b272ae218ccdf1f67f4eed92e2cdbe21c56ceb8"
+
+src_prepare() {
+	default
+
+	sed -e "s|share/doc/\$\${PROJECT_NAME}|share/doc/${PF}|" \
+		-i doc/doc.pri || die
+	if ! use doc; then
+		sed -e "/include( doc\/doc.pri )/d" -i ${PN}.pro || die
+	fi
+	if ! use test; then
+		sed -e '/^SUBDIRS/s/tests//' \
+			-i accounts-qt.pro || die "couldn't disable tests"
+	fi
+}
+
+src_configure() {
+	eqmake5 LIBDIR="${EPREFIX}/usr/$(get_libdir)"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+}