[gentoo-commits] repo/gentoo:master commit in: dev-libs/hsa-ext-rocr/

["Marek Szuba" <marecki@gentoo.org>]

commit:     02b7fd5c0c4a9334e942f6b05ac71bcf72a3b6df
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Tue Aug 20 15:05:57 2019 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Tue Aug 20 15:14:35 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=02b7fd5c

dev-libs/hsa-ext-rocr: new package

Required for the time being by dev-libs/rocm-opencl-runtime in order to
enable OpenCL image support. The relevant code will eventually be
open-sourced but so far upstream hasn't provided any timeline for it.

There is no licence file in the upstream package, that said the
libraries it contains used to be distributed as part of the AMDGPU-Pro
stack so it is a safe bet that the standalone package is covered by the
same EULA as for dev-libs/amdgpu-pro-opencl.

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 dev-libs/hsa-ext-rocr/Manifest                     |  1 +
 dev-libs/hsa-ext-rocr/hsa-ext-rocr-1.1.9.99.ebuild | 53 ++++++++++++++++++++++
 dev-libs/hsa-ext-rocr/metadata.xml                 | 22 +++++++++
 3 files changed, 76 insertions(+)

diff --git a/dev-libs/hsa-ext-rocr/Manifest b/dev-libs/hsa-ext-rocr/Manifest
new file mode 100644
index 00000000000..a8f257eb375
--- /dev/null
+++ b/dev-libs/hsa-ext-rocr/Manifest
@@ -0,0 +1 @@
+DIST hsa-ext-rocr-dev_1.1.9-99-g835b876_amd64.deb 1113746 BLAKE2B ff1d3418febdde505e12a3a41b39a15d6ed28e97f62700ffa4b7bfbc618b23253026e3978e1293cfa2c06742c78574510e08969e1e1524b82b94a45d98efd2af SHA512 e7c799e218eaee6f926fe309b470af00e0ef7e4974a3dd67231c1c904a0a036e62b1ce3b176bb0c13c0fa65a718443f06e7472e3e66225d818074620e46350b1

diff --git a/dev-libs/hsa-ext-rocr/hsa-ext-rocr-1.1.9.99.ebuild b/dev-libs/hsa-ext-rocr/hsa-ext-rocr-1.1.9.99.ebuild
new file mode 100644
index 00000000000..7d91362d6a0
--- /dev/null
+++ b/dev-libs/hsa-ext-rocr/hsa-ext-rocr-1.1.9.99.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit unpacker
+
+MY_PV=$(ver_rs 3 '-')
+
+DESCRIPTION="Proprietary image-support library for Radeon Open Compute"
+HOMEPAGE="https://github.com/RadeonOpenCompute/ROCm#closed-source-components"
+SRC_URI="http://repo.radeon.com/rocm/apt/debian/pool/main/h/${PN}-dev/${PN}-dev_${MY_PV}-g835b876_amd64.deb"
+
+LICENSE="AMD-GPU-PRO-EULA"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="-deprecated"
+
+RESTRICT="mirror fetch strip"
+
+QA_PREBUILT="/opt/${PN}/lib*/*"
+
+S="${WORKDIR}"
+
+pkg_nofetch() {
+	einfo "Please download the package"
+	einfo
+	einfo "    ${SRC_URI}"
+	einfo
+	einfo "and place into your distfiles directory."
+}
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+src_install() {
+	local destdir="/opt/${PN}"
+	local soversion=$(ver_cut 1-3)
+	local somajor=$(ver_cut 1)
+
+	local solibs_to_install=( "libhsa-ext-image64.so" )
+	if use deprecated; then
+		solibs_to_install+=( "libhsa-runtime-tools64.so" )
+	fi
+
+	into "${destdir}"
+	for solib in ${solibs_to_install[@]}; do
+		dolib.so "opt/rocm/hsa/lib/${solib}.${soversion}"
+		dosym "${EPREFIX}${destdir}/$(get_libdir)/${solib}.${soversion}" "${EPREFIX}usr/$(get_libdir)/${solib}.${soversion}"
+		dosym "${solib}.${soversion}" "${EPREFIX}usr/$(get_libdir)/${solib}.${somajor}"
+	done
+}

diff --git a/dev-libs/hsa-ext-rocr/metadata.xml b/dev-libs/hsa-ext-rocr/metadata.xml
new file mode 100644
index 00000000000..d61b59ba30a
--- /dev/null
+++ b/dev-libs/hsa-ext-rocr/metadata.xml
@@ -0,0 +1,22 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>marecki@gentoo.org</email>
+		<name>Marek Szuba</name>
+	</maintainer>
+	<maintainer type="person">
+		<email>candrews@gentoo.org</email>
+		<name>Craig Andrews</name>
+	</maintainer>
+	<longdescription lang="en">
+		For the time being the ROCm platform relies on a closed-source library
+		to provide HSA image support. In the future it will either be deprecated
+		or become open source.
+		Furthermore, this package optionally provides the "tools"
+		debug/trace/profiling library which has already been deprecated.
+	</longdescription>
+	<use>
+		<flag name="deprecated">Install the deprecated debug/trace/profiling library</flag>
+	</use>
+</pkgmetadata>