[gentoo-commits] repo/gentoo:master commit in: dev-db/pgrouting/

["Aaron W. Swenson" <titanofold@gentoo.org>]

commit:     486e884611f9d08e3036474e4c032c9b4b830a41
Author:     Aaron W. Swenson <titanofold <AT> gentoo <DOT> org>
AuthorDate: Sat Aug 17 11:16:49 2019 +0000
Commit:     Aaron W. Swenson <titanofold <AT> gentoo <DOT> org>
CommitDate: Sat Aug 17 11:17:13 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=486e8846

dev-db/pgrouting: Fix manpage generation

Bug: https://bugs.gentoo.org/625778
Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Aaron W. Swenson <titanofold <AT> gentoo.org>

 dev-db/pgrouting/pgrouting-2.6.2-r1.ebuild | 61 ++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

diff --git a/dev-db/pgrouting/pgrouting-2.6.2-r1.ebuild b/dev-db/pgrouting/pgrouting-2.6.2-r1.ebuild
new file mode 100644
index 00000000000..db35bce832a
--- /dev/null
+++ b/dev-db/pgrouting/pgrouting-2.6.2-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+POSTGRES_COMPAT=( 9.{4..6} 10 11 )
+POSTGRES_USEDEP="server"
+
+inherit  postgres cmake-utils
+
+DESCRIPTION="pgRouting extends PostGIS and PostgreSQL with geospatial routing functionality."
+HOMEPAGE="http://pgrouting.org/"
+LICENSE="GPL-2 MIT Boost-1.0"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+SRC_URI="https://github.com/pgRouting/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+IUSE="pdf html"
+
+RDEPEND="${POSTGRES_DEP}
+	>=dev-db/postgis-2.0
+	dev-libs/boost
+	sci-mathematics/cgal
+"
+
+# Sphinx is needed to build the man pages
+DEPEND="${RDEPEND}
+	>=dev-python/sphinx-1.2
+	pdf? ( >=dev-python/sphinx-1.2[latex] )
+"
+
+# Needs a running psql instance, doesn't work out of the box
+RESTRICT="test"
+
+pkg_setup() {
+	postgres_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_HTML=$(usex html)
+		-DBUILD_LATEX=$(usex pdf)
+		-DBUILD_MAN=ON
+		-DWITH_DOC=ON
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_make all doc
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	doman "${BUILD_DIR}"/doc/man/en/pgrouting.7
+
+	use html && dodoc -r "${BUILD_DIR}"/doc/html
+	use pdf && dodoc "${BUILD_DIR}"/doc/latex/en/*.pdf
+}