[gentoo-commits] repo/gentoo:master commit in: dev-python/uranium/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     e8df467f3abf5ea56e9e249ddfb8380950fb6c98
Author:     Michael Perlov <perlovka <AT> gmail <DOT> com>
AuthorDate: Sat Sep 28 10:31:45 2019 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Wed Oct 16 05:21:58 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e8df467f

dev-python/uranium: version bump to 4.3.0

Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Michael Perlov <perlovka <AT> gmail.com>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 dev-python/uranium/Manifest             |  1 +
 dev-python/uranium/uranium-4.3.0.ebuild | 69 +++++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/dev-python/uranium/Manifest b/dev-python/uranium/Manifest
index c2ba4bfe8d3..bb4c1e16ceb 100644
--- a/dev-python/uranium/Manifest
+++ b/dev-python/uranium/Manifest
@@ -1,2 +1,3 @@
 DIST uranium-3.6.0.tar.gz 668552 BLAKE2B 84ab1eed5474bf14aec5b7782b332e9846d14f589c0dfa7366c74ad682fdc0a8e5ef94a0b9576f0e80cf792b49132d3abb3f17341a2e8570d08bf898231deca6 SHA512 41779e9cf76dff8f74252f668d1cf909c93f4f1416f75d2ed263f89fcfccfbcebce5580d8202d8d1697491139db448bbfa76e2dbc761dd24cb98030b3241e80d
 DIST uranium-4.2.0.tar.gz 711868 BLAKE2B 8098372704db0494519ab0a24046b72f2527695716286463e7ecffb776db351bfb4ffcd7b53276d59403b39e40ef605fb016e9ec57e18cd06e8f22f22d8ef732 SHA512 fab04efbb6337e366501ffc0336f208ddc0f9e568a2822363b84b6512268f2560a22bc71e745d30e66026d7a0bf9e150eda605ef8b511b59264407cab491eee1
+DIST uranium-4.3.0.tar.gz 899153 BLAKE2B 314dbeed1cce49d33439b2fa744d37e4b360edb041964d2c3336730295b88bb2af86df8eac8382a6696fbc9c1ba07fa0774089ec3aa7fd0f8fbb92c61ce2825b SHA512 eac28907ccd66e5a43012a6f5af2a97daea21f0e2832613562e848cca967e036fea117811d8a4cc519c1417a113449e7065233fc541347202c6a8ff85a9d60b7

diff --git a/dev-python/uranium/uranium-4.3.0.ebuild b/dev-python/uranium/uranium-4.3.0.ebuild
new file mode 100644
index 00000000000..00956f788e6
--- /dev/null
+++ b/dev-python/uranium/uranium-4.3.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6} )
+
+inherit cmake-utils python-single-r1
+
+MY_PN="Uranium"
+
+DESCRIPTION="A Python framework for building 3D printing related applications"
+HOMEPAGE="https://github.com/Ultimaker/Uranium"
+SRC_URI="https://github.com/Ultimaker/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND="${PYTHON_DEPS}
+	sys-devel/gettext
+	doc? ( app-doc/doxygen )
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/mypy[${PYTHON_USEDEP}]
+	)"
+
+RDEPEND="${PYTHON_DEPS}
+	~dev-libs/libarcus-${PV}:=[python,${PYTHON_USEDEP}]
+	dev-python/PyQt5[${PYTHON_USEDEP},declarative,network,svg]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=sci-libs/scipy-1.1[${PYTHON_USEDEP}]
+	sci-libs/Shapely[${PYTHON_USEDEP}]
+	dev-qt/qtquickcontrols:5
+	dev-qt/qtquickcontrols2:5"
+
+DEPEND="${RDEPEND}"
+
+DOCS=( README.md )
+
+PATCHES=( "${FILESDIR}/${PN}-3.3.0-fix-install-paths.patch" )
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DPYTHON_SITE_PACKAGES_DIR="$(python_get_sitedir)" )
+	cmake-utils_src_configure
+
+	if ! use debug; then
+		sed -i 's/logging.DEBUG/logging.ERROR/' plugins/ConsoleLogger/ConsoleLogger.py || die
+		sed -i 's/logging.DEBUG/logging.ERROR/' plugins/FileLogger/FileLogger.py || die
+	fi
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	if use doc; then
+		cmake-utils_src_compile doc
+		DOCS+=( html )
+	fi
+}
+
+src_install() {
+	cmake-utils_src_install
+	python_optimize "${D}/usr/$(get_libdir)"
+}