From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1110411-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 33767138335
for <garchives@archives.gentoo.org>; Thu, 12 Sep 2019 07:49:36 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id D5500E0970;
Thu, 12 Sep 2019 07:49:33 +0000 (UTC)
Received: from smtp.gentoo.org (dev.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 44952E0970
for <gentoo-commits@lists.gentoo.org>; Thu, 12 Sep 2019 07:49:32 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id DC71634B07A
for <gentoo-commits@lists.gentoo.org>; Thu, 12 Sep 2019 07:49:30 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 79BA0615
for <gentoo-commits@lists.gentoo.org>; Thu, 12 Sep 2019 07:49:28 +0000 (UTC)
From: "Andreas Sturmlechner" <asturm@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Andreas Sturmlechner" <asturm@gentoo.org>
Message-ID: <1568273429.999c06930e5bcb4c842756e56f3e2047315b9407.asturm@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-qt/qtwebkit/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-qt/qtwebkit/Manifest dev-qt/qtwebkit/qtwebkit-5.212.0_pre20190629.ebuild
X-VCS-Directories: dev-qt/qtwebkit/
X-VCS-Committer: asturm
X-VCS-Committer-Name: Andreas Sturmlechner
X-VCS-Revision: 999c06930e5bcb4c842756e56f3e2047315b9407
X-VCS-Branch: master
Date: Thu, 12 Sep 2019 07:49:28 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 0af62f24-a0bc-42c6-a571-41858e8cb6ca
X-Archives-Hash: 8814ad315783d223cc55dc51818709d9
commit: 999c06930e5bcb4c842756e56f3e2047315b9407
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Sep 11 16:51:06 2019 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Sep 12 07:30:29 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=999c0693
dev-qt/qtwebkit: 5.212.0_pre20190629 snapshot bump
Package-Manager: Portage-2.3.75, Repoman-2.3.17
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
dev-qt/qtwebkit/Manifest | 1 +
.../qtwebkit/qtwebkit-5.212.0_pre20190629.ebuild | 140 +++++++++++++++++++++
2 files changed, 141 insertions(+)
diff --git a/dev-qt/qtwebkit/Manifest b/dev-qt/qtwebkit/Manifest
index 2edec829aec..1e6cb48c55f 100644
--- a/dev-qt/qtwebkit/Manifest
+++ b/dev-qt/qtwebkit/Manifest
@@ -1 +1,2 @@
+DIST qtwebkit-5.212.0-alpha3.tar.xz 12457896 BLAKE2B 1b6ce78706a9696f0eb1fbe287d0d095d0089daf645a9ca60f9f31b9057669180b14d67a3bdfb387fc09dbbeee658c0e895a95edc46b2020f06f2b58188ba65d SHA512 38794514b886de3fa63a41277c2bcbb970e87a12070962b527e3898466cf7ad3b65ce4588669498415d365310b37729e81aabb457808fe11120558ef8e35445f
DIST qtwebkit-5.212.0_pre20180120.tar.gz 18830192 BLAKE2B a74329c424f5546cbbfda8f398da8547a78661c66e26e8168ba2fc35140070cbd0e826aeadc6b4f1b30ef3f8dc5259a017fb4cb73990b1f03ed541afcab50ec0 SHA512 582b0c5cb10756d88206a9b935a868026f2c2294c6476c0668ad416880b921735efbad32635671daa89792ba9a6d4ff397534df150fe641d984d5784ce0bf047
diff --git a/dev-qt/qtwebkit/qtwebkit-5.212.0_pre20190629.ebuild b/dev-qt/qtwebkit/qtwebkit-5.212.0_pre20190629.ebuild
new file mode 100644
index 00000000000..ce0302f95ae
--- /dev/null
+++ b/dev-qt/qtwebkit/qtwebkit-5.212.0_pre20190629.ebuild
@@ -0,0 +1,140 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+USE_RUBY="ruby24 ruby25 ruby26"
+MY_P="${PN}-${PV/_pre20190629/-alpha3}" # present as upgrade over previous snapshot
+inherit check-reqs cmake-utils flag-o-matic python-any-r1 qmake-utils ruby-single toolchain-funcs
+
+DESCRIPTION="WebKit rendering library for the Qt5 framework (deprecated)"
+HOMEPAGE="https://www.qt.io/"
+SRC_URI="https://github.com/annulen/webkit/releases/download/${MY_P}/${MY_P}.tar.xz"
+
+LICENSE="BSD LGPL-2+"
+SLOT="5/5.212"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="geolocation gles2 +gstreamer +hyphen +jit multimedia nsplugin opengl orientation +printsupport qml webp X"
+
+REQUIRED_USE="
+ nsplugin? ( X )
+ qml? ( opengl )
+ ?? ( gstreamer multimedia )
+"
+
+# Dependencies found at Source/cmake/OptionsQt.cmake
+QT_MIN_VER="5.9.1:5"
+BDEPEND="
+ ${PYTHON_DEPS}
+ ${RUBY_DEPS}
+ dev-lang/perl
+ dev-util/gperf
+ >=sys-devel/bison-2.4.3
+ sys-devel/flex
+ virtual/pkgconfig
+"
+DEPEND="
+ dev-db/sqlite:3
+ dev-libs/icu:=
+ dev-libs/libxml2
+ dev-libs/libxslt
+ >=dev-qt/qtcore-${QT_MIN_VER}
+ >=dev-qt/qtgui-${QT_MIN_VER}
+ >=dev-qt/qtnetwork-${QT_MIN_VER}
+ >=dev-qt/qtwidgets-${QT_MIN_VER}=
+ media-libs/libpng:0=
+ virtual/jpeg:0
+ geolocation? ( >=dev-qt/qtpositioning-${QT_MIN_VER} )
+ gstreamer? (
+ dev-libs/glib:2
+ media-libs/gstreamer:1.0
+ media-libs/gst-plugins-bad:1.0
+ media-libs/gst-plugins-base:1.0
+ )
+ hyphen? ( dev-libs/hyphen )
+ multimedia? ( >=dev-qt/qtmultimedia-${QT_MIN_VER}[widgets] )
+ opengl? (
+ >=dev-qt/qtgui-${QT_MIN_VER}[gles2=]
+ >=dev-qt/qtopengl-${QT_MIN_VER}[gles2=]
+ )
+ orientation? ( >=dev-qt/qtsensors-${QT_MIN_VER} )
+ printsupport? ( >=dev-qt/qtprintsupport-${QT_MIN_VER} )
+ qml? (
+ >=dev-qt/qtdeclarative-${QT_MIN_VER}
+ >=dev-qt/qtwebchannel-${QT_MIN_VER}[qml]
+ )
+ webp? ( media-libs/libwebp:= )
+ X? (
+ x11-libs/libX11
+ x11-libs/libXcomposite
+ x11-libs/libXrender
+ )
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+CHECKREQS_DISK_BUILD="16G" # bug 417307
+
+_check_reqs() {
+ if [[ ${MERGE_TYPE} != binary ]] && is-flagq "-g*" && ! is-flagq "-g*0"; then
+ einfo "Checking for sufficient disk space to build ${PN} with debugging flags"
+ check-reqs_$1
+ fi
+}
+
+pkg_pretend() {
+ _check_reqs pkg_pretend
+}
+
+pkg_setup() {
+ _check_reqs pkg_setup
+ python-any-r1_pkg_setup
+}
+
+src_configure() {
+ # Respect CC, otherwise fails on prefix, bug #395875
+ tc-export CC
+
+ # Multiple rendering bugs on youtube, github, etc without this, bug #547224
+ append-flags $(test-flags -fno-strict-aliasing)
+
+ local mycmakeargs=(
+ -DPORT=Qt
+ -DENABLE_API_TESTS=OFF
+ -DENABLE_TOOLS=OFF
+ -DENABLE_GEOLOCATION=$(usex geolocation)
+ -DUSE_GSTREAMER=$(usex gstreamer)
+ -DUSE_LIBHYPHEN=$(usex hyphen)
+ -DENABLE_JIT=$(usex jit)
+ -DUSE_QT_MULTIMEDIA=$(usex multimedia)
+ -DENABLE_NETSCAPE_PLUGIN_API=$(usex nsplugin)
+ -DENABLE_OPENGL=$(usex opengl)
+ -DENABLE_PRINT_SUPPORT=$(usex printsupport)
+ -DENABLE_DEVICE_ORIENTATION=$(usex orientation)
+ -DENABLE_WEBKIT2=$(usex qml)
+ $(cmake-utils_use_find_package webp WebP)
+ -DENABLE_X11_TARGET=$(usex X)
+ )
+
+ if has_version "virtual/rubygems[ruby_targets_ruby26]"; then
+ mycmakeargs+=( -DRUBY_EXECUTABLE=$(type -P ruby26) )
+ elif has_version "virtual/rubygems[ruby_targets_ruby25]"; then
+ mycmakeargs+=( -DRUBY_EXECUTABLE=$(type -P ruby25) )
+ else
+ mycmakeargs+=( -DRUBY_EXECUTABLE=$(type -P ruby24) )
+ fi
+
+ cmake-utils_src_configure
+}
+
+src_install() {
+ cmake-utils_src_install
+
+ # bug 572056
+ if [[ ! -f ${ED}$(qt5_get_libdir)/libQt5WebKit.so ]]; then
+ eerror "${CATEGORY}/${PF} could not build due to a broken ruby environment."
+ die 'Check "eselect ruby" and ensure you have a working ruby in your $PATH'
+ fi
+}