[gentoo-commits] repo/gentoo:master commit in: media-sound/beets/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     aa1f3c48ab47e76595f59cbdc73d79a2e48e2bf8
Author:     Bernardo Meurer <meurerbernardo <AT> gmail <DOT> com>
AuthorDate: Tue Jul 30 21:30:30 2019 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Fri Aug 30 11:45:19 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=aa1f3c48

media-sound/beets: bump to 1.4.9

Closes: https://bugs.gentoo.org/689182
Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Bernardo Meurer <bernardo <AT> standard.ai>
Closes: https://github.com/gentoo/gentoo/pull/12582
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 media-sound/beets/Manifest           |   1 +
 media-sound/beets/beets-1.4.9.ebuild | 142 +++++++++++++++++++++++++++++++++++
 2 files changed, 143 insertions(+)

diff --git a/media-sound/beets/Manifest b/media-sound/beets/Manifest
index a75afe9cac4..98aff304f12 100644
--- a/media-sound/beets/Manifest
+++ b/media-sound/beets/Manifest
@@ -1 +1,2 @@
 DIST beets-1.4.8.tar.gz 1493539 BLAKE2B 63c44f05bbf139cd43b5f5ada972fd30beeea2303c6b479b1be35ea21fabb0039b3c8eb6e90f8f1b2a61fed36d97ce09a32c6346cbd3b84c7c978e796505f4b4 SHA512 449bed88185a5ecb4781719e092c2428ddc52fb8084033db64a4c0eca8899154192e7cea82517993d60326c7fe39b26429584ba368ffc35800f722d8d6a03217
+DIST beets-1.4.9.tar.gz 1494459 BLAKE2B 2daf77caf395143813c8b288fc376b5aec01d49281d40ba5942daf9941891146d698a1517ced958e480c6f253eadb6a7e09029e079c97e6cc17d44ac18fa0e7b SHA512 616bad4ca3ecdd05d2f59846fd67215f476ce89cc34d63bc6351efcbaf1e33e5ca783cb8a716e8597b56a7e08e6a6dc15e64b51e89dd786bfb6c5d847f66de5a

diff --git a/media-sound/beets/beets-1.4.9.ebuild b/media-sound/beets/beets-1.4.9.ebuild
new file mode 100644
index 00000000000..e2da8e5f2f7
--- /dev/null
+++ b/media-sound/beets/beets-1.4.9.ebuild
@@ -0,0 +1,142 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PV=${PV/_beta/-beta.}
+MY_P=${PN}-${MY_PV}
+
+PYTHON_COMPAT=( python3_{5,6} )
+PYTHON_REQ_USE="sqlite"
+inherit distutils-r1
+
+DESCRIPTION="Media library management system for obsessive-compulsive music geeks"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+HOMEPAGE="http://beets.io/ https://pypi.org/project/beets/"
+
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+LICENSE="MIT"
+IUSE="badfiles chromaprint discogs doc ffmpeg gstreamer icu lastfm mpd replaygain test thumbnail webserver"
+
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+DEPEND="
+	>=dev-python/jellyfish-0.7.1[${PYTHON_USEDEP}]
+	dev-python/munkres[${PYTHON_USEDEP}]
+	>=dev-python/python-musicbrainz-ngs-0.4[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/requests-oauthlib[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9[${PYTHON_USEDEP}]
+	dev-python/unidecode[${PYTHON_USEDEP}]
+	>=media-libs/mutagen-1.33[${PYTHON_USEDEP}]
+	virtual/python-enum34[${PYTHON_USEDEP}]
+	badfiles? (
+		media-libs/flac
+		media-sound/mp3val
+	)
+	chromaprint? (
+		dev-python/pyacoustid[${PYTHON_USEDEP}]
+		media-libs/chromaprint[tools]
+	)
+	discogs? ( dev-python/discogs-client[${PYTHON_USEDEP}] )
+	ffmpeg? ( media-video/ffmpeg:0[encode] )
+	gstreamer? (
+		media-libs/gst-plugins-good:1.0
+		media-libs/gst-plugins-bad:1.0
+	)
+	icu? ( dev-db/sqlite[icu] )
+	lastfm? ( dev-python/pylast[${PYTHON_USEDEP}] )
+	mpd? (
+		dev-python/bluelet[${PYTHON_USEDEP}]
+		dev-python/python-mpd[${PYTHON_USEDEP}]
+	)
+	replaygain? (
+		gstreamer? (
+			dev-python/pygobject:3[${PYTHON_USEDEP}]
+			media-plugins/gst-plugins-libav:1.0
+		)
+		!gstreamer? ( media-sound/mp3gain )
+	)
+	thumbnail? (
+		dev-python/pyxdg[${PYTHON_USEDEP}]
+		virtual/python-pathlib[${PYTHON_USEDEP}]
+		|| (
+			dev-python/pillow[${PYTHON_USEDEP}]
+			media-gfx/imagemagick
+		)
+	)
+	webserver? (
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/flask-cors[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="${DEPEND}"
+
+RESTRICT="test" # tests broken in 1.4.3 already
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	rm_use_plugins() {
+		[[ -n "${1}" ]] || die "rm_use_plugins: No use option given"
+		local use=${1}
+		local plugins=${use}
+		use ${use} && return
+		einfo "no ${use}:"
+		[[ $# -gt 1 ]] && plugins="${@:2}"
+		for arg in ${plugins[@]}; do
+			einfo "  removing ${arg}"
+			if [[ -e "beetsplug/${arg}.py" ]]; then
+				rm beetsplug/${arg}.py || die "Unable to remove ${arg} plugin"
+			fi
+			if [[ -d "beetsplug/${arg}" ]]; then
+				rm -r beetsplug/${arg} || die "Unable to remove ${arg} plugin"
+			fi
+			sed -e "s:'beetsplug.${arg}',::" -i setup.py || \
+				die "Unable to disable ${arg} plugin "
+		done
+	}
+
+	default
+
+	rm_use_plugins chromaprint chroma
+	rm_use_plugins ffmpeg convert
+	rm_use_plugins icu loadext
+	rm_use_plugins lastfm lastgenre lastimport
+	rm_use_plugins mpd bpd mpdstats
+	rm_use_plugins webserver web
+	rm_use_plugins thumbnail thumbnails
+
+	# remove plugins that do not have appropriate dependencies installed
+	for flag in badfiles discogs replaygain; do
+		rm_use_plugins ${flag}
+	done
+
+	if ! use mpd; then
+		rm test/test_player.py || die
+	fi
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	cd test || die
+	if ! use webserver; then
+		rm test_web.py || die "Failed to remove test_web.py"
+	fi
+	"${EPYTHON}" testall.py || die "Testsuite failed"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	doman man/beet.1 man/beetsconfig.5
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	einstalldocs
+}