From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1110031-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 841AA138334
for <garchives@archives.gentoo.org>; Mon, 9 Sep 2019 18:48:26 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id CA345E092F;
Mon, 9 Sep 2019 18:48:25 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 9FF3DE092F
for <gentoo-commits@lists.gentoo.org>; Mon, 9 Sep 2019 18:48:25 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 9C47F34AF2C
for <gentoo-commits@lists.gentoo.org>; Mon, 9 Sep 2019 18:48:24 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id BE73D7CD
for <gentoo-commits@lists.gentoo.org>; Mon, 9 Sep 2019 18:48:22 +0000 (UTC)
From: "Georgy Yakovlev" <gyakovlev@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Georgy Yakovlev" <gyakovlev@gentoo.org>
Message-ID: <1568054894.7b56def091dede93b9bc403eab5f2b1f559296ad.gyakovlev@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-irc/weechat/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-irc/weechat/Manifest net-irc/weechat/weechat-2.6.ebuild
X-VCS-Directories: net-irc/weechat/
X-VCS-Committer: gyakovlev
X-VCS-Committer-Name: Georgy Yakovlev
X-VCS-Revision: 7b56def091dede93b9bc403eab5f2b1f559296ad
X-VCS-Branch: master
Date: Mon, 9 Sep 2019 18:48:22 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 329735e9-e40e-4846-a25f-f07d4f974c4e
X-Archives-Hash: 847d95992028906f203f73410fefe921
commit: 7b56def091dede93b9bc403eab5f2b1f559296ad
Author: Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
AuthorDate: Mon Sep 9 18:43:11 2019 +0000
Commit: Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
CommitDate: Mon Sep 9 18:48:14 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7b56def0
net-irc/weechat: bump to 2.6
removed python libs handling from ebuild, it just uses pkg-config now
Package-Manager: Portage-2.3.75, Repoman-2.3.17
Signed-off-by: Georgy Yakovlev <gyakovlev <AT> gentoo.org>
net-irc/weechat/Manifest | 1 +
net-irc/weechat/weechat-2.6.ebuild | 147 +++++++++++++++++++++++++++++++++++++
2 files changed, 148 insertions(+)
diff --git a/net-irc/weechat/Manifest b/net-irc/weechat/Manifest
index a0cf9a6842e..ef9dfaea465 100644
--- a/net-irc/weechat/Manifest
+++ b/net-irc/weechat/Manifest
@@ -1 +1,2 @@
DIST weechat-2.5.tar.xz 2067180 BLAKE2B 5ef2a20d0f4e72958f8523c46eac4acf8223d70efbadc78a1a5623b0e63e11acbe1c8e5ec739f56764c6825393902626e234269646031971a0f58fbd314f8918 SHA512 af0135009b799d40790c09da5419c950a6c750264a556de418b0ba4f396ecbde2aadeae5cbea3f2e98fc9926f07439e28beac00cb0019dc6752c1a5640a9834e
+DIST weechat-2.6.tar.xz 2080092 BLAKE2B e54d8493de7783e18e0de3a7280088a27a70b270a2d7a504ad35c4091e03a0d3c2f3fd19260b700bb115e3804ab4d6d8963bea46faad1368f3dd0569c0595add SHA512 cf56692e12b2e034675d4c15a8822836b2fcf93d584948e338d263f5a7207edf4599cc72bfb940427146f5f75e7239207cf54f5ed07dd5b6119f68c445725a2d
diff --git a/net-irc/weechat/weechat-2.6.ebuild b/net-irc/weechat/weechat-2.6.ebuild
new file mode 100644
index 00000000000..024f0d1b0d0
--- /dev/null
+++ b/net-irc/weechat/weechat-2.6.ebuild
@@ -0,0 +1,147 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
+
+inherit cmake-utils python-single-r1 xdg-utils
+
+if [[ ${PV} == "9999" ]] ; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/weechat/weechat.git"
+else
+ SRC_URI="https://weechat.org/files/src/${P}.tar.xz"
+ KEYWORDS="~amd64 ~arm ~x86 ~x64-macos"
+fi
+
+DESCRIPTION="Portable and multi-interface IRC client"
+HOMEPAGE="https://weechat.org/"
+
+LICENSE="GPL-3"
+SLOT="0"
+
+NETWORKS="+irc"
+PLUGINS="+alias +buflist +charset +exec +fifo +fset +logger +relay +scripts +spell +trigger +xfer"
+# dev-lang/v8 was dropped from Gentoo so we can't enable javascript support
+SCRIPT_LANGS="guile lua +perl php +python ruby tcl"
+LANGS=" cs de es fr it ja pl ru"
+IUSE="doc man nls +ssl test ${SCRIPT_LANGS} ${PLUGINS} ${INTERFACES} ${NETWORKS}"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+ dev-libs/libgcrypt:0=
+ net-misc/curl[ssl]
+ sys-libs/ncurses:0=
+ sys-libs/zlib
+ charset? ( virtual/libiconv )
+ guile? ( >=dev-scheme/guile-2.0 )
+ lua? ( dev-lang/lua:0[deprecated] )
+ nls? ( virtual/libintl )
+ perl? ( dev-lang/perl:= )
+ php? ( >=dev-lang/php-7.0:* )
+ python? ( ${PYTHON_DEPS} )
+ ruby? ( || ( dev-lang/ruby:2.6 dev-lang/ruby:2.5 dev-lang/ruby:2.4 ) )
+ ssl? ( net-libs/gnutls )
+ spell? ( app-text/aspell )
+ tcl? ( >=dev-lang/tcl-8.4.15:0= )
+"
+DEPEND="${RDEPEND}
+ test? ( dev-util/cpputest )
+"
+
+BDEPEND="
+ doc? ( >=dev-ruby/asciidoctor-1.5.4 )
+ man? ( >=dev-ruby/asciidoctor-1.5.4 )
+ nls? ( >=sys-devel/gettext-0.15 )
+"
+
+DOCS="AUTHORS.adoc ChangeLog.adoc Contributing.adoc ReleaseNotes.adoc README.adoc"
+
+# tests need to be fixed to not use system plugins if weechat is already installed
+RESTRICT="test"
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ cmake-utils_src_prepare
+
+ # install only required translations
+ local i
+ for i in ${LANGS} ; do
+ if ! has ${i} ${LINGUAS-${i}} ; then
+ sed -i \
+ -e "/${i}.po/d" \
+ po/CMakeLists.txt || die
+ fi
+ done
+
+ # install only required documentation ; en always
+ for i in $(grep add_subdirectory doc/CMakeLists.txt \
+ | sed -e 's/.*add_subdirectory(\(..\)).*/\1/' -e '/en/d'); do
+ if ! has ${i} ${LINGUAS-${i}} ; then
+ sed -i \
+ -e '/add_subdirectory('${i}')/d' \
+ doc/CMakeLists.txt || die
+ fi
+ done
+
+ # install docs in correct directory
+ sed -i "s#\${SHAREDIR}/doc/\${PROJECT_NAME}#\0-${PV}/html#" doc/*/CMakeLists.txt || die
+
+ if [[ ${CHOST} == *-darwin* ]]; then
+ # fix linking error on Darwin
+ sed -i "s/+ get_config_var('LINKFORSHARED')//" \
+ cmake/FindPython.cmake || die
+ # allow to find the plugins by default
+ sed -i 's/".so,.dll"/".bundle,.so,.dll"/' \
+ src/core/wee-config.c || die
+ fi
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DLIBDIR=/usr/$(get_libdir)
+ -DENABLE_JAVASCRIPT=OFF
+ -DENABLE_LARGEFILE=ON
+ -DENABLE_NCURSES=ON
+ -DENABLE_ALIAS=$(usex alias)
+ -DENABLE_BUFLIST=$(usex buflist)
+ -DENABLE_CHARSET=$(usex charset)
+ -DENABLE_DOC=$(usex doc)
+ -DENABLE_EXEC=$(usex exec)
+ -DENABLE_FIFO=$(usex fifo)
+ -DENABLE_FSET=$(usex fset)
+ -DENABLE_GNUTLS=$(usex ssl)
+ -DENABLE_GUILE=$(usex guile)
+ -DENABLE_IRC=$(usex irc)
+ -DENABLE_LOGGER=$(usex logger)
+ -DENABLE_LUA=$(usex lua)
+ -DENABLE_MAN=$(usex man)
+ -DENABLE_NLS=$(usex nls)
+ -DENABLE_PERL=$(usex perl)
+ -DENABLE_PHP=$(usex php)
+ -DENABLE_PYTHON=$(usex python)
+ -DENABLE_RELAY=$(usex relay)
+ -DENABLE_RUBY=$(usex ruby)
+ -DENABLE_SCRIPT=$(usex scripts)
+ -DENABLE_SCRIPTS=$(usex scripts)
+ -DENABLE_SPELL=$(usex spell)
+ -DENABLE_TCL=$(usex tcl)
+ -DENABLE_TESTS=$(usex test)
+ -DENABLE_TRIGGER=$(usex trigger)
+ -DENABLE_XFER=$(usex xfer)
+ )
+
+ cmake-utils_src_configure
+}
+
+pkg_postinst() {
+ xdg_icon_cache_update
+}
+
+pkg_postrm() {
+ xdg_icon_cache_update
+}