[gentoo-commits] repo/gentoo:master commit in: dev-libs/appstream/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     c97d614ec39328069b9257c17542a06d57de53bc
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Oct  3 20:16:36 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Oct  3 20:38:45 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c97d614e

dev-libs/appstream: 0.12.9 version bump

Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 dev-libs/appstream/Manifest                |  1 +
 dev-libs/appstream/appstream-0.12.9.ebuild | 71 ++++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/dev-libs/appstream/Manifest b/dev-libs/appstream/Manifest
index 0e79187094c..60fca643a4d 100644
--- a/dev-libs/appstream/Manifest
+++ b/dev-libs/appstream/Manifest
@@ -1,2 +1,3 @@
 DIST AppStream-0.12.7.tar.xz 1958948 BLAKE2B 51a70395e4801ceeb3e97ac081f4c45be242cca14728f8efc5eec0d4b3cfa4cc9fab9ef7429c18e9bbb0dedb693a847258be1b11491155658a6ffa2a28358e35 SHA512 53ca7ebde3fcd345a895527da2ac5d829a09f25d28836a867b500282fba3465bde657cd75a4030cb831022f7a0d9f50aadb36078d62924e4d0edad6bfe3c5561
 DIST AppStream-0.12.8.tar.xz 1992072 BLAKE2B ae1d6801119798f360b7eae36b0c46b0511a93ae00adb2437e7dda830d5293c622b04475664055bee392dc824f398d42c6a0a4000392f82fc8bdfc828fa0295e SHA512 4354ef1840d919102647feffc38687f508b14fe9c047c868448347d888aa821dd8a4d25787a2ffb55247f8e9e20e9e03ba330ad74ad61d476be0c414c04a7c30
+DIST AppStream-0.12.9.tar.xz 2023312 BLAKE2B aa5de7936909be54401e4df80363c9b59ad60dc29b3d02ef1ed8203dd480dfb4222816cde5ea6e469039448684142afc028275e619665f15cef99af6745d80e8 SHA512 af3d5e7885ee09fb6ef9ea0a5c2386141736166ce42912e618f1ee04f2b28866b27c7c5e326221574eb78933b32de8db9f76023bf54e528aded1607e5130992e

diff --git a/dev-libs/appstream/appstream-0.12.9.ebuild b/dev-libs/appstream/appstream-0.12.9.ebuild
new file mode 100644
index 00000000000..82e775582a5
--- /dev/null
+++ b/dev-libs/appstream/appstream-0.12.9.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson xdg-utils
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/ximion/${PN}"
+else
+	SRC_URI="https://www.freedesktop.org/software/appstream/releases/AppStream-${PV}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+	S="${WORKDIR}/AppStream-${PV}"
+fi
+
+DESCRIPTION="Cross-distro effort for providing metadata for software in the Linux ecosystem"
+HOMEPAGE="https://www.freedesktop.org/wiki/Distributions/AppStream/"
+
+LICENSE="LGPL-2.1+ GPL-2+"
+# check as_api_level
+SLOT="0/4"
+IUSE="apt doc +introspection qt5 test"
+
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-libs/libxslt
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	doc? ( app-text/docbook-xml-dtd:4.5 )
+	test? (
+		dev-qt/linguist-tools:5
+		qt5? ( dev-qt/qttest:5 )
+	)
+"
+DEPEND="
+	dev-db/lmdb:=
+	>=dev-libs/glib-2.54:2
+	dev-libs/libxml2:2
+	dev-libs/libyaml
+	dev-libs/snowball-stemmer
+	introspection? ( >=dev-libs/gobject-introspection-1.56:= )
+	qt5? ( dev-qt/qtcore:5 )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	sed -e "/^as_doc_target_dir/s/appstream/${PF}/" -i docs/meson.build || die
+	if ! use test; then
+		sed -e "/^subdir.*tests/s/^/#DONT /" -i {,qt/}meson.build || die # bug 675944
+	fi
+}
+
+src_configure() {
+	xdg_environment_reset
+
+	local emesonargs=(
+		-Dapidocs=false
+		-Ddocs=false
+		-Dmaintainer=false
+		-Dstemming=true
+		-Dvapi=false
+		-Dapt-support=$(usex apt true false)
+		-Dinstall-docs=$(usex doc true false)
+		-Dgir=$(usex introspection true false)
+		-Dqt=$(usex qt5 true false)
+	)
+
+	meson_src_configure
+}