[gentoo-commits] repo/gentoo:master commit in: sys-power/intel-undervolt/

["Georgy Yakovlev" <gyakovlev@gentoo.org>]

commit:     124b6426777e0d11a80bce5ed6c1a13d9c122c2c
Author:     Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
AuthorDate: Fri Aug 30 20:18:58 2019 +0000
Commit:     Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
CommitDate: Fri Aug 30 20:25:59 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=124b6426

sys-power/intel-undervolt: bump to 1.7

Thanks-to: Matthew Thode <prometheanfire <AT> gentoo.org>
Package-Manager: Portage-2.3.73, Repoman-2.3.17
Signed-off-by: Georgy Yakovlev <gyakovlev <AT> gentoo.org>

 sys-power/intel-undervolt/Manifest                 |  1 +
 .../intel-undervolt/intel-undervolt-1.7.ebuild     | 61 ++++++++++++++++++++++
 sys-power/intel-undervolt/metadata.xml             |  3 ++
 3 files changed, 65 insertions(+)

diff --git a/sys-power/intel-undervolt/Manifest b/sys-power/intel-undervolt/Manifest
index 6b09153cf63..e21f6df73d7 100644
--- a/sys-power/intel-undervolt/Manifest
+++ b/sys-power/intel-undervolt/Manifest
@@ -1 +1,2 @@
 DIST intel-undervolt-1.6.tar.gz 22465 BLAKE2B 947f3e3f94316a9988fc0311faa23b07e8e0a99afb737232e6e581f45cca89124a49e47bbc85eb0e836b7fc7f966869910fe4d42581e47d98d8c036390c3dec2 SHA512 1c1de1083654085d6711aad28d2815f2aa05d08b7fddbee425b59ab8109dc1e635c2a9bdda8ba0221420e9e00fcd61013bd4a4633d05ede87808c49898772db3
+DIST intel-undervolt-1.7.tar.gz 31481 BLAKE2B 0daade381b492184616356f097de32d14c76d6ab3f7dd59240fb25f92ee1b9aebb16cbef8b6836e16e361a9560b000655470140c31b5822fed7bd90e0b9d9bf2 SHA512 727eddd47a92f6092e89f9326c6b453785fac6155f2c2c50887f9a90704226e6abaf27b4a91cabd4783c4477371699a92186fe7847ac9218da9c26fb295a5304

diff --git a/sys-power/intel-undervolt/intel-undervolt-1.7.ebuild b/sys-power/intel-undervolt/intel-undervolt-1.7.ebuild
new file mode 100644
index 00000000000..3073fbb4c1b
--- /dev/null
+++ b/sys-power/intel-undervolt/intel-undervolt-1.7.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit linux-info systemd toolchain-funcs
+
+DESCRIPTION="Intel CPU undervolting and throttling configuration tool"
+HOMEPAGE="https://github.com/kitsunyan/intel-undervolt"
+
+if [ ${PV} == "9999" ] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/kitsunyan/${PN}.git"
+else
+	SRC_URI="https://github.com/kitsunyan/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="-* ~amd64"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="elogind"
+
+DEPEND="elogind? ( sys-auth/elogind )"
+
+RDEPEND="${DEPEND}"
+
+BDEPEND="virtual/pkgconfig"
+
+CONFIG_CHECK="~INTEL_RAPL ~X86_MSR"
+
+src_configure() {
+	local myconf=(
+		# it's a non-standard build system
+		$(usex elogind --enable-elogind '')
+		--enable-openrc
+		--enable-systemd
+		--unitdir="$(systemd_get_systemunitdir)"
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_compile() {
+
+	tc-export CC
+
+	local myemakeargs=(
+		CC="${CC}"
+		CFLAGS="${CFLAGS}"
+	)
+	emake "${myemakeargs[@]}"
+}
+
+pkg_postinst() {
+for v in ${REPLACING_VERSIONS}; do
+	if [[ ${v} == 1.6 ]] ; then
+		elog "openrc service has been renamed to intel-undervolt-loop"
+		elog "please update your startup configuration"
+	fi
+done
+}

diff --git a/sys-power/intel-undervolt/metadata.xml b/sys-power/intel-undervolt/metadata.xml
index 52dabf8e780..ae8c6fe793f 100644
--- a/sys-power/intel-undervolt/metadata.xml
+++ b/sys-power/intel-undervolt/metadata.xml
@@ -8,6 +8,9 @@
 	<longdescription lang="en">
 		Tool for undervolting and throttling limits alteration for Intel CPUs
 	</longdescription>
+	<use>
+		<flag name="elogind">Use elogind hook to apply voltage after system sleep</flag>
+	</use>
 	<upstream>
 		<remote-id type="github">kitsunyan/intel-undervolt</remote-id>
 	</upstream>