[gentoo-commits] repo/gentoo:master commit in: dev-db/libdbi-drivers/

["Brian Evans" <grknight@gentoo.org>]

commit:     1c29811d86dbc0a458f74c8b026263ef3d83ca05
Author:     Brian Evans <grknight <AT> gentoo <DOT> org>
AuthorDate: Fri Aug 23 14:36:53 2019 +0000
Commit:     Brian Evans <grknight <AT> gentoo <DOT> org>
CommitDate: Fri Aug 23 14:38:47 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1c29811d

dev-db/libdbi-drivers: Revbump for EAPI and deps

Non-maintainer commit

Change to EAPI 7 and use mysql-connector-c instead of virtual/mysql

Bug: https://bugs.gentoo.org/665840
Package-Manager: Portage-2.3.72, Repoman-2.3.17
Signed-off-by: Brian Evans <grknight <AT> gentoo.org>

 .../libdbi-drivers/libdbi-drivers-0.9.0-r1.ebuild  | 87 ++++++++++++++++++++++
 1 file changed, 87 insertions(+)

diff --git a/dev-db/libdbi-drivers/libdbi-drivers-0.9.0-r1.ebuild b/dev-db/libdbi-drivers/libdbi-drivers-0.9.0-r1.ebuild
new file mode 100644
index 00000000000..a46e855b424
--- /dev/null
+++ b/dev-db/libdbi-drivers/libdbi-drivers-0.9.0-r1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="The libdbi-drivers project maintains drivers for libdbi"
+SRC_URI="mirror://sourceforge/project/${PN}/${PN}/${P}/${P}.tar.gz"
+HOMEPAGE="http://libdbi-drivers.sourceforge.net/"
+LICENSE="LGPL-2.1"
+
+IUSE="doc firebird mysql oci8 postgres +sqlite static-libs"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+SLOT=0
+REQUIRED_USE="|| ( mysql postgres sqlite firebird oci8 )"
+RESTRICT="firebird? ( bindist )"
+
+RDEPEND="
+	>=dev-db/libdbi-0.9.0
+	firebird? ( dev-db/firebird )
+	mysql? ( dev-db/mysql-connector-c:= )
+	postgres? ( dev-db/postgresql:* )
+	sqlite? ( dev-db/sqlite:3 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="doc? ( app-text/openjade )"
+
+DOCS=( AUTHORS ChangeLog NEWS README README.osx TODO )
+
+PATCHES=(
+		#"${FILESDIR}"/${P}-fix-ac-macro.patch \
+		#"${FILESDIR}"/${PN}-0.8.3-oracle-build-fix.patch \
+		#"${FILESDIR}"/${PN}-0.8.3-firebird-fix.patch
+		"${FILESDIR}"/${PN}-0.9.0-doc-build-fix.patch
+)
+
+pkg_setup() {
+	use oci8 && [[ -z "${ORACLE_HOME}" ]] && die "\$ORACLE_HOME is not set!"
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=""
+	# WARNING: the configure script does NOT work correctly
+	# --without-$driver does NOT work
+	# so do NOT use `use_with...`
+	# Future additions:
+	# msql
+	# freetds
+	# ingres
+	# db2
+	use mysql && myconf+=" --with-mysql"
+	use postgres && myconf+=" --with-pgsql"
+	use sqlite && myconf+=" --with-sqlite3"
+	use firebird && myconf+=" --with-firebird"
+	if use oci8; then
+		[[ -z "${ORACLE_HOME}" ]] && die "\$ORACLE_HOME is not set!"
+		myconf+=" --with-oracle-dir=${ORACLE_HOME} --with-oracle"
+	fi
+
+	econf \
+		$(use_enable doc docs) \
+		$(use_enable static-libs static) \
+		--with-dbi-libdir=/usr/$(get_libdir) \
+		${myconf}
+}
+
+src_test() {
+	if [[ -z "${WANT_INTERACTIVE_TESTS}" ]]; then
+		ewarn "Tests disabled due to interactivity."
+		ewarn "Run with WANT_INTERACTIVE_TESTS=1 if you want them."
+		return 0
+	fi
+	einfo "Running interactive tests"
+	emake check
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -type f -delete || die
+}