[gentoo-commits] repo/gentoo:master commit in: app-cdr/xfburn/

["Michał Górny" <mgorny@gentoo.org>]

commit:     ee044894d3ebb2885b65e6f3f509f6d909522a1a
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Nov  3 08:50:04 2019 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Nov  3 09:28:54 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ee044894

app-cdr/xfburn: Bump to 0.6.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 app-cdr/xfburn/Manifest            |  1 +
 app-cdr/xfburn/xfburn-0.6.0.ebuild | 52 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)

diff --git a/app-cdr/xfburn/Manifest b/app-cdr/xfburn/Manifest
index b3b1eaf3c5d..1d5a92c6b95 100644
--- a/app-cdr/xfburn/Manifest
+++ b/app-cdr/xfburn/Manifest
@@ -1 +1,2 @@
 DIST xfburn-0.5.5.tar.bz2 819546 BLAKE2B 180f50e9dc8e9bb2372ac7335374b09eade93b6477e557b4282ee65705e55d1f391578343e3473061921cfe296e0da9dae0ddb8823fc5daadc673537331f3085 SHA512 37574aa7dcec65c26a8fd5019c3776196763fa1ebb0f531002f5bcb72a6eb0ec19ed994dd14726988766d890ef257c39c26e64ca3f5944386c03d9b54c26a90a
+DIST xfburn-0.6.0.tar.bz2 847356 BLAKE2B 76f7dce31166b4524631fb1278adfb8a456f5ec8202ca1e29d86cc52b58a084a09099602c3258eda85f93e0d802afd281a15d91801b79d16520ebd13cc5fceb8 SHA512 b72f75ed8923cda1eaed9c64385a9e578635a678ef6fce54e8d1b27e3974b8def8b83ec66a1e0113521fe637901af02c53bb806e1b67e10687b7e0a6c9d80a5b

diff --git a/app-cdr/xfburn/xfburn-0.6.0.ebuild b/app-cdr/xfburn/xfburn-0.6.0.ebuild
new file mode 100644
index 00000000000..ab94182b1f3
--- /dev/null
+++ b/app-cdr/xfburn/xfburn-0.6.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils
+
+DESCRIPTION="GTK+ based CD and DVD burning application"
+HOMEPAGE="https://goodies.xfce.org/projects/applications/xfburn"
+SRC_URI="https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE="gstreamer +udev"
+# only .po check, that fails
+# https://bugzilla.xfce.org/show_bug.cgi?id=16115
+RESTRICT="test"
+
+RDEPEND=">=dev-libs/glib-2.32:=
+	>=dev-libs/libburn-0.4.2:=
+	>=dev-libs/libisofs-0.6.2:=
+	>=x11-libs/gtk+-3.20:3=
+	>=xfce-base/exo-0.11:=
+	>=xfce-base/libxfce4ui-4.12:=
+	gstreamer? (
+		media-libs/gstreamer:1.0=
+		media-libs/gst-plugins-base:1.0= )
+	udev? ( dev-libs/libgudev:= )"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_configure() {
+	local myconf=(
+		$(use_enable udev gudev)
+		$(use_enable gstreamer)
+	)
+
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}