[gentoo-commits] repo/gentoo:master commit in: games-strategy/colobot/

["Michał Górny" <mgorny@gentoo.org>]

commit:     94ac1ac56f74cebb597dac79e8780f37a8acb725
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Sep 23 16:09:31 2019 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Sep 23 17:39:29 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=94ac1ac5

games-strategy/colobot: Bump to 0.1.12

Closes: https://bugs.gentoo.org/687994
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 games-strategy/colobot/Manifest              |  1 +
 games-strategy/colobot/colobot-0.1.12.ebuild | 57 ++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/games-strategy/colobot/Manifest b/games-strategy/colobot/Manifest
index e61203e4f87..eeafb000c2b 100644
--- a/games-strategy/colobot/Manifest
+++ b/games-strategy/colobot/Manifest
@@ -1 +1,2 @@
 DIST colobot-0.1.11.tar.gz 1430595 BLAKE2B 6e4a23f17631031a6f502b045637949d99bfcf8aa723f11c406c8cdb9b201b9a2771de8b8c92829bc890848a19eb182bc30a45a51e6d281ce64370f6c7a0d8a5 SHA512 fe32bc56b6fae9435c74a73b694b7d2b93667e5d15b1c57a7558e492613f0a5d4cab72ff341ab4c921150137282cc71292a1e31eb1ed06c752de33c50120f20e
+DIST colobot-gold-0.1.12-alpha.tar.gz 1468594 BLAKE2B 2b470e8b074e4a973b751062dca2358396066d8816c2b1b5b44649b798610dccd73ab5fed4086f2aa8d4495f3de69dd8b72b45f97f23f66b18a50fc976bf25ef SHA512 63647a16b376db6544830f96e7d323c0f58003645bf636abd1cab0ffd47b39b0bef47191d584f5156b75324d75dfdfdcabe8b89be565087c37c367ca366f3cbe

diff --git a/games-strategy/colobot/colobot-0.1.12.ebuild b/games-strategy/colobot/colobot-0.1.12.ebuild
new file mode 100644
index 00000000000..3c3762f6152
--- /dev/null
+++ b/games-strategy/colobot/colobot-0.1.12.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# upstream CMakeLists.txt are buggy
+CMAKE_MAKEFILE_GENERATOR=emake
+inherit cmake-utils desktop xdg-utils
+
+DESCRIPTION="Colobot is an educational real-time strategy video game featuring 3D graphics"
+HOMEPAGE="https://colobot.info/"
+SRC_URI="https://github.com/colobot/colobot/archive/${PN}-gold-${PV}-alpha.tar.gz"
+S="${WORKDIR}/${PN}-${PN}-gold-${PV}-alpha"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="devbuild doc +openal test tools"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-games/physfs
+	dev-libs/boost:=
+	media-libs/glew:0
+	media-libs/libogg
+	media-libs/libpng:0=
+	media-libs/libsdl2:=
+	media-libs/libsndfile:=
+	media-libs/libvorbis:=
+	media-libs/sdl2-image
+	media-libs/sdl2-ttf
+	media-sound/vorbis-tools
+	sys-devel/gettext
+	openal? ( media-libs/openal )"
+RDEPEND="${DEPEND}
+	games-strategy/colobot-data"
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEV_BUILD=$(usex devbuild)
+		-DTESTS=$(usex test)
+		-DTOOLS=$(usex tools)
+		-DINSTALL_DOCS=$(usex doc)
+		-DOPENAL_SOUND=$(usex openal)
+		-DCOLOBOT_INSTALL_BIN_DIR="${EPREFIX}"/usr/bin
+		-DCOLOBOT_INSTALL_LIB_DIR="${EPREFIX}"/usr/$(get_libdir)
+	)
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}