[gentoo-commits] repo/gentoo:master commit in: media-libs/vamp-plugin-sdk/

["David Seifert" <soap@gentoo.org>]

commit:     cd86291b815da3bd373a97d1d45cd47ef7a012f1
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 20 14:19:08 2019 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sun Oct 20 14:19:08 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cd86291b

media-libs/vamp-plugin-sdk: Port to EAPI 7

* Do not install static archives

Closes: https://bugs.gentoo.org/474768
Package-Manager: Portage-2.3.77, Repoman-2.3.17
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 .../vamp-plugin-sdk/vamp-plugin-sdk-2.7.1.ebuild   | 41 ++++++++++++++--------
 1 file changed, 26 insertions(+), 15 deletions(-)

diff --git a/media-libs/vamp-plugin-sdk/vamp-plugin-sdk-2.7.1.ebuild b/media-libs/vamp-plugin-sdk/vamp-plugin-sdk-2.7.1.ebuild
index 0791dd53403..7351cdb0de3 100644
--- a/media-libs/vamp-plugin-sdk/vamp-plugin-sdk-2.7.1.ebuild
+++ b/media-libs/vamp-plugin-sdk/vamp-plugin-sdk-2.7.1.ebuild
@@ -1,9 +1,9 @@
 # Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=7
 
-inherit toolchain-funcs eutils multilib multilib-minimal
+inherit toolchain-funcs multilib-minimal
 
 DESCRIPTION="Audio processing system for plugins to extract information from audio data"
 HOMEPAGE="https://www.vamp-plugins.org"
@@ -12,44 +12,55 @@ SRC_URI="https://code.soundsoftware.ac.uk/attachments/download/2206/${P}.tar.gz"
 LICENSE="BSD"
 SLOT="0"
 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 ~sparc x86"
-IUSE="doc static-libs"
+IUSE="doc"
 
-RDEPEND="media-libs/libsndfile"
-DEPEND="${RDEPEND}
-	media-libs/libsndfile[${MULTILIB_USEDEP}]
-	doc? ( app-doc/doxygen )"
+RDEPEND="media-libs/libsndfile:0=[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+BDEPEND="doc? ( app-doc/doxygen )"
 
 src_prepare() {
+	default
 	multilib_copy_sources
 }
 
 multilib_src_configure() {
 	# multilib for default search paths
-	sed -i -e "s:/usr/lib/vamp:${EPREFIX}/usr/$(get_libdir)/vamp:" src/vamp-hostsdk/PluginHostAdapter.cpp || die "sed failed"
+	sed -i -e "s:/usr/lib/vamp:${EPREFIX}/usr/$(get_libdir)/vamp:" \
+		src/vamp-hostsdk/PluginHostAdapter.cpp || die
 	econf
 }
 
 multilib_src_compile() {
-	emake AR="$(tc-getAR)" RANLIB="$(tc-getRANLIB)"
+	emake \
+		AR="$(tc-getAR)" \
+		RANLIB="$(tc-getRANLIB)"
 
 	if multilib_is_native_abi && use doc; then
-		cd build
+		cd build || die
 		doxygen || die "creating doxygen doc failed"
+		HTML_DOCS=( "${BUILD_DIR}"/build/doc/html/. )
 	fi
 }
 
 multilib_src_install() {
-	emake DESTDIR="${D}" INSTALL_SDK_LIBS="${EPREFIX}/usr/$(get_libdir)" INSTALL_PKGCONFIG="${EPREFIX}/usr/$(get_libdir)/pkgconfig" INSTALL_PLUGINS="${EPREFIX}/usr/$(get_libdir)/vamp" install
-	multilib_is_native_abi && use doc && dohtml -r build/doc/html/*
+	emake \
+		DESTDIR="${D}" \
+		INSTALL_SDK_LIBS="${EPREFIX}"/usr/$(get_libdir) \
+		INSTALL_PKGCONFIG="${EPREFIX}"/usr/$(get_libdir)/pkgconfig \
+		INSTALL_PLUGINS="${EPREFIX}"/usr/$(get_libdir)/vamp \
+		install
 }
 
 multilib_src_install_all() {
-	dodoc README* CHANGELOG
+	einstalldocs
+
+	# don't want static archives, #474768
+	find "${D}" -name '*.a' -delete || die
 }
 
 pkg_postinst() {
-	elog ""
+	elog
 	elog "You might also want to install some Vamp plugins."
 	elog "See media-plugins/vamp-*"
-	elog ""
+	elog
 }