[gentoo-commits] repo/gentoo:master commit in: app-misc/gramps/

["Marek Szuba" <marecki@gentoo.org>]

commit:     9ccff3e3f26bff809fde4548580b24f25f6100e0
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Fri Aug  9 15:11:05 2019 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Fri Aug  9 15:11:25 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9ccff3e3

app-misc/gramps: bump to 5.0.2

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 app-misc/gramps/Manifest            |  1 +
 app-misc/gramps/gramps-5.0.2.ebuild | 71 +++++++++++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/app-misc/gramps/Manifest b/app-misc/gramps/Manifest
index d4ed883d6cb..0a81bf89f40 100644
--- a/app-misc/gramps/Manifest
+++ b/app-misc/gramps/Manifest
@@ -1,2 +1,3 @@
 DIST gramps-4.2.8.tar.gz 18704769 BLAKE2B 795febcc2c93a0c9b72aceeba1ac4c4f10953c2bf3b23dd8d38f662a231e21967e6f263e14d2344ef2f422e170617b7b80be4fafc2cb20c4a659366836b0e641 SHA512 c814914eb3a650dd5753d83e492d91d5db11b55321f63bd460e4eb8d80a36dd727a3792a203e3061dfaa89fd13549f51809bb83cc65b2a494c1fb8f42dcb4b8f
 DIST gramps-5.0.1.tar.gz 16718439 BLAKE2B 75b4a70275f7e6e181ba948df6fe44cbb9221436c2e860db8ef83bcc02b916aa3921ae09fa8ed18876f28551ed10b5047ae1aef0967b48532b54ad97c8af6d8a SHA512 68b905a8e59eedb620329b05bdd4cca842a79f885645140d31b637fc82ec7470892ebf0fd899aeb6a1205473f79e7f13d6c5e05b36da94b9049dcbb78e07aa76
+DIST gramps-5.0.2.tar.gz 16706686 BLAKE2B 006c8d10d574d7fe92b661400c257f6f1bc2b2e9e27d788ca761a5d51aa8593f9d26fdccdeeb0fb2860bfe1b08d937e938b3fb21094a42de0fb306d3c16dca49 SHA512 abbf885189bedcf9897bcb3216df86af41498c94b3b9c133350e84a8a61057ab4ed4823c3923823ec99fe0be92648e9259fdceaafd31f968c7d1560a0cd859da

diff --git a/app-misc/gramps/gramps-5.0.2.ebuild b/app-misc/gramps/gramps-5.0.2.ebuild
new file mode 100644
index 00000000000..3ce0f03cb28
--- /dev/null
+++ b/app-misc/gramps/gramps-5.0.2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6} )
+PYTHON_REQ_USE="sqlite"
+
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="Genealogical Research and Analysis Management Programming System"
+HOMEPAGE="https://gramps-project.org/"
+SRC_URI="https://github.com/gramps-project/${PN}/archive/v${PV}.tar.gz
+	-> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+rcs +reports exif geo postscript spell"
+
+RDEPEND="
+	dev-python/bsddb3[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-3.12:3[cairo,${PYTHON_USEDEP}]
+	dev-python/pyicu[${PYTHON_USEDEP}]
+	gnome-base/librsvg:2
+	>x11-libs/gtk+-3.14.8:3[introspection]
+	x11-libs/pango[introspection]
+	x11-misc/xdg-utils
+	reports? ( media-gfx/graphviz[postscript?] )
+	exif? ( >=media-libs/gexiv2-0.5[${PYTHON_USEDEP},introspection] )
+	geo? ( >=sci-geosciences/osm-gps-map-1.1.0 )
+	spell? ( app-text/gtkspell:3[introspection] )
+	rcs? ( dev-vcs/rcs )
+"
+
+python_prepare_all() {
+	# Install documentation to the proper location. This can't be done
+	# easily with a patch because we substitute in the $PF variable,
+	# and that changes with every revision.
+	sed -i "s:share/doc/gramps:share/doc/${PF}:g" setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	mydistutilsargs=(
+		--resourcepath=/usr/share
+		--no-compress-manpages
+	)
+}
+
+python_test_all() {
+	# GRAMPS builds just fine out of tree but it confuses its test suite.
+	# The following might be an ugly hack but at least it lets the tests
+	# run properly until either I or upstream have come up with something
+	# better.
+	rm -rf "${S}/build" && ln -s "${BUILD_DIR}" "${S}"/build || \
+		die "Failed to symlink build directory to source directory"
+
+	esetup.py test
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}