[gentoo-commits] repo/gentoo:master commit in: media-sound/qjackctl/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     81e0652d27f0d1a6e65336a7bbb3dfa2e283f602
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Fri Nov  1 12:04:22 2019 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Fri Nov  1 12:04:35 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=81e0652d

media-sound/qjackctl-{0.6.0,9999}: bump + added live ebuild

Closes: https://bugs.gentoo.org/628856
Package-Manager: Portage-2.3.78, Repoman-2.3.17
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-sound/qjackctl/Manifest              |  1 +
 media-sound/qjackctl/qjackctl-0.6.0.ebuild | 61 +++++++++++++++++++++++++++
 media-sound/qjackctl/qjackctl-9999.ebuild  | 67 ++++++++++++++++++++++++++++++
 3 files changed, 129 insertions(+)

diff --git a/media-sound/qjackctl/Manifest b/media-sound/qjackctl/Manifest
index 4fb67cca544..409e2f8f92b 100644
--- a/media-sound/qjackctl/Manifest
+++ b/media-sound/qjackctl/Manifest
@@ -1 +1,2 @@
 DIST qjackctl-0.4.5.tar.gz 832932 BLAKE2B 9e47ce1bb0439e62b8922b2a39650410b96ffa6f13489042fdd8909152d31b2a8f5b1a7ee73cd8a85b10aec776175a9c6a3782b0ab592c5196e7352b106b53ee SHA512 251b7275fd6cb13c91420b7c11d5d2a1d9b7c5b11b78a4b5ba41955b4bbaa3c4f4721123f3375c2ce4a243ee9defc69c982cc93796e17e01e096e1228c4fe5fd
+DIST qjackctl-0.6.0.tar.gz 933416 BLAKE2B 116a6a71ab0c0974ff5109c5ae34c47fb4706e3e051d7bfc9daec74f952304606f5a790e03d3b97bc2c68968ac6a09ad885c4dd4c774b2454c9a7af8ec6c997f SHA512 f1cd281f67a764f12301c6b58644aed2419d2c82696a24bd9980aa7ea42a266ff5e4aa6247b0b6ac78cb01afc34219c7de8c0657cfdf0fa9858a52d1f84b8fea

diff --git a/media-sound/qjackctl/qjackctl-0.6.0.ebuild b/media-sound/qjackctl/qjackctl-0.6.0.ebuild
new file mode 100644
index 00000000000..124e16d17dc
--- /dev/null
+++ b/media-sound/qjackctl/qjackctl-0.6.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic qmake-utils xdg-utils
+
+DESCRIPTION="Qt GUI to control the JACK Audio Connection Kit and ALSA sequencer connections"
+HOMEPAGE="http://qjackctl.sourceforge.net/"
+SRC_URI="mirror://sourceforge/qjackctl/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="alsa dbus debug portaudio"
+
+RDEPEND="
+	app-arch/gzip
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	virtual/jack
+	alsa? ( media-libs/alsa-lib )
+	dbus? ( dev-qt/qtdbus:5 )
+	portaudio? ( media-libs/portaudio )"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5"
+
+src_configure() {
+	append-cxxflags -std=c++11
+	econf \
+		$(use_enable alsa alsa-seq) \
+		$(use_enable dbus) \
+		$(use_enable debug) \
+		$(use_enable portaudio) \
+		--enable-jack-version
+
+	eqmake5 ${PN}.pro -o ${PN}.mak
+}
+
+src_compile() {
+	emake -f ${PN}.mak
+}
+
+src_install() {
+	default
+
+	gunzip "${D}/usr/share/man/man1/qjackctl.fr.1.gz"
+	gunzip "${D}/usr/share/man/man1/qjackctl.1.gz"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}

diff --git a/media-sound/qjackctl/qjackctl-9999.ebuild b/media-sound/qjackctl/qjackctl-9999.ebuild
new file mode 100644
index 00000000000..c9e9519c845
--- /dev/null
+++ b/media-sound/qjackctl/qjackctl-9999.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic qmake-utils autotools git-r3 xdg-utils
+
+DESCRIPTION="Qt GUI to control the JACK Audio Connection Kit and ALSA sequencer connections"
+HOMEPAGE="http://qjackctl.sourceforge.net/"
+EGIT_REPO_URI="https://git.code.sf.net/p/qjackctl/code"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+
+IUSE="alsa dbus debug portaudio"
+
+RDEPEND="
+	app-arch/gzip
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	virtual/jack
+	alsa? ( media-libs/alsa-lib )
+	dbus? ( dev-qt/qtdbus:5 )
+	portaudio? ( media-libs/portaudio )"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5"
+
+src_prepare() {
+	eautoreconf
+
+	default
+}
+
+src_configure() {
+	append-cxxflags -std=c++11
+	econf \
+		$(use_enable alsa alsa-seq) \
+		$(use_enable dbus) \
+		$(use_enable debug) \
+		$(use_enable portaudio) \
+		--enable-jack-version
+
+	eqmake5 ${PN}.pro -o ${PN}.mak
+}
+
+src_compile() {
+	emake -f ${PN}.mak
+}
+
+src_install() {
+	default
+
+	gunzip "${D}/usr/share/man/man1/qjackctl.fr.1.gz"
+	gunzip "${D}/usr/share/man/man1/qjackctl.1.gz"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}