[gentoo-commits] repo/gentoo:master commit in: dev-java/jackson/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     571aeaecbaf3738fa9204aeb4a34de167da23021
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Wed Sep 25 17:22:46 2019 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Wed Sep 25 17:26:14 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=571aeaec

dev-java/jackson-2.9.10: bump

Bug: https://bugs.gentoo.org/695532
Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 dev-java/jackson/Manifest              |  1 +
 dev-java/jackson/jackson-2.9.10.ebuild | 58 ++++++++++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-java/jackson/Manifest b/dev-java/jackson/Manifest
index 65ea33b93b3..87023f2011c 100644
--- a/dev-java/jackson/Manifest
+++ b/dev-java/jackson/Manifest
@@ -1 +1,2 @@
 DIST jackson-core-2.8.5.tar.gz 338770 BLAKE2B d02643ecd2fd2528d0fedba7aae54a88ccb223491f1198f3bb8e8f6f70d5a70be3d250e57c9b5b17bfe44c0508eab725fd57cb17a1e2d5224c1ef6dacfdb3795 SHA512 43a2a7959b182ecf3a805d138bb1d49e1dd496d9a36274f5d9f2cdec5f06d02b1cde0e932216768689609faec2bd3f8d7747c61db2a12d0ae68bf22e87a4782c
+DIST jackson-core-2.9.10.tar.gz 416803 BLAKE2B 9d8efc39b09b9619da301dc7fec3bd6339133c3fea3af46bbd77530883662b3b1d4ba2536cb8bd7ff7609a79ae6cfce135a3a5d75076bb7884e5e2878ac0107b SHA512 26b22e3fa60190877f5227c936ee32fdb4014347307904b140a6c787bb732df598b0ed48e7014cb6e51172abe52783e4d866f135706c8ebc77e24bdf087e9e71

diff --git a/dev-java/jackson/jackson-2.9.10.ebuild b/dev-java/jackson/jackson-2.9.10.ebuild
new file mode 100644
index 00000000000..20987cc01db
--- /dev/null
+++ b/dev-java/jackson/jackson-2.9.10.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="High-performance JSON processor"
+HOMEPAGE="https://github.com/FasterXML/jackson-core"
+SRC_URI="https://github.com/FasterXML/${PN}-core/archive/${PN}-core-${PV}.tar.gz"
+LICENSE="Apache-2.0"
+SLOT="2"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND=">=virtual/jre-1.7"
+DEPEND=">=virtual/jdk-1.7
+	test? ( dev-java/junit:4 )"
+
+S="${WORKDIR}/${PN}-core-${PN}-core-${PV}"
+JAVA_SRC_DIR="src/main/java"
+
+src_prepare() {
+	default
+
+	sed -e 's:@package@:com.fasterxml.jackson.core.json:g' \
+		-e "s:@projectversion@:${PV}:g" \
+		-e 's:@projectgroupid@:com.fasterxml.jackson.core:g' \
+		-e 's:@projectartifactid@:jackson-core:g' \
+		"${JAVA_SRC_DIR}/com/fasterxml/jackson/core/json/PackageVersion.java.in" \
+		> "${JAVA_SRC_DIR}/com/fasterxml/jackson/core/json/PackageVersion.java" || die
+
+	java-pkg-2_src_prepare
+}
+
+src_compile() {
+	java-pkg-simple_src_compile
+	java-pkg_addres ${PN}.jar src/main/resources
+}
+
+src_install() {
+	java-pkg-simple_src_install
+	dodoc README.md release-notes/{CREDITS,VERSION}-2.x
+}
+
+src_test() {
+	cd src/test/java || die
+
+	local CP=".:../resources:${S}/${PN}.jar:$(java-pkg_getjars junit-4)"
+	local TESTS=$(find * -name "Test*.java")
+	TESTS="${TESTS//.java}"
+	TESTS="${TESTS//\//.}"
+
+	ejavac -cp "${CP}" -d . $(find * -name "*.java")
+	ejunit4 -classpath "${CP}" ${TESTS}
+}