From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1117288-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 8E8D8138334
for <garchives@archives.gentoo.org>; Wed, 16 Oct 2019 21:54:39 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id BBD89E0819;
Wed, 16 Oct 2019 21:54:38 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 92620E0819
for <gentoo-commits@lists.gentoo.org>; Wed, 16 Oct 2019 21:54:38 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id E07AA34BDCB
for <gentoo-commits@lists.gentoo.org>; Wed, 16 Oct 2019 21:54:36 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 6B909744
for <gentoo-commits@lists.gentoo.org>; Wed, 16 Oct 2019 21:54:35 +0000 (UTC)
From: "James Le Cuirot" <chewi@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "James Le Cuirot" <chewi@gentoo.org>
Message-ID: <1571262786.3c1315cd32bf21526dec379e956b5e7df705a366.chewi@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: games-fps/eduke32/
X-VCS-Repository: repo/gentoo
X-VCS-Files: games-fps/eduke32/eduke32-20190919.8133-r1.ebuild
X-VCS-Directories: games-fps/eduke32/
X-VCS-Committer: chewi
X-VCS-Committer-Name: James Le Cuirot
X-VCS-Revision: 3c1315cd32bf21526dec379e956b5e7df705a366
X-VCS-Branch: master
Date: Wed, 16 Oct 2019 21:54:35 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: cc0cf10c-1f8f-4147-8561-785fba4bff8c
X-Archives-Hash: a2b70faa7d573bd4c35094d5e4eb09ac
commit: 3c1315cd32bf21526dec379e956b5e7df705a366
Author: Conrad Kostecki <conrad <AT> kostecki <DOT> com>
AuthorDate: Wed Oct 16 08:00:44 2019 +0000
Commit: James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Wed Oct 16 21:53:06 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3c1315cd
games-fps/eduke32: fix timidity deps
Instead of depending on a specific timidity patchset,
the deps should be changed to depend on timidity itself,
as it already depends on all patchsets.
Closes: https://bugs.gentoo.org/697808
Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Conrad Kostecki <conrad <AT> kostecki.com>
Closes: https://github.com/gentoo/gentoo/pull/13316
Signed-off-by: James Le Cuirot <chewi <AT> gentoo.org>
games-fps/eduke32/eduke32-20190919.8133-r1.ebuild | 255 ++++++++++++++++++++++
1 file changed, 255 insertions(+)
diff --git a/games-fps/eduke32/eduke32-20190919.8133-r1.ebuild b/games-fps/eduke32/eduke32-20190919.8133-r1.ebuild
new file mode 100644
index 00000000000..bfa718b76cc
--- /dev/null
+++ b/games-fps/eduke32/eduke32-20190919.8133-r1.ebuild
@@ -0,0 +1,255 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop toolchain-funcs xdg-utils
+
+MY_BUILD="$(ver_cut 2)"
+MY_DATE="$(ver_cut 1)"
+
+MY_PV_HRP="5.4"
+MY_PV_OFFENSIVE_XXX="1.33"
+MY_PV_OPL="2.01"
+MY_PV_PSX="1.11"
+MY_PV_SC55="4.02"
+MY_PV_VOXELS="1.21"
+
+DESCRIPTION="An open source engine port of the classic PC first person shooter Duke Nukem 3D"
+HOMEPAGE="http://www.eduke32.com/"
+SRC_URI="
+ http://dukeworld.com/eduke32/synthesis/${MY_DATE}-${MY_BUILD}/${PN}_src_${MY_DATE}-${MY_BUILD}.tar.xz
+ http://www.eduke32.com/images/eduke32_classic.png
+ hrp? ( http://www.duke4.org/files/nightfright/hrp/duke3d_hrp.zip -> duke3d_hrp-${MY_PV_HRP}.zip )
+ offensive? ( http://www.duke4.org/files/nightfright/related/duke3d_xxx.zip -> duke3d_xxx-${MY_PV_OFFENSIVE_XXX}.zip )
+ opl? ( http://www.moddb.com/downloads/mirror/95750/102/ce9e8f422c6cccdb297852426e96740a -> duke3d_musopl-${MY_PV_OPL}.zip )
+ psx? ( http://www.duke4.org/files/nightfright/related/duke3d_psx.zip -> duke3d_psx-${MY_PV_PSX}.zip )
+ sc-55? ( http://www.duke4.org/files/nightfright/music/duke3d_music-sc55.zip -> duke3d_music-sc55-${MY_PV_SC55}.zip )
+ voxels? ( https://www.dropbox.com/s/yaxfahyvskyvt4r/duke3d_voxels.zip -> duke3d_voxels-${MY_PV_VOXELS}.zip )
+"
+
+LICENSE="BUILDLIC GPL-2 HRP"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~x86"
+IUSE="cdinstall demo flac fluidsynth gtk hrp offensive opengl opl png psx sc-55 server sdk timidity tools vorbis voxels vpx xmp"
+REQUIRED_USE="
+ cdinstall? ( !demo )
+ demo? ( !cdinstall )
+ hrp? ( ^^ ( demo cdinstall )
+ !voxels )
+ offensive? ( ^^ ( demo cdinstall ) )
+ opl? ( ^^ ( demo cdinstall )
+ !sc-55 )
+ psx? ( ^^ ( demo cdinstall ) )
+ sc-55? ( ^^ ( demo cdinstall )
+ !opl )
+ voxels? ( !hrp )
+ vpx? ( opengl )
+"
+
+RESTRICT="bindist"
+
+S="${WORKDIR}/${PN}_${MY_DATE}-${MY_BUILD}"
+
+RDEPEND="
+ media-libs/libsdl2[joystick,opengl?,sound,video]
+ media-libs/sdl2-mixer[flac?,fluidsynth?,midi,timidity?,vorbis?]
+ sys-libs/zlib:=
+ flac? ( media-libs/flac )
+ gtk? ( x11-libs/gtk+:2 )
+ opengl? (
+ virtual/glu
+ virtual/opengl
+ )
+ png? ( media-libs/libpng:0= )
+ vpx? ( media-libs/libvpx:= )
+ vorbis? (
+ media-libs/libogg
+ media-libs/libvorbis
+ )
+ xmp? ( media-libs/exempi:= )
+"
+
+DEPEND="
+ ${RDEPEND}
+ cdinstall? ( games-fps/duke3d-data )
+ demo? ( games-fps/duke3d-demodata )
+ timidity? ( media-sound/timidity++ )
+"
+
+BDEPEND="
+ app-arch/unzip
+ x86? ( dev-lang/nasm )
+"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-20190419.7615-wad2map-buildfix.patch"
+ "${FILESDIR}/${PN}-20190820.8043-log-to-tmpdir.patch"
+ "${FILESDIR}/${PN}-20190820.8043-search-duke3d-path.patch"
+)
+
+src_unpack() {
+ # Extract only the eduke32 archive
+ unpack ${PN}_src_${MY_DATE}-${MY_BUILD}.tar.xz
+
+ # Unpack only the documentation
+ if use hrp; then
+ unzip -q "${DISTDIR}"/duke3d_hrp-${MY_PV_HRP}.zip hrp_readme.txt hrp_todo.txt || die
+ fi
+ if use offensive; then
+ unzip -q "${DISTDIR}"/duke3d_xxx-${MY_PV_OFFENSIVE_XXX}.zip xxx_readme.txt || die
+ fi
+ if use opl; then
+ unzip -q "${DISTDIR}"/duke3d_musopl-${MY_PV_OPL}.zip readme.txt || die
+ mv readme.txt opl_readme.txt || die
+ fi
+ if use sc-55; then
+ unzip -q "${DISTDIR}"/duke3d_music-sc55-${MY_PV_SC55}.zip readme/music_readme.txt || die
+ fi
+ if use voxels; then
+ unzip -q "${DISTDIR}"/duke3d_voxels-${MY_PV_VOXELS}.zip voxelpack_readme.txt || die
+ fi
+}
+
+src_compile() {
+ local myemakeopts=(
+ ALLOCACHE_AS_MALLOC=0
+ AS=$(tc-getAS)
+ CC=$(tc-getCC)
+ CXX=$(tc-getCXX)
+ CLANG=0
+ CPLUSPLUS=1
+ CUSTOMOPT=""
+ DEBUGANYWAY=0
+ F_JUMP_TABLES=""
+ FORCEDEBUG=0
+ HAVE_FLAC=$(usex flac 1 0)
+ HAVE_GTK2=$(usex gtk 1 0)
+ HAVE_VORBIS=$(usex vorbis 1 0)
+ HAVE_XMP=$(usex xmp 1 0)
+ LINKED_GTK=$(usex gtk 1 0)
+ LTO=1
+ LUNATIC=0
+ KRANDDEBUG=0
+ MEMMAP=0
+ MIXERTYPE=SDL
+ NETCODE=$(usex server 1 0)
+ NOASM=0
+ OPTLEVEL=0
+ OPTOPT=""
+ PACKAGE_REPOSITORY=1
+ POLYMER=$(usex opengl 1 0)
+ PRETTY_OUTPUT=0
+ PROFILER=0
+ RELEASE=1
+ RENDERTYPE=SDL
+ SDL_TARGET=2
+ SIMPLE_MENU=0
+ STRIP=""
+ TANDALONE=0
+ STARTUP_WINDOW=$(usex gtk 1 0)
+ USE_OPENGL=$(usex opengl 1 0)
+ USE_LIBVPX=$(usex vpx 1 0)
+ USE_LIBPNG=$(usex png 1 0)
+ USE_LUAJIT_2_1=0
+ WITHOUT_GTK=$(usex gtk 0 1)
+ )
+
+ emake "${myemakeopts[@]}"
+
+ if use tools; then
+ emake utils "${myemakeopts[@]}"
+ fi
+}
+
+src_test() {
+ # There are no tests
+ # Instead it tries to build a test game, which does not compile
+ :;
+}
+
+src_install() {
+ dobin eduke32 mapster32 "${FILESDIR}"/eduke32-bin
+
+ if use tools; then
+ local tools=(
+ arttool
+ bsuite
+ cacheinfo
+ generateicon
+ givedepth
+ ivfrate
+ kextract
+ kgroup
+ kmd2tool
+ makesdlkeytrans
+ map2stl
+ md2tool
+ mkpalette
+ transpal
+ unpackssi
+ wad2art
+ wad2map
+ )
+
+ dobin "${tools[@]}"
+ fi
+
+ keepdir /usr/share/games/eduke32
+ insinto /usr/share/games/eduke32
+
+ if use hrp; then
+ doins "${DISTDIR}"/duke3d_hrp-${MY_PV_HRP}.zip
+ fi
+ if use offensive; then
+ doins "${DISTDIR}"/duke3d_xxx-${MY_PV_OFFENSIVE_XXX}.zip
+ fi
+ if use opl; then
+ doins "${DISTDIR}"/duke3d_musopl-${MY_PV_OPL}.zip
+ fi
+ if use psx; then
+ doins "${DISTDIR}"/duke3d_psx-${MY_PV_PSX}.zip
+ fi
+ if use sc-55; then
+ doins "${DISTDIR}"/duke3d_music-sc55-${MY_PV_SC55}.zip
+ fi
+ if use sdk; then
+ doins -r package/sdk
+ fi
+ if use voxels; then
+ doins "${DISTDIR}"/duke3d_voxels-${MY_PV_VOXELS}.zip
+ fi
+
+ newicon "${DISTDIR}"/eduke32_classic.png eduke32.png
+
+ make_desktop_entry eduke32-bin EDuke32 eduke32 Game
+ make_desktop_entry mapster32 Mapster32 eduke32 Game
+
+ local DOCS=( package/sdk/samples/*.txt source/build/doc/*.txt source/duke3d/src/lunatic/doc/*.txt )
+
+ if use hrp; then
+ DOCS+=( "${WORKDIR}"/hrp_readme.txt "${WORKDIR}"/hrp_todo.txt )
+ fi
+ if use offensive; then
+ DOCS+=( "${WORKDIR}"/xxx_readme.txt )
+ fi
+ if use opl; then
+ DOCS+=( "${WORKDIR}"/opl_readme.txt )
+ fi
+ if use sc-55; then
+ DOCS+=( "${WORKDIR}"/readme/music_readme.txt )
+ fi
+ if use voxels; then
+ DOCS+=( "${WORKDIR}"/voxelpack_readme.txt )
+ fi
+
+ einstalldocs
+}
+
+pkg_postinst() {
+ xdg_icon_cache_update
+}
+
+pkg_postrm() {
+ xdg_icon_cache_update
+}