[gentoo-commits] repo/gentoo:master commit in: dev-util/dput-ng/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     2ae702785998778596473766a24520c9d1ee9ab0
Author:     Yuri Konotopov <ykonotopov <AT> gnome <DOT> org>
AuthorDate: Wed Oct  9 16:37:05 2019 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Sun Oct 13 16:55:14 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2ae70278

dev-util/dput-ng: version bump to 1.28

Closes: https://bugs.gentoo.org/696412
Package-Manager: Portage-2.3.76, Repoman-2.3.16
Signed-off-by: Yuri Konotopov <ykonotopov <AT> gnome.org>
Closes: https://github.com/gentoo/gentoo/pull/13237
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 dev-util/dput-ng/Manifest            |  1 +
 dev-util/dput-ng/dput-ng-1.28.ebuild | 85 ++++++++++++++++++++++++++++++++++++
 2 files changed, 86 insertions(+)

diff --git a/dev-util/dput-ng/Manifest b/dev-util/dput-ng/Manifest
index 1a531f401fb..c09fd0e18c5 100644
--- a/dev-util/dput-ng/Manifest
+++ b/dev-util/dput-ng/Manifest
@@ -1 +1,2 @@
 DIST dput-ng_1.10.tar.xz 82608 BLAKE2B e7b3769490ec0bf4de4f763380e9a50fd2c76778c2864a4ba45eb754f2dc4aa896e556ad86939f9bf003a68b1e185b51507dd0a015453dfb39965c63beab4964 SHA512 4a883350e7a0b47c121b752d1e0ab1470924319ef895f55742fc4d8f8a0cb3a0ab4ae18d54495ebc9229b0cbf18fa375848fcdcd2431ee1f66bff6433b9a3b08
+DIST dput-ng_1.28.tar.xz 85276 BLAKE2B d205d15aad1b81dcf2cc0b765c9724b21add32df39102b63502d99e5da73aa95efdf66e94f6226105ab2ae97a4bf8c43963784f3ddf2d03217ab5023a7a98f22 SHA512 cfd4a6143b33f29eb32b88972a204ab7a6c2f062299c76167434322ae5d6d2cf8654c5b4d1e96db90dbffe372a04e2a7691694ecf46787c7743dd9ac2b7b317e

diff --git a/dev-util/dput-ng/dput-ng-1.28.ebuild b/dev-util/dput-ng/dput-ng-1.28.ebuild
new file mode 100644
index 00000000000..9840d82797b
--- /dev/null
+++ b/dev-util/dput-ng/dput-ng-1.28.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7} )
+DISTUTILS_SINGLE_IMPL=1
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="Next generation Debian package upload tool"
+HOMEPAGE="https://people.debian.org/~paultag/dput-ng/"
+SRC_URI="mirror://debian/pool/main/d/${PN}/${PN}_${PV}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	dev-python/python-debian[${PYTHON_USEDEP}]
+	dev-python/paramiko[${PYTHON_USEDEP}]
+	dev-util/distro-info[python,${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	app-text/asciidoc
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/python-debian[${PYTHON_USEDEP}]
+		dev-util/debhelper
+	)"
+
+# Requires missing build-essential package
+RESTRICT="test"
+
+src_compile() {
+	distutils-r1_src_compile
+
+	mkdir man || die
+	for file in docs/man/*.man; do
+		a2x --doctype manpage --format manpage -D man \
+			"${file}" || die
+	done
+}
+
+src_install() {
+	local DPUT_BINARIES=( dcut dirt dput )
+	local DPUT_ETC=( metas profiles )
+	local DPUT_SHARE=(
+		codenames
+		commands
+		hooks
+		interfaces
+		schemas
+		uploaders
+	)
+
+	distutils-r1_src_install
+
+	for binary in ${DPUT_BINARIES[@]}; do
+		dobin bin/"${binary}"
+	done
+	python_fix_shebang "${D}"/usr/bin
+
+	insinto /etc/dput.d
+	for dir in ${DPUT_ETC[@]}; do
+		doins -r skel/"${dir}"
+	done
+
+	insinto /usr/share/"${PN}"
+	for dir in ${DPUT_SHARE[@]}; do
+		doins -r skel/"${dir}"
+	done
+
+	# doman incorrectly treats "cf" in dput.cf.5 as a lang code
+	doman -i18n="" man/*
+
+	newbashcomp debian/dcut-completion dcut
+	newbashcomp debian/dput-completion dput
+}
+
+python_test() {
+	# test_configs.py failing
+	# https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=824652
+	nosetests || die "Tests failed under ${EPYTHON}"
+}